hm_read_ale_grid.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_ale_grid     ../starter/source/general_controls/ale_grid/hm_read_ale_grid.F
!||--- called by ------------------------------------------------------
!||    contrl               ../starter/source/starter/contrl.f
!||--- calls      -----------------------------------------------------
!||    ancmsg               ../starter/source/output/message/message.F
!||    hm_get_floatv        ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv          ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_count      ../starter/source/devtools/hm_reader/hm_option_count.F
!||    hm_option_read_key   ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start      ../starter/source/devtools/hm_reader/hm_option_start.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod   ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod          ../starter/share/message_module/message_mod.F
!||    submodel_mod         ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_ale_grid(DT_INPUT, ALPHA, GAMMA, VGX, VGY, VGZ, VOLMIN, LSUBMODEL, UNITAB)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C Input Reader for options /ALE/GRID/...
C  NWALE       FORMULATION
C  0           'DONEA'
C  1           'DISP'
C  2           'SPRING'
C  3           'ZERO'
C  4           'STANDARD'
C  5           'LAPLACIAN'
C  6           'VOLUME'
C  7           'FLOW-TRACKING'
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE hm_option_read_mod
      USE submodel_mod
      USE message_mod
      USE ale_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "param_c.inc"
#include "com01_c.inc"
#include "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, INTENT(INOUT) :: dt_input, alpha, gamma, vgx, vgy, vgz, volmin
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(unit_type_), INTENT(IN) :: UNITAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NALE_GRID, II, NITER,NTETRA4
      CHARACTER :: KEY*32
      LOGICAL :: IS_AVAILABLE
      LOGICAL :: IS_DEFINED_ALE_GRID
      INTEGER :: IS_DEF, IS_ROT
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
!     Initializations
      is_defined_ale_grid = .false.
      ale%GRID%NWALE = 0
      alpha = zero
      gamma = zero
      vgx = zero
      vgy = zero
      vgz = zero
      volmin = zero
!     Counting
      CALL hm_option_count('/ALE/GRID', nale_grid)
 
      CALL hm_option_start('/ale/grid')
      DO II = 1, NALE_GRID
         CALL HM_OPTION_READ_KEY(LSUBMODEL, KEYWORD3 = KEY)
         IF (KEY(1:5) == 'donea') THEN
            IS_DEFINED_ALE_GRID = .TRUE.
            IF(NUMTETRA4 > 0) ALE%GLOBAL%NALENOVS=12
            CALL HM_GET_FLOATV('alpha', ALPHA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('gamma', GAMMA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('vel_x', VGX, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('vel_y', VGY, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('vel_z', VGZ, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('mini', VOLMIN, IS_AVAILABLE, LSUBMODEL, UNITAB)
            IF (GAMMA == ZERO) GAMMA = HUNDRED
            IF (VGX == ZERO) VGX = ONE
            IF (VGY == ZERO) VGY = ONE
            IF (VGZ == ZERO) VGZ = ONE
         ELSEIF (KEY(1:4) == 'disp') THEN
            IS_DEFINED_ALE_GRID = .TRUE.
            ALE%GRID%NWALE = 1
            CALL HM_GET_FLOATV('mat_eps', ALPHA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('mat_pc', VOLMIN, IS_AVAILABLE, LSUBMODEL, UNITAB)
            IF (ALPHA == ZERO) ALPHA = INFINITY
            VGX = ONE
            VGY = ONE
            VGZ = ONE
         ELSEIF (KEY(1:6) == 'spring') THEN
            IS_DEFINED_ALE_GRID = .TRUE.
            IF (N2D /= 0) THEN
               CALL ANCMSG(MSGID = 787, MSGTYPE=MSGERROR, ANMODE=ANINFO,C1='spring')
            ENDIF
            ALE%GRID%NWALE = 2
            VGZ = ZERO
            CALL HM_GET_FLOATV('deltat', ALPHA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('mat_gama0', GAMMA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('damp1', VGX, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('nu_l', VGY, IS_AVAILABLE, LSUBMODEL, UNITAB)
            IF (VGX == ZERO) VGX = HALF
            IF (VGY == ZERO) VGY = ONE
            DT_INPUT = ALPHA
            ALPHA = ALPHA / (-VGX + SQRT(VGX * VGX + ONE))
         ELSEIF (KEY(1:8) == 'standard') THEN
            IS_DEFINED_ALE_GRID = .TRUE.
            ALE%GRID%NWALE = 4
            CALL HM_GET_FLOATV('deltat_min', ALPHA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('mat_gamai', GAMMA, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('damp4', VGX, IS_AVAILABLE, LSUBMODEL, UNITAB)
            CALL HM_GET_FLOATV('nu_g', vgy, is_available, lsubmodel, unitab)
            IF (alpha == zero) alpha = zep9
            IF (gamma == zero) gamma = em02
            IF (vgx == zero) vgx = em02
            IF (vgy == zero) THEN
               CALL ancmsg(msgid = 1119, msgtype = msgerror, anmode = aninfo,
     .                     c1='** CRITICAL ELEMENT SIZE MUST BE DEFINED (4TH FIELD)')
            ENDIF
            IF (gamma < zero .OR. gamma > one) THEN
               CALL ancmsg(msgid = 1119, msgtype = msgerror, anmode = aninfo,
     .                     c1='** NON-LINEAR FACTOR MUST BE BETWEEN 0 AND 1 (2ND FIELD)')
            ENDIF
         ELSEIF (key(1:4) == 'ZERO') THEN
            is_defined_ale_grid = .true.
            ale%GRID%NWALE = 3
         ELSEIF (key(1:9) == 'LAPLACIAN') THEN
            is_defined_ale_grid = .true.
            ale%GRID%NWALE = 5
            CALL hm_get_floatv('LAMBDA', alpha, is_available, lsubmodel, unitab)
            CALL hm_get_intv('Niter', niter, is_available, lsubmodel)
            gamma = zero
            vgx = niter
            alpha = max(zero, min(alpha, ep06))
            IF (alpha == zero) alpha = one
            IF (gamma == zero) gamma = one
            IF (gamma /= one .AND. gamma /= two) gamma = one
            IF (vgx <= zero) vgx = one
         ELSEIF (key(1:6) == 'VOLUME') THEN
            is_defined_ale_grid = .true.
            ale%GRID%NWALE = 6
         ELSEIF (key(1:13) == 'FLOW-TRACKING') THEN
            is_defined_ale_grid = .true.
            ale%GRID%NWALE = 7
            CALL hm_get_intv('IS_DEF', is_def, is_available, lsubmodel)
            CALL hm_get_intv('IS_ROT', is_rot, is_available, lsubmodel)
            CALL hm_get_floatv('SCALE_DEF', alpha, is_available, lsubmodel, unitab)
            CALL hm_get_floatv('SCALE_ROT', gamma, is_available, lsubmodel, unitab)
            IF(is_def == 0)is_def = 1
            IF(is_def /= 1 .AND. is_def /= -1)is_def = 1 !value different than expected values leads to default value
            IF(is_rot == 0)is_rot = 1
            IF(is_rot /= 1 .AND. is_rot /= -1)is_rot = 1 !value different than expected values leads to default value
            IF (alpha == zero) alpha = one
            IF (gamma == zero) gamma = one
            vgx = is_def
            vgy = is_rot
            vgz = zero
         ELSEIF (key(1:8) == 'LAGRANGE') THEN
            is_defined_ale_grid = .true.
            ale%GRID%NWALE = 8
         ELSE
           !invalid keyword : error message managed by Reader itself
         ENDIF
 
      ENDDO
 
       ! NO /ALE/GRID formulation => DEFAULT:'DISP' & its default values are set here
       IF(.NOT. is_defined_ale_grid .OR. nale_grid == 0)THEN
         ale%GRID%NWALE = 1
         alpha = infinity
         vgx = one
         vgy = one
         vgz = one
       ENDIF
 
       IF(nale_grid > 1)THEN
         ! multiple definition of /ALE/GRID : error message eliminates any ambiguity
          CALL ancmsg(msgid = 1118, msgtype = msgerror, anmode = aninfo,
     .    c1='ONLY A SINGLE DEFINITION OF GRID SMOOTHING ALGORITHM IS ALLOWED')
       ENDIF
 
      END SUBROUTINE hm_read_ale_grid