hm_read_fail_fabric.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_fail_fabric      ../starter/source/materials/fail/fabric/hm_read_fail_fabric.F
!||--- called by ------------------------------------------------------
!||    hm_read_fail             ../starter/source/materials/fail/hm_read_fail.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_fail_fabric(FAIL     ,
     .           MAT_ID   ,FAIL_ID  ,IRUPT    ,UNIT_ID ,
     .           LSUBMODEL,UNITAB   )
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   READ ANISOTROPIC FABRIC FAILURE MODEL
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fail_param_mod
      USE unitab_mod
      USE message_mod 
      USE submodel_mod
      USE hm_option_read_mod 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER             ,INTENT(IN) :: FAIL_ID       ! failure model ID
      INTEGER             ,INTENT(IN) :: MAT_ID        ! material law ID
      INTEGER             ,INTENT(IN) :: IRUPT         ! failure model number
      INTEGER             ,INTENT(IN) :: UNIT_ID       ! 
      TYPE (UNIT_TYPE_)   ,INTENT(IN) :: UNITAB        ! table of input units
      TYPE (SUBMODEL_DATA),INTENT(IN) :: LSUBMODEL(*)  ! submodel table 
      TYPE (FAIL_PARAM_)  ,INTENT(INOUT) :: FAIL       ! failure model data structure
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  :: IRFUN,NDIR
      my_real  :: EPSF1,EPSR1,EPSF2,EPSR2,FAC_T
      LOGICAL  :: IS_AVAILABLE,IS_ENCRYPTED
C=======================================================================
      is_encrypted = .false.
      is_available = .false.
c
      IF (unit_id > 0) THEN
        fac_t = unitab%FAC_T(unit_id)
      ELSE
        fac_t = one
      ENDIF     
C--------------------------------------------------
C     check crypting
C--------------------------------------------------
c
      CALL hm_option_is_encrypted(is_encrypted)
c
C--------------------------------------------------
C     Read DATA
C--------------------------------------------------
      CALL hm_get_floatv ('Epsilon_f1'  ,epsf1     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('Epsilon_r1'  ,epsr1     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('Epsilon_f2'  ,epsf2     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('Epsilon_r2'  ,epsr2     ,is_available,lsubmodel,unitab)
      CALL hm_get_intv   ('NDIR'        ,ndir      ,is_available,lsubmodel)
c
      CALL hm_get_intv   ('fct_ID'      ,irfun     ,is_available,lsubmodel)
c--------------------------------------------------
c     Default values
c--------------------------------------------------
      IF (epsf1 <= zero) epsf1 = ep20
      IF (epsr1 <= zero) epsr1 = ep20*two
      IF (epsf2 <= zero) epsf2 = ep20
      IF (epsr2 <= zero) epsr2 = ep20*two
      IF (ndir == 0) ndir = 2
      ndir = min(ndir,2)
      ndir = max(ndir,1)
c          
      IF (epsf1 > epsr1 .or. epsf2 > epsr2) THEN
        CALL ancmsg(msgid=617,
     .              msgtype=msgerror,
     .              anmode=aninfo_blind_1,
     .              i1=mat_id)
      ENDIF     
c--------------------------------------------------
      fail%KEYWORD = 'FABRIC' 
      fail%IRUPT   = irupt 
      fail%FAIL_ID = fail_id 
      fail%NUPARAM = 6
      fail%NIPARAM = 0
      fail%NUVAR   = 2
      fail%NFUNC   = 1
      fail%NTABLE  = 0
      fail%NMOD    = 0
c            
      ALLOCATE (fail%UPARAM(fail%NUPARAM))
      ALLOCATE (fail%IPARAM(fail%NIPARAM))
      ALLOCATE (fail%IFUNC (fail%NFUNC))
      ALLOCATE (fail%TABLE (fail%NTABLE))
 
      fail%IFUNC(1)  = irfun
c
      fail%UPARAM(1) = epsf1 
      fail%UPARAM(2) = epsr1
      fail%UPARAM(3) = epsf2
      fail%UPARAM(4) = epsr2
      fail%UPARAM(5) = fac_t   ! abscissa unit scaling factor (strain rate)
      fail%UPARAM(6) = ndir
c-----------------------------------------------------
      IF (is_encrypted)THEN
        WRITE(iout, 1000)
      ELSE
        WRITE(iout, 1100) epsf1,epsr1,epsf2,epsr2,ndir,irfun
      ENDIF
c-----------
      RETURN
c-------------------------------------------------- 
 1000 FORMAT(
     & 5x,'    CRYPTED DATA IN FAILURE MODEL             '/,
     & 5x,'    -----------------------------             '/)
 1100 FORMAT(
     & 5x,'    ANISOTROPIC FABRIC FAILURE MODEL          ',/
     & 5x,'    ------------------------                  ',/
     & 5x,'FAILURE TENSION STRAIN DIRECTION 1 . . =',e12.4/
     & 5x,'RUPTURE TENSION STRAIN DIRECTION 1 . . =',e12.4/
     & 5x,'FAILURE TENSION STRAIN DIRECTION 2 . . =',e12.4/
     & 5x,'RUPTURE TENSION STRAIN DIRECTION 2 . . =',e12.4/
     & 5x,'NUMBER OF BROKEN DIR. FOR EL. DELETION =',i10/
     & 5x,'STRAIN RATE SCALING FUNCTION . . . . . =',i10)
c-------------------------------------------------- 
      END