hm_read_cload.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_cload          ../starter/source/loads/general/cload/hm_read_cload.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim      ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.f
!||    hm_get_string          ../starter/source/devtools/hm_reader/hm_get_string.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.f
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    nodgr_r2r              ../starter/source/coupling/rad2rad/routines_r2r.F
!||    nodgrnr5               ../starter/source/starter/freform.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    r2r_mod                ../starter/share/modules1/r2r_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_cload(IBCL   ,FORC    ,NUM    ,ITAB   ,ITABM1   ,
     .                         IGRNOD ,NWORK   ,UNITAB ,ISKN   ,LSUBMODEL,
     .                         LOADS  )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE r2r_mod
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE loads_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "units_c.inc"
#include      "r2r_c.inc"
#include      "sphcom.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER NUM
      INTEGER IBCL(NIBCLD,*), ITAB(*), ITABM1(*),NWORK(*),
     .        iskn(liskn,*)
      my_real forc(lfaccld,*)
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
      TYPE (LOADS_),INTENT(INOUT) :: LOADS
C-----------------------------------------------
      TYPE (GROUP_)  ,DIMENSION(NGRNOD)  :: IGRNOD
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real
     .        fcx,fcy,fac_fcx,fac_fcy
      INTEGER I,J,K,K1,K2,NOD, NCUR, NOSKEW, ISENS,NLD0,NN,IGU,IGS,
     .        UID,IAD,NS,IWA,ID,NUM0,IFLAGUNIT,COMPT,SUB_INDEX,IDIR,IFUNCTYPE
      INTEGER NNB
      CHARACTER MESS*40,X*1, Y*1, Z*1, XX*2, YY*2, ZZ*2
      CHARACTER(LEN=NCHARFIELD) :: XYZ
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER  NODGRNR5,NODGR_R2R
      EXTERNAL NODGRNR5,NODGR_R2R
C-----------------------------------------------
C     IBCL(NIBCLD,NUMCLD+NUMPRES), NUMCLD = Total nb of (cloads * nodes)
C                             NUMPRES = Total nb of (ploads * segments)
C     IBCL(1:NIBCLD,1:NUMCLD)              IPRES = IBCL(1:NIBCLD,NUMCCLD+1,NUMCLD+NUMPRES)         
C     1: Node Number                       1st node number of the segment
C     2: NS = 10*Noskew+Idir               2nd node number of the segment
C     3: Function internal number          3rd node number of the segment
C     4: -1 <=> CLOAD                      4th node number of the segment
C     5: UNUSED                            Function internal number
C     6: ISENS Sensor User ID              ISENS Sensor User ID
C     7: User ID                           User ID
C     9: Itypfun                           Function type
C-----------------------------------------------
C     FORC(LFACCLD,NUMCLD+NUMPRES)
C     FORC(LFACCLD,NUMCLD)                 PRES = FORC(LFACCLD,NUMCLD+1:NUMCLD+NUMPRES)
C     1: Fscale_y                          Fscale_y  
C     2: 1/Ascale_x                        1/Ascale_x
C     3 : UNUSED                           /=0 <=> Pinching pressure
C=======================================================================
      DATA x/'X'/
      DATA y/'Y'/
      DATA z/'Z'/
      DATA xx/'XX'/
      DATA yy/'YY'/
      DATA zz/'ZZ'/
      DATA mess/'CONCENTRATED LOADS DEFINITION           '/
C=======================================================================
      is_available = .false.
C
      WRITE (iout,2000)
      nld0=num
      num=0
      i=0
      ifunctype=0
C--------------------------------------------------
C START BROWSING MODEL CLOAD
C--------------------------------------------------
      CALL hm_option_start('/CLOAD')
C--------------------------------------------------
C BROWSING MODEL PARTS 1->NLD0 (=NCONLD)
C--------------------------------------------------
      DO k=1,nld0
        IF(nsubdom>0)THEN
          IF(nncl(k)==0)cycle
        END IF
        titr = ''
C--------------------------------------------------
C EXTRACT DATAS OF /CLOAD/... LINE
C--------------------------------------------------
        CALL hm_option_read_key(lsubmodel,
     .                       option_id = id,
     .                       unit_id = uid,
     .                       submodel_index = sub_index,
     .                       option_titr = titr)
C--------------------------------------------------
C EXTRACT DATAS (STRING VALUES)
C--------------------------------------------------
        xyz = ''
        CALL hm_get_string('rad_dir',xyz,ncharfield,is_available)
C--------------------------------------------------
C EXTRACT DATAS (INTEGER VALUES)
C--------------------------------------------------
        CALL hm_get_intv('curveid',ncur,is_available,lsubmodel)
        CALL hm_get_intv('inputsystem',noskew,is_available,lsubmodel)
        IF(noskew == 0 .AND. sub_index /= 0 ) noskew = lsubmodel(sub_index)%SKEW
        CALL hm_get_intv('rad_sensor_id',isens,is_available,lsubmodel)
        CALL hm_get_intv('entityid',igu,is_available,lsubmodel)
        CALL hm_get_intv('Itypfun',ifunctype,is_available,lsubmodel)
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
        CALL hm_get_floatv('xscale',fcx,is_available,lsubmodel,unitab)
        CALL hm_get_floatv_dim('xscale',fac_fcx,is_available,lsubmodel,unitab)
        CALL hm_get_floatv('magnitude',fcy,is_available,lsubmodel,unitab)
        CALL hm_get_floatv_dim('magnitude',fac_fcy,is_available,lsubmodel,unitab)
C--------------------------------------------------
        iflagunit = 0
        DO j=1,unitab%NUNITS
          IF (unitab%UNIT_ID(j) == uid) THEN
            iflagunit = 1
            EXIT
          ENDIF
        ENDDO
c
        IF (uid/=0.AND.iflagunit==0) THEN
          CALL ancmsg(msgid=659,anmode=aninfo,msgtype=msgerror,
     .                i2=uid,i1=id,c1='CONCENTRED LOAD',
     .                 c2='CONCENTRED LOAD',
     .                 c3=titr) 
        ENDIF
        DO j=0,numskw+min(1,nspcond)*numsph+nsubmod
          IF(noskew == iskn(4,j+1)) THEN
            noskew=j+1
            GO TO 100
          ENDIF
        ENDDO
        CALL ancmsg(msgid=137,anmode=aninfo,msgtype=msgerror,
     .              c1='CONCENTRED LOAD',
     .              c2='CONCENTRED LOAD',
     .              i2=noskew,i1=id,c3=titr)
 100    CONTINUE
C
        IF (fcx == zero) fcx = fac_fcx
        IF (fcy == zero) fcy = fac_fcy
        noskew=10*noskew
        ns=0
 
        idir = 0
        IF(xyz(1:1)==x) idir=1
        IF(xyz(1:1)==y) idir=2
        IF(xyz(1:1)==z) idir=3
        IF(xyz(1:2)==xx) idir=4
        IF(xyz(1:2)==yy) idir=5
        IF(xyz(1:2)==zz) idir=6
 
        IF(idir == 1) ns=1+noskew
        IF(idir == 2) ns=2+noskew
        IF(idir == 3) ns=3+noskew
        IF(idir == 4) ns=4+noskew
        IF(idir == 5) ns=5+noskew
        IF(idir == 6) ns=6+noskew
 
 
        IF(idir == 0) THEN
           CALL ancmsg(msgid=149,anmode=aninfo,msgtype=msgerror,
     .                 c2=xyz,i1=id,c1=titr)
        ENDIF
        IF(idir >= 4) THEN
           IF (iroddl==0) THEN
             CALL ancmsg(msgid=845,anmode=aninfo,msgtype=msgerror,
     .                   c2=xyz,i1=id,c1=titr)
           END IF
        END IF
C !!  ibcl and nwork have the same address
        num0=num
C-----------
        IF (iddom==0) THEN
        nn = nodgrnr5(igu    ,igs    ,nwork(1+nibcld*num0),igrnod ,
     .                itabm1 ,mess   )
        ELSE
Cmultidomains: shared nodes already processed in the full domain are removed
        nn = nodgr_r2r(igu    ,igs    ,nwork(1+nibcld*num0),igrnod   ,
     .                itabm1 ,mess      )
        ENDIF
C-----------
        IF (nn==0) THEN
         CALL ancmsg(msgid=3026,
     .               anmode=aninfo,
     .               msgtype=msgerror,
     .               i1=id,
     .               c1=titr)
        ENDIF
        num=num+nn
        DO j=nn,1,-1
C       !!  ibcl and nwork have the same address
C          IBCL(1,I+J)=NWORK(J+6*NUM0)
            nwork(1+nibcld*(j+i-1))=nwork(j+nibcld*num0)
        ENDDO
 
        IF(ifunctype == 0) ifunctype = 1 ! Abscissa function is time (by default)
                        !  IFUNCTYPE = 2 ! Abscissa function is nodal displacement
                        !  IFUNCTYPE = 3 ! Abscissa function is nodal velocity
 
        DO j=1,nn
          i=i+1
          ibcl(2,i)      = ns
          ibcl(3,i)      = ncur
          ibcl(4,i)      = -1
          ibcl(6,i)      = isens
          ibcl(7,i)      = 0
          ibcl(8,i)      = 0
          ibcl(9,i)      = ifunctype
          forc(1,i) = fcy
          forc(2,i) = one/fcx
          IF (idir <= 3) THEN
             WRITE (iout,'(I10,2X,I10,5X,A,2X,I10,2X,I10,2X,
     .                  1PG20.13,2X,1PG20.13)')
     .       itab(ibcl(1,i)),iskn(4,noskew/10),xyz(1:1),
     .       ibcl(3,i),isens,fcx,fcy
          ELSEIF (idir <= 6) THEN
             WRITE (iout,'(I10,2X,I10,4X,A2,2X,I10,2X,I10,2X,
     .                  1PG20.13,2X,1PG20.13)')
     .       itab(ibcl(1,i)),iskn(4,noskew/10),xyz(1:2),
     .       ibcl(3,i),isens,fcx,fcy
          ENDIF
        ENDDO
      ENDDO
C----
      loads%NLOAD_CLOAD = num
C----
 2000 FORMAT(//
     .'     CONCENTRATED LOADS  '/
     .'     ------------------  '/
     .'      NODE        SKEW   DIR  LOAD_CURVE      SENSOR',
     .'           SCALE_X               SCALE_Y')
      RETURN
      END