hm_read_box.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_box            ../starter/source/model/box/hm_read_box.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    hm_option_count        ../starter/source/devtools/hm_reader/hm_option_count.F
!||    nboxlst                ../starter/source/model/box/nboxlist.F
!||    read_box_box           ../starter/source/model/box/read_box_box.F
!||    read_box_cyl           ../starter/source/model/box/read_box_cyl.F
!||    read_box_rect          ../starter/source/model/box/read_box_rect.F
!||    read_box_spher         ../starter/source/model/box/read_box_spher.F
!||    udouble_igr            ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_box(IBOX    ,UNITAB  ,ITABM1   ,ISKN    ,SKEW    ,
     .                       X       ,RTRANS  ,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE my_alloc_mod
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE optiondef_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : ncharkey
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,DIMENSION(LISKN,*)   ,INTENT(IN) :: ISKN
      INTEGER ,DIMENSION(NUMNOD)    ,INTENT(IN) :: ITABM1
      my_real ,DIMENSION(3,NUMNOD)  ,INTENT(IN) :: x
      my_real ,DIMENSION(LSKEW,*)   ,INTENT(IN) :: skew
      my_real ,DIMENSION(NTRANSF,*) ,INTENT(IN) :: rtrans
      TYPE (UNIT_TYPE_)             ,INTENT(IN) :: UNITAB 
      TYPE(submodel_data),DIMENSION(*) ,INTENT(IN) :: LSUBMODEL
      TYPE (BOX_)  ,DIMENSION(NBBOX)  :: IBOX
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II,J,UID,LEN,BOXID,IUNIT,FLAGUNIT,
     .        iad,nbox,nbox_rect,nbox_cyl,nbox_spher,nbox_box,nlist
      my_real :: bid
      INTEGER :: IWORK(70000)
      INTEGER INDEX(NBBOX*3),IX1(NBBOX),IX2(NBBOX)
      INTEGER, DIMENSION(:)   ,ALLOCATABLE :: BUFTMP,IBOXTMP
      CHARACTER(LEN=NCHARKEY)    :: KEY,KEY2
      CHARACTER(nchartitle)  :: TITR,MESS
      LOGICAL :: IS_AVAILABLE
c
      DATA mess/'BOX DEFINITION                          '/
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER LISTCNT,NBOXLST
C-----------------------------------------------
C     IBOX(I)%ID       : BOX IDENTIFIER
C     IBOX(I)%TITLE    : BOX title
C     IBOX(I)%NBOXBOX  : NUMBER OF SUB BOXES (BOXES OF BOXES)
C     IBOX(I)%ISKBOX   : BOX SKEW_ID (/BOX/RECTA)
C     IBOX(I)%NOD1     : FIRST NODE for box limit definition  - N1
C     IBOX(I)%NOD2     : SECOND NODE for box limit definition - N2
C     IBOX(I)%TYPE     : BOX TYPE (0='BOX',1='RECTA',2='CYLIN' ,3='SPHER')
C     IBOX(I)%NBLEVELS : TEMPORARY LEVEL NB OF BOXES
C     IBOX(I)%LEVEL    : FLAG "SUBLEVEL DONE" FOR BOX OF BOXES
C     IBOX(I)%ACTIBOX  : FLAG FOR ACTIVATED BOX FOR (GRNOD,GRSHEL,LINE,SURF...)
C     IBOX(I)%NENTITY  : NUMBER OF BOX ENTITIES (NODES,ELEMS,LINES,SURF)
C                        WITHIN ACTIVATED BOX
C     IBOX(I)%SURFIAD  :temporary address for solid external surface (in box)
C     IBOX(I)%BOXIAD   : temporary address
C     IBOX(I)%DIAM     : BOX diameter (CYLIN + SPHER)
C     IBOX(I)%X1       : coord.X for N1
C     IBOX(I)%Y1       : coord.Y for N1
C     IBOX(I)%Z1       : coord.Z for N1
C     IBOX(I)%X2       : coord.X for N2
C     IBOX(I)%Y2       : coord.Y for N2
C     IBOX(I)%Z2       : coord.Z for N2
C     IBOX(I)%IBOXBOX(NBOXBOX)  : LIST OF BOXES (in /box/box)
C     IBOX(I)%ENTITY(NENTITY)   : LIST OF ENTITIES (NODES,ELEMS,LINES,SURF)
C=======================================================================
c
      CALL hm_option_count('/BOX/RECTA' ,nbox_rect  )
      CALL hm_option_count('/BOX/CYLIN' ,nbox_cyl   )
      CALL hm_option_count('/BOX/SPHER' ,nbox_spher )
      CALL hm_option_count('/BOX/BOX'   ,nbox_box   )
c      
      nbox = nbox_rect + nbox_cyl + nbox_spher + nbox_box     
c-----------------------------------------------
      iad = 0
      len = 5*nbbox
      CALL my_alloc(buftmp  ,len)
c--------------------------------------------------
c
      CALL read_box_spher(
     .     ibox     ,iad      ,nbox_spher,itabm1   ,x        ,
     .     rtrans   ,unitab   ,lsubmodel )
c
      CALL read_box_cyl(
     .     ibox     ,iad      ,nbox_cyl  ,itabm1   ,x        ,
     .     rtrans   ,unitab   ,lsubmodel )
c
      CALL read_box_rect(
     .     ibox     ,iad      ,nbox_rect ,iskn     ,skew     ,
     .     itabm1   ,x        ,rtrans    ,unitab   ,lsubmodel)
c
      CALL read_box_box(ibox     ,iad      ,nbox_box  ,lsubmodel)
c
c--------------------------------------------------
c     Search for double IDs
c
      CALL my_alloc (iboxtmp  ,nbox )
      iboxtmp(1:nbox) = ibox(1:nbox)%ID
      CALL udouble_igr(iboxtmp,nbox,mess,0,zero)
c
c--------------------------------------------------
c     check /box/box
c--------------------------------------------------
      IF (nbox_box > 0) THEN
        ii = 0
        DO i = 1,nbbox
          IF (ibox(i)%TYPE == 0) THEN                  
            nlist = ibox(i)%NBOXBOX
            boxid = ibox(i)%ID
            titr  = ibox(i)%TITLE
            IF (nlist > 0) THEN
               nlist = nboxlst(ibox(i)%IBOXBOX,nlist ,iboxtmp  ,nbbox,
     .                         buftmp ,buftmp(1+nbbox),buftmp(1+2*nbbox),
     .                         ii,boxid,titr)
              ii = 1
              ibox(i)%NBOXBOX = nlist
            ELSE
              ibox(iad)%NBOXBOX = 0
            ENDIF
          ENDIF
        ENDDO
      ENDIF      
C-----------------------------
      IF (ALLOCATED(iboxtmp)) DEALLOCATE (iboxtmp)
      IF (ALLOCATED(buftmp) ) DEALLOCATE (buftmp )
c-----------
      RETURN
      END