hm_read_eos_ideal_gas.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_ideal_gas    ../starter/source/materials/eos/hm_read_eos_ideal_gas.F
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_ideal_gas(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS,MAT_PARAM)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   IDEAL-GAS EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IIN,IOUT,IUNIT
      my_real pm(npropm)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
      TYPE(matparam_struct_),INTENT(INOUT) :: MAT_PARAM
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  gamma, p0,t0, e0, psh, rho0,fac_l,fac_t,fac_m,fac_c,cv,mu0,pp,rhoi,rhor,g0,ssp0,dpdmu,df
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('Gamma', gamma, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('T_Initial', t0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
      ELSE
        rho0=rhor                   
      ENDIF
      
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      
      IF(gamma > one) THEN
        e0 = p0/(gamma-one)/(one+mu0)
      ELSE
        e0 = zero !manage this error below
      ENDIF
 
      !ERREURS :
      ! P0 <=0
      ! GAMMA <=ONE
      IF(p0 <= zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/IDEAL-GAS',
     .               c2='INITIAL PRESSURE MUST BE POSITIVE')
      ENDIF
      
      IF(gamma <= one)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/IDEAL-GAS',
     .               c2='SPECIFIC HEAT RATIO (GAMMA) MUST BE GREATER THAN 1.0')
      ENDIF
 
      IF(t0 == zero)t0=three100
      cv = zero
      IF(rho0*t0 /= zero) THEN
        ! this situation is not expected unless in case of input inconsistency (eos_uid does not match mat_uid)
        cv = e0/rho0/t0
      ENDIF
      
      pm(32) = gamma
      pm(88) = psh
      pm(23) = e0
      pm(35) = t0
      pm(36) = cv
      pm(31) = p0-psh
      pm(79) = t0
      pm(104)=p0-psh
 
      mat_param%EOS%Cv = cv
      mat_param%EOS%Cp = gamma * cv
      
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)
      dpdmu =  (gamma-one)*e0+(one+mu0)*(gamma-one)*df*df*(pm(31)+psh)
 
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0      
 
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)gamma,p0,psh,t0,e0,cv
      ENDIF
      IF(is_available_rho0)WRITE(iout,1501)pm(1)
 
      RETURN
 1000 FORMAT(
     & 5x,'  IDEAL GAS EOS     ',/,
     & 5x,'  -------------     ',/)
 1500 FORMAT(
     & 5x,'GAMMA . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'P0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PSH . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'T0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'E0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'COMPUTED HEAT CAPACITY (Cv) . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13) 
      
      RETURN
 
      END SUBROUTINE hm_read_eos_ideal_gas