hm_preread_impvel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_preread_impvel      ../starter/source/constraints/general/impvel/hm_preread_impvel.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_count        ../starter/source/devtools/hm_reader/hm_option_count.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    ngr2usrn               ../starter/source/system/nintrr.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_preread_impvel(
     .           NIMPVEL  ,IGRNOD  ,IPART   ,IPARTR   ,   NFVLAG,
     .           UNITAB   ,LSUBMODEL)
C============================================================================
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE unitab_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(OUT)   :: NIMPVEL
      INTEGER ,INTENT(INOUT) :: NFVLAG
      INTEGER IPART(LIPART1,*), IPARTR(*)
      TYPE(unit_type_), INTENT(IN) :: UNITAB
      TYPE (GROUP_)      , DIMENSION(NGRNOD)  ,INTENT(IN) :: IGRNOD
      TYPE(submodel_data), DIMENSION(*)       ,INTENT(IN) :: LSUBMODEL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,N,OPTID,NFVEL,NFGEO,IGS,GRNOD_ID,PART_ID,NNOD,JPART,SYS_TYPE
      CHARACTER(LEN=NCHARKEY) :: KEY
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL :: IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER  NGR2USRN
c--------------------------------------------------
c     Count number of nodes with imposed velocity => NUMVEL
C======================================================================|
      is_available = .false.
c
      nimpvel = 0   ! initialize counter of nodes
c--------------------------------------------------
c     /IMPVEL and /IMPVEL/LAGMUL
c--------------------------------------------------
      CALL hm_option_count('/IMPVEL',nfvel)
c
      CALL hm_option_start('/IMPVEL')
c
      DO i=1,nfvel
c
        CALL hm_option_read_key(lsubmodel,
     .                          option_id   = optid,
     .                          option_titr = titr,
     .                          keyword2    = key)
c
        IF (key(1:4) /= 'FGEO') THEN
          CALL hm_get_intv('rad_system_input_type'   ,sys_type ,is_available,lsubmodel)
          CALL hm_get_intv('entityid'                ,grnod_id ,is_available,lsubmodel)
          igs = ngr2usrn(grnod_id,igrnod,ngrnod,nnod)
          IF (igs > 0) THEN
            nimpvel = nimpvel + nnod                                         
            IF (key(1:6) == 'LAGMUL') nfvlag = nfvlag + nnod
          END IF
        ENDIF
c
      ENDDO ! DO I=1,NFVEL
c--------------------------      
c     /IMPVEL/FGEO    
c--------------------------         
      CALL hm_option_count('/IMPVEL/FGEO',nfgeo)
c
      CALL hm_option_start('/IMPVEL/FGEO')
c
      
      DO i=1,nfgeo
c
        CALL hm_option_read_key(lsubmodel,
     .                          option_id   = optid,
     .                          option_titr = titr,
     .                          keyword2    = key)
        IF (key(1:4) == 'FGEO') THEN
          CALL hm_get_intv('rad_spring_part' ,part_id ,is_available,lsubmodel)
          IF (part_id > 0) THEN
            jpart = 0
            DO n=1,npart
              IF (ipart(4,n) == part_id) jpart = n
            ENDDO
            IF (jpart == 0) THEN
             CALL ancmsg(msgid=1077, msgtype=msgerror,
     .                   anmode=aninfo,
     .                   i1=optid,
     .                   c1=titr,
     .                   i2=part_id)
            ENDIF
            DO n=1,numelr
              IF (ipartr(n) == jpart) nimpvel = nimpvel + 1
            ENDDO
          ENDIF
c
          CALL hm_get_intv('distribution_table_count' ,nnod ,is_available,lsubmodel)
          nimpvel = nimpvel + nnod
        ENDIF
      ENDDO ! DO I=1,NFGEO
c-----------
      RETURN
      END