hm_bigbox.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_bigbox              ../starter/source/model/box/hm_bigbox.F
!||--- called by ------------------------------------------------------
!||    hm_lecgrn              ../starter/source/groups/hm_lecgrn.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    boxbox                 ../starter/source/model/box/boxbox.F
!||    boxtagn                ../starter/source/model/box/bigbox.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE hm_bigbox(X   ,FLAG,NNOD ,
     .                  SKEW,IGS    ,ISKN ,ITABM1,IBOX   ,
     .                  ID  ,IBUFBOX,IADB ,TITR,KEY,NN,
     .                  IBOXMAX,IGRNOD,IDB)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
      USE optiondef_mod
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER FLAG,NNOD,
     .        IGS,ISKN(LISKN,*),ITABM1(*),
     .        ID,IBUFBOX(*),IADB,NN,IBOXMAX
      INTEGER,INTENT(IN) :: IDB
      my_real
     .        X(3,*),SKEW(LSKEW,*)
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER(LEN=NCHARFIELD) :: KEY
      TYPE (GROUP_)  , DIMENSION(NGRNOD) :: IGRNOD
      TYPE (BOX_)    , DIMENSION(NBBOX)  :: IBOX
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K,N,ISU,JREC,NBOX,BOXTYPE,IADBOX,
     .        ICOUNT,ITER,FLAGG,INBOX,BOXNODS,IADISU
      CHARACTER BOX*3
      LOGICAL BOOL
C-----------------------------------------------
       DO i=1,nbbox
         ibox(i)%NBLEVELS = 0
         ibox(i)%LEVEL = 1
         ibox(i)%ACTIBOX = 0
         IF(ibox(i)%NBOXBOX > 0)THEN
           ibox(i)%NBLEVELS = -1
           ibox(i)%LEVEL =  0
         END IF
C
         ibox(i)%BOXIAD = 0
       END DO
C-------
C get box de box ID'S dans grnod:
C-------
      isu = 0
      DO i=1,nbbox
        IF(idb == ibox(i)%ID) THEN 
          isu=i
          EXIT
        ENDIF
      END DO
C---
      IF(isu > 0)THEN
       nbox   = ibox(isu)%NBOXBOX
C super box activated:
       ibox(isu)%ACTIBOX = 1
      ELSE
       IF(flag == 0)THEN
        CALL ancmsg(msgid=794,
     .              msgtype=msgerror,
     .              anmode=aninfo,
     .              i1=id,
     .              c1=titr,
     .              i2=idb)
       END IF
      END IF
C---
C   simple box dans grnod:
C---
      bool = .false.
      IF(isu>0)THEN
        IF(ibox(isu)%NBLEVELS == 0 .AND. ibox(isu)%LEVEL == 1) THEN
          IF(nbox == 0)THEN
            CALL boxtagn(x   ,ibufbox,skew,iadb,ibox,isu ,flag,iboxmax)
            bool =.true.
          END IF
        END IF
      ENDIF
C---
C READ LEVELS OF BOXES ==> "SUBLEVEL DONE"
C---
       IF(.NOT.bool)THEN
        icount = 1
        iter   = 0
        DO WHILE (icount == 1)
          iter  = iter  + 1
          flagg = 0
C---      count next level
          CALL boxbox(ibox  ,skew   ,
     .                flagg  ,icount,iter  ,ibufbox,
     .                x      ,iadb  ,id    ,titr   ,
     .                key    ,flag  ,iboxmax)
C---      fill next level
          flagg = 1
          CALL boxbox(ibox  ,skew   ,
     .                flagg  ,icount,iter  ,ibufbox,
     .                x      ,iadb  ,id    ,titr   ,
     .                key    ,flag  ,iboxmax)
C---
        ENDDO
      ENDIF
C---
C tag group nodes in main-box:
C---
      IF(isu > 0)THEN
        IF(flag == 0)THEN
          boxnods = ibox(isu)%NENTITY  ! nodes of main box
          nnod = boxnods
        ELSE IF(flag == 1)THEN
          boxnods = ibox(isu)%NENTITY  ! nodes of main box
          iadisu  = ibox(isu)%BOXIAD  ! addresses of nodes in main box
          nnod = boxnods
          DO i=1,boxnods
            n=ibufbox(iadisu+i-1)
            nn = nn + 1
            igrnod(igs)%ENTITY(nn) = n
          END DO
        END IF
      END IF
C--------------
      RETURN
      END