hm_read_fail_gurson.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_fail_gurson      ../starter/source/materials/fail/gurson/hm_read_fail_gurson.F
!||--- called by ------------------------------------------------------
!||    hm_read_fail             ../starter/source/materials/fail/hm_read_fail.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.f
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_fail_gurson(
     .           FAIL    ,MAT_ID   ,FAIL_ID  ,IRUPT    ,NLOC_MOD   ,
     .           TITR    ,LSUBMODEL,UNITAB   )
C-----------------------------------------------
c    ROUTINE DESCRIPTION :
c    Read Gurson damage model parameters (irup = 35)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fail_param_mod
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE nlocal_reg_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C----------+---------+---+---+--------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER            ,INTENT(IN) :: FAIL_ID         ! failure model ID
      INTEGER            ,INTENT(IN) :: MAT_ID          ! material law ID
      INTEGER            ,INTENT(IN) :: IRUPT           ! failure model type number
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN) :: TITR     ! material model title
      TYPE(unit_type_)   ,INTENT(IN) :: UNITAB          ! table of input units
      TYPE(submodel_data),INTENT(IN) :: LSUBMODEL(*)    ! submodel table
      INTEGER            ,INTENT(INOUT) :: NLOC_MOD     ! non-local variable regularization flag
      TYPE(fail_param_)  ,INTENT(INOUT) :: FAIL         ! failure model data structure
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: ILOC
      my_real :: Q1,Q2,Q3,EPN,AS,KW,FC,FR,F0,RLEN,HKHI,LE_MAX
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s
C=======================================================================
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
      ! Card 1 
      CALL hm_get_floatv ('FAIL_q1'        ,q1      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_q2'        ,q2      ,is_available,lsubmodel,unitab)
      CALL hm_get_intv   ('FAIL_Iloc'      ,iloc    ,is_available,lsubmodel) 
      ! Card 2
      CALL hm_get_floatv ('FAIL_eps_strain',epn     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_As'        ,as      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_Kw'        ,kw      ,is_available,lsubmodel,unitab)
      ! Card 3
      CALL hm_get_floatv ('FAIL_Fc'        ,fc      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_Fr'        ,fr      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_F0'        ,f0      ,is_available,lsubmodel,unitab)
      ! Card 4
      CALL hm_get_floatv ('FAIL_RLen'      ,rlen    ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_Hchi'      ,hkhi    ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv ('FAIL_Le_max'    ,le_max  ,is_available,lsubmodel,unitab)      
c-----------------------------------------------------------------------
      ! Checking Gurson yield criterion parameters
      IF (q1 == zero) q1 = three_half
      IF (q2 == zero) q2 = one
      q3 = q1**2
      ! Checking value of nucleation function
      IF (as == zero) THEN
        ! No nucleation trigger
        epn = infinity
      ENDIF
      ! Checking value of coalescence function
      IF (fc == zero) fc = infinity
      IF (fr == zero) fr = two*infinity
      IF (fc >= fr)  THEN
        ! Error message
        CALL ancmsg(msgid=1747,msgtype=msgerror,
     .    anmode=aninfo_blind_1,i1=mat_id,c1=titr)
      ENDIF
      IF (f0 >= fc) THEN
        ! Warning message
        CALL ancmsg(msgid=1748,msgtype=msgwarning,
     .      anmode=aninfo_blind_1,i1=mat_id,c1=titr)
      ENDIF
c
      ! Choice of the non-local regularization method
c     ILOC = 1 => local damage : no plastic strain regularization (default)
c     ILOC = 2 => Forest (micromorphic) method of nodal variable regularization
c     ILOC = 3 => Peerlings method of nodal variable regularization
      IF (iloc == 0) iloc = 1
      nloc_mod = iloc-1
c
      ! Automatic Rlen computation
      IF (le_max > zero) THEN 
        CALL get_length(rlen,le_max)
      ! Or printout the maximum element length target for convergence
      ELSE
        CALL get_lemax(le_max,rlen)
      ENDIF
c
      ! Micromorphic penalty parameter (homogeneous to a stress [MPa])
      IF (iloc /= 2) THEN 
        hkhi = zero    ! only used for micromorphic
      ENDIF
c-----------------------------------------------------------------------
      fail%KEYWORD = 'GURSON' 
      fail%IRUPT   = irupt 
      fail%FAIL_ID = fail_id 
      fail%NUPARAM = 12
      fail%NIPARAM = 0
      fail%NUVAR   = 0
      fail%NFUNC   = 0
      fail%NTABLE  = 0
      fail%NMOD    = 0
c            
      ALLOCATE (fail%UPARAM(fail%NUPARAM))
      ALLOCATE (fail%IPARAM(fail%NIPARAM))
      ALLOCATE (fail%IFUNC (fail%NFUNC))
      ALLOCATE (fail%TABLE (fail%NTABLE))
c
      fail%UPARAM(1) = nloc_mod  ! non-local variable regularization flag
      fail%UPARAM(2) = q1        ! Gurson yield criterion 1st parameter
      fail%UPARAM(3) = q2        ! Gurson yield criterion 2nd parameter
      fail%UPARAM(4) = q3        ! Gurson yield criterion 3rd parameter
      fail%UPARAM(5) = epn       ! Trigger plastic strain for nucleation
      fail%UPARAM(6) = as        ! Nucleation rate
      fail%UPARAM(7) = kw        ! Nahshon-Hutchinson shear parameter
      fail%UPARAM(8) = fr        ! Failure void volume fraction
      fail%UPARAM(9) = fc        ! Critical void volume fraction
      fail%UPARAM(10)= f0        ! Initial void volume fraction
      fail%UPARAM(11)= rlen      ! Non-local internal length
      fail%UPARAM(12)= hkhi      ! Micromorphic penalty parameter
c-----------------------------------------------------------------------
      IF (is_encrypted) THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout, 1100) q1,q2,epn,as,kw,f0,fc,fr,iloc
        IF (iloc > 1)  WRITE(iout, 1200) rlen,le_max
        IF (iloc == 2) WRITE(iout, 1300) hkhi
      ENDIF
C-----------
      RETURN
C-----------
 1100 FORMAT(
     & 5x,40h    gurson ductile damage model          /,
     & 5x,40h    ------------------------------------ /,
     & 5x,'Q1 GURSON COEFFICIENT. . . . . . . . . . . . . . . =',1pg20.13/
     & 5x,'Q2 GURSON COEFFICIENT. . . . . . . . . . . . . . . =',1pg20.13/
     & 5x,'NUCLEATION PLASTIC STRAIN. . . . . . . . . . . . . =',1pg20.13/
     & 5x,'AS NUCLEATION SLOPE. . . . . . . . . . . . . . . . =',1pg20.13/
     & 5x,'SHEAR DAMAGE COEFFICIENT . . . . . . . . . . . . . =',1pg20.13/
C
     & 5x,'INITIAL VOID VOLUME FRACTION . . . . . . . . . . . =',1pg20.13/
     & 5x,'CRITICAL VOID VOLUME FRACTION. . . . . . . . . . . =',1pg20.13/
     & 5x,'RUPTURE VOID VOLUME FRACTION . . . . . . . . . . . =',1pg20.13/
     & 5x,'NON LOCAL PLASTIC STRAIN REGULARIZATION FLAG . . . =',i3/
     & 5x,'     ILOC=1  LOCAL DAMAGE MODEL '/
     & 5x,'     ILOC=2  NON LOCAL MICROMORPHIC MODEL '/
     & 5x,'     ILOC=3  NON LOCAL PEERLING MODEL ')
 1200 FORMAT(
     & 5x,'NON-LOCAL REGULARIZATION LENGTH. . . . . . . . . . =',1pg20.13/
     & 5x,'CONVERGENCE ELEMENT LENGTH TARGET. . . . . . . . . =',1pg20.13/)
 1300 FORMAT(
     & 5x,'PENALTY PARAMETER FOR NONLOCAL MICROMORPHIC METHOD =',1pg20.13/)
C-----------       
      RETURN
      END