hm_read_eos_sesame.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_sesame       ../starter/source/materials/eos/hm_read_eos_sesame.F
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_string            ../starter/source/devtools/hm_reader/hm_get_string.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    mrdse2                   ../starter/source/materials/mat/mat026/mrdse2.F
!||    tb2si1                   ../starter/source/materials/eos/sesame_tools.F
!||    tbusr1                   ../starter/source/materials/eos/sesame_tools.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_sesame(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS,IMID,TITR,BUFMAT,MFI,IDF,MAT_PARAM)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod  
      USE inoutfile_mod
      USE names_and_titles_mod , ONLY : nchartitle
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   NOBLE-ABEL EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT,IUNIT
      INTEGER,INTENT(INOUT) :: MFI, IDF
      INTEGER,INTENT(IN) :: IMID      
      my_real pm(npropm),bufmat(*)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(matparam_struct_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NR, NT, IDR, IDT, IDP, IDE
      my_real e0, rho0, rho0i, p0, t0, xnr, xnt, dpdr, rho
      my_real dydz,rhoi,rhor
      my_real mu0,df,ssp0,g0,dpdmu
      CHARACTER FILE*(ncharline),FILE_TMP*(ncharline)
      INTEGER :: FILE_LEN
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
      CHARACTER(LEN=NCHARTITLE) :: TITR
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_EA', e0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('SESAME_RHO', rho0, is_available_rho0,lsubmodel,unitab)
      CALL hm_get_string('ISRTY',file, ncharline,is_available)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
 
      pm(23) = e0
C----------------
C     READ TABLE
C----------------
      file_len = len_trim(file)
      file_tmp(1:file_len) = file(1:file_len)
      file = infile_name(1:infile_name_len)//file_tmp(1:file_len)
      file_len = file_len + infile_name_len
      OPEN(unit=31,file=file(1:file_len),err=999,status='OLD',form='FORMATTED')
      READ(31,*)
      READ(31,'(2E15.0)')xnr,xnt
      rewind(31)
      nr = nint(xnr)
      nt = nint(xnt)
 
      mat_param%EOS%NUPARAM = 0
      mat_param%EOS%NIPARAM = 3
      mat_param%EOS%NFUNC = 0
      mat_param%EOS%NTABLE = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      IF (mat_param%THERM%TINI == zero) THEN
        mat_param%THERM%TINI =three100
        pm(79) = three100
      END IF
 
      IF(pm(79) == zero)pm(79)=three100
      idr = idf
      idt = idr + nr
      idp = idt + nt
      ide = idp + nr * nt
      idf = ide + nr * nt
      mfi = mfi + idf - idr
 
      mat_param%EOS%IPARAM(1) = nr  ! PM(33)
      mat_param%EOS%IPARAM(2) = nt  ! PM(34)
      mat_param%EOS%IPARAM(3) = idr ! PM(35)
C
      bufmat(idr:idf-1) = zero
C
      CALL mrdse2(bufmat(idr),nr,bufmat(idt),nt,bufmat(idp),bufmat(ide))
      CLOSE(31)
C
      CALL tb2si1(bufmat(idr),bufmat(idp),bufmat(ide),nr,nt)
      CALL tbusr1(bufmat(idr),bufmat(idp),bufmat(ide),nr,nt,unitab)
C
      rho = pm(89)
 
       CALL mintp_re(bufmat(idr),nr,bufmat(idt),nt,bufmat(ide),rho,t0,e0/rho0,dydz)
       CALL mintp_rt(bufmat(idr),nr,bufmat(idt),nt,bufmat(idp),rho,t0,p0,dpdr)
C
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)e0,file,p0,t0
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      pm(31) = p0
      
      !SSP0
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
            
      rho0i=pm(89)
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89) 
      dpdmu=rho0i*dpdr
      dpdmu=max(zero,dpdmu)        
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0      
      
      RETURN
  999 CONTINUE
      CALL ancmsg(msgid=19,msgtype=msgerror,anmode=aninfo,i1=imid,c1='EOS',c2='EOS',c3=titr,c4=file)
      RETURN
      
 1000 FORMAT(
     & 5x,'  SESAME TABLE EOS     ',/,
     & 5x,'  ----------------     ',/)
 1500 FORMAT(
     & 5x,'INITIAL INTERNAL ENERGY PER UNIT VOLUME. =',1pg20.13/,
     & 5x,'SESAME TABLE 301 . . . . . . . . . . . . =',a70/,
     & 5x,'INITIAL PRESSURE . . . . . . . . . . . . =',1pg20.13/,
     & 5x,'INITIAL TEMPERATURE. . . . . . . . . . . =',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13)        
C
      RETURN
      END