hm_preread_node.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    hm_preread_node        ../starter/source/elements/reader/hm_preread_node.F
!||--- called by ------------------------------------------------------
!||    contrl                 ../starter/source/starter/contrl.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    auto_node_merge        ../starter/source/elements/nodes/auto_node_merge.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    reader_old_mod         ../starter/share/modules1/reader_old_mod.F90
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_preread_node(UNITAB,LSUBMODEL,NUMNUSR,IS_DYNA)
C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------- 
      USE unitab_mod
      USE message_mod
      USE submodel_mod , ONLY : nsubmod, submodel_data
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : ncharfield
      USE reader_old_mod , ONLY : line
      USE user_id_mod , ONLY : id_limit
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN)  :: UNITAB 
      TYPE(submodel_data),INTENT(IN):: LSUBMODEL(NSUBMOD)
      INTEGER,INTENT(IN)   :: NUMNUSR
      INTEGER,INTENT(IN)   :: IS_DYNA
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: N,I,J,STAT
      INTEGER :: IFLAGUNIT, UID
      my_real :: fac_l
      INTEGER, DIMENSION(:), ALLOCATABLE :: SUB_NOD,UID_NOD
      INTEGER, DIMENSION(:), ALLOCATABLE :: ITAB
      my_real, DIMENSION(:,:), ALLOCATABLE :: x
      real*8, DIMENSION(:,:), ALLOCATABLE :: hm_x
      real*8, DIMENSION(:), ALLOCATABLE :: dmerge
C-----------------------------------------------      
      fac_l = one
C--------------------------------------------------
C      ALLOCS & INITS
C--------------------------------------------------
      ALLOCATE (itab(numnusr+numcnod),stat=stat)
      IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,msgtype=msgerror,c1='ITAB')
      ALLOCATE (x(3,numnusr+numcnod),stat=stat)
      IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,msgtype=msgerror,c1='X')
      ALLOCATE (sub_nod(numnusr+numcnod),stat=stat)
      IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,msgtype=msgerror,c1='SUB_NOD')
      ALLOCATE (uid_nod(numnusr+numcnod),stat=stat)
      IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,msgtype=msgerror,c1='UID_NOD')
      ALLOCATE (hm_x(3,numnusr+numcnod),stat=stat)
      IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,msgtype=msgerror,c1='HM_X')
      ALLOCATE (dmerge(numcnod),stat=stat)
      IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,msgtype=msgerror,c1='DMERGE')
      sub_nod(1:numnusr+numcnod) = 0
      uid_nod(1:numnusr+numcnod) = 0
      dmerge(1:numcnod) = zero
C--------------------------------------------------
C      PRE-READING OF INPUT NODES IN HM STRUCTURE
C-------------------------------------------------- 
      CALL cpp_nodes_read(itab,hm_x,dmerge,sub_nod,uid_nod)
C--------------------------------------------------
C      FILL OTHER STRUCTURES + CHECKS
C--------------------------------------------------
      uid = -1 
      n=0                                              
      DO i=1,numnusr+numcnod                                        
        n=n+1  
        x(1,n) = hm_x(1,n)
        x(2,n) = hm_x(2,n)
        x(3,n) = hm_x(3,n)
C--------------------------------------------------
        IF(sub_nod(n) /= 0)THEN
          IF(uid_nod(n) == 0 .AND. lsubmodel(sub_nod(n))%UID /= 0) uid_nod(n) = lsubmodel(sub_nod(n))%UID
        ENDIF
        IF ( itab(n) > id_limit%GLOBAL )THEN
          CALL ancmsg(msgid=509,anmode=aninfo,msgtype=msgerror,i1=itab(n),c1=line,c2='/NODE')
        ENDIF                    
C--------------------------------------------------
C      UNITS
C--------------------------------------------------
        IF(uid_nod(n) /= uid )THEN
          uid = uid_nod(n)
          iflagunit = 0          
          DO j=1,unitab%NUNITS                   
            IF (unitab%UNIT_ID(j) == uid) THEN  
              fac_l = unitab%FAC_L(j)
              iflagunit = 1                 
              EXIT                              
            ENDIF                               
          ENDDO                    
          IF (uid/=0 .AND. iflagunit==0 .AND. i <= numnusr)THEN
            CALL ancmsg(msgid=643,anmode=aninfo,msgtype=msgerror,i1=uid,c1='/NODE')
          ELSEIF (uid/=0 .AND. iflagunit==0 .AND. i > numnusr)THEN
            CALL ancmsg(msgid=643,anmode=aninfo,msgtype=msgerror,i1=uid,c1='/CNODE')
          ENDIF 
        ENDIF
        x(1,n) = x(1,n)*fac_l  
        x(2,n) = x(2,n)*fac_l  
        x(3,n) = x(3,n)*fac_l 
      ENDDO
      IF(ALLOCATED(sub_nod)) DEALLOCATE(sub_nod)
      IF(ALLOCATED(uid_nod)) DEALLOCATE(uid_nod)
      IF(ALLOCATED(hm_x)) DEALLOCATE(hm_x)
      IF(ALLOCATED(dmerge)) DEALLOCATE(dmerge)                             
C--------------------------------------------------
C     Check nodes within some tolerance (possibly merge nodes)
C--------------------------------------------------
      CALL auto_node_merge(is_dyna,numnusr,numcnod,numnod,itab,x)
C--------------------------------
      DEALLOCATE(itab,x)
      RETURN
C--------------------------------
      END