hm_read_fail_sahraei.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_fail_sahraei     ../starter/source/materials/fail/sahraei/hm_read_fail_sahraei.F
!||--- called by ------------------------------------------------------
!||    hm_read_fail             ../starter/source/materials/fail/hm_read_fail.F
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_fail_sahraei(    
     .           FAIL    ,MAT_ID   ,FAIL_ID  ,IRUPT    ,
     .           LSUBMODEL,UNITAB   )
C-----------------------------------------------
c    ROUTINE DESCRIPTION :
c    Sahraei failure criterion (irup = 29)
C-----------------------------------------------
C    M o d u l e s
C-----------------------------------------------
      USE fail_param_mod
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C----------+---------+---+---+--------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER            ,INTENT(IN) :: FAIL_ID         ! failure model ID
      INTEGER            ,INTENT(IN) :: MAT_ID          ! material law ID
      INTEGER            ,INTENT(IN) :: IRUPT           ! failure model type number
      TYPE(unit_type_)   ,INTENT(IN) :: UNITAB          ! table of input units
      TYPE(submodel_data),INTENT(IN) :: LSUBMODEL(*)    ! submodel table
      TYPE(fail_param_)  ,INTENT(INOUT) :: FAIL         ! failure model data structure
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NUM,DEN,ORDI,COMP_DIR,IDEL,NUPARAM,NUVAR,NFUNC
      INTEGER ,PARAMETER :: NSIZE = 2
      INTEGER ,DIMENSION(NSIZE) :: IFUNC
      my_real :: vol_strain,max_comp_strain,ratio,el_ref,el_ref_unit
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s
C=======================================================================
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
c
c!#
c!# NUMERATOR    =  1  ==> Eps_xx 
c!# NUMERATOR    =  2  ==> Eps_yy 
c!# NUMERATOR    =  3  ==> Eps_zz 
c!# NUMERATOR    =  4  ==> Eps_1   1st. 3d-principal
c!# NUMERATOR    =  5  ==> Eps_2   2nd. 3d-principal
c!# NUMERATOR    =  6  ==> Eps_3   3rd. 3d-principal
c!#
c!# Denominator  =  1  ==> 2D e1 = x-z - plane 
c!# Denominator  =  2  ==> 2D e1 = x-y - plane 
c!# Denominator  =  3  ==> 2D e1 = y-z - plane 
c!# Denominator  =  4  ==> Eps_1   1st. 3d-principal
c!# Denominator  =  5  ==> Eps_2   2nd. 3d-principal 
c!# Denominator  =  6  ==> Eps_3   3rd. 3d-principal 
c!#
c!# Ordinate     =  1  ==> MAX(Eps_xx,Eps_yy,Eps_zz)
c!# Ordinate     =  2  ==> Eps_xx
c!# Ordinate     =  3  ==> Eps_yy
c!# Ordinate     =  4  ==> Eps_zz
c!# Ordinate     =  5  ==> Eps_1   1st. 3d-principal
c!# Ordinate     =  6  ==> 2D - e1 = x-z - plane
c!# Ordinate     =  7  ==> 2D - e1 = x-y - plane
c!# Ordinate     =  8  ==> 2D - e1 = y-z - plane
c!#
c!# COMP_DIR     = 0   ==> Feature is not taken into account
c!# COMP_DIR     = 1   ==> Normal to layers is in xx
c!# COMP_DIR     = 2   ==> Normal to layers is in yy
c!# COMP_DIR     = 3   ==> Normal to layers is in zz
c!#
c!# MAX_COMP_STRAIN = In-plane failure compression strain (not deleting, only damage=1)
c!# if value is negative, the element will NOT be deleted, only DAMAGE set to 1
c!# RATIO        = RATIO of the two other failure strains (default = 1.0)
c!# 
C===================================================================================
C READING CARD 1
C===================================================================================
      CALL hm_get_intv   ('Fct_Ratio'      ,ifunc(1)        ,is_available,lsubmodel) 
      CALL hm_get_intv   ('NUM'            ,num             ,is_available,lsubmodel) 
      CALL hm_get_intv   ('DEN'            ,den             ,is_available,lsubmodel)
      CALL hm_get_intv   ('ORDI'           ,ordi            ,is_available,lsubmodel)  
      IF (ordi == 0) ordi = 1
      CALL hm_get_floatv ('Vol_strain'     ,vol_strain      ,is_available,lsubmodel,unitab)
      CALL hm_get_intv   ('Fct_Elsize'     ,ifunc(2)        ,is_available,lsubmodel)
      CALL hm_get_floatv ('EL_REF'         ,el_ref          ,is_available,lsubmodel,unitab)
      IF ((el_ref == zero).AND.(ifunc(2) > 0)) THEN 
        CALL hm_get_floatv_dim('EL_REF' ,el_ref_unit,is_available, lsubmodel, unitab)
        el_ref = one*el_ref_unit
      ENDIF 
C===================================================================================
C READING CARD 2 
C===================================================================================    
      CALL hm_get_intv   ('Comp_dir'       ,comp_dir        ,is_available,lsubmodel) 
      CALL hm_get_intv   ('IDEL'           ,idel            ,is_available,lsubmodel) 
      CALL hm_get_floatv ('Max_Comp_Strain',max_comp_strain ,is_available,lsubmodel,unitab)
      IF (max_comp_strain == zero) max_comp_strain = infinity
      CALL hm_get_floatv ('Ratio'          ,ratio           ,is_available,lsubmodel,unitab)
      IF (ratio == zero) ratio = one
C===================================================================================
C NUMBER OF PARAMETERS,FUNCTIONS, AND USER VARIABLE
C===================================================================================
      nuparam = 9
      IF (ifunc(2) > 0) THEN
        nfunc = 2
        nuvar = 1
      ELSE
        nfunc = 1
        nuvar = 0
      ENDIF
C===================================================================================
C STORING PARAMETERS
C===================================================================================
      fail%KEYWORD = 'SAHRAEI' 
      fail%IRUPT   = irupt 
      fail%FAIL_ID = fail_id 
      fail%NUPARAM = nuparam
      fail%NIPARAM = 0
      fail%NUVAR   = nuvar
      fail%NFUNC   = nfunc
      fail%NTABLE  = 0
      fail%NMOD    = 0
c            
      ALLOCATE (fail%UPARAM(fail%NUPARAM))
      ALLOCATE (fail%IPARAM(fail%NIPARAM))
      ALLOCATE (fail%IFUNC (fail%NFUNC))
      ALLOCATE (fail%TABLE (fail%NTABLE))
      
      fail%IFUNC(1:nfunc) = ifunc(1:nfunc)
c
      fail%UPARAM(1) = vol_strain
      fail%UPARAM(2) = num
      fail%UPARAM(3) = den
      fail%UPARAM(4) = ordi
      IF (comp_dir == zero) THEN
        fail%UPARAM(5) = zero
      ELSE
        fail%UPARAM(5) = comp_dir
      ENDIF
      fail%UPARAM(6) = max_comp_strain
      fail%UPARAM(7) = ratio
      fail%UPARAM(8) = idel
      fail%UPARAM(9) = el_ref
C===================================================================================
C PRINTING OUT DATA
C===================================================================================
      IF (is_encrypted) THEN
        WRITE (iout,'(5X,A,//)') 'CONFIDENTIAL DATA'
      ELSE 
        WRITE (iout, 1000) ifunc(1),vol_strain
        WRITE (iout, 2000) num,den,ordi
        IF (ifunc(2) > 0) THEN 
          WRITE (iout, 3000) ifunc(2),el_ref
        ENDIF
        IF (comp_dir /= zero) THEN
          WRITE (iout, 4000) comp_dir, idel, max_comp_strain, ratio
        ENDIF
      ENDIF
C===================================================================================
C PRINTOUT FORMAT
C===================================================================================
 1000 FORMAT(
     & 5x,'    SAHRAEI LOCAL ELECTRIC BATTERY FAILURE      ',/,
     & 5x,'    --------------------------------------      ',/,
     & 5x,'STRAIN RATIO FUNCTION ID . . . . . . . . . . . . .=',i10/,
     & 5x,'VOLUMETRIC STRAIN LIMIT. . . . . . . . . . . . . .=',1pg20.13/)
 2000 FORMAT(
     & 5x,'NUMERATOR FLAG FOR STRAIN RATIO. . . . . . . . . .=',i10/,
     & 5x,'DENOMINATOR FLAG FOR STRAIN RATIO. . . . . . . . .=',i10/,
     & 5x,'FAILURE ORDINATE FOR FAILURE LIMIT . . . . . . . .=',i10/)
 3000 FORMAT(
     & 5x,'ELEMENT SIZE REGULARIZATION FUNCTION ID. . . . . .=',i10/,
     & 5x,'ELEMENT REFERENCE SIZE . . . . . . . . . . . . . .=',1pg20.13/)
 4000 FORMAT(
     & 5x,'NORMAL IN-PLANE COMPRESSION DIRECTION. . . . . . .=',i10/,
     & 5x,'FLAG FOR ELEMENT DELETION IN COMPRESSION . . . . .=',i10/,
     & 5x,'IN-PLANE COMPRESSION FAILURE STRAIN  . . . . . . .=',1pg20.13/,
     & 5x,'RATIO FOR IN-PLANE 2ND DIRECTION FAILURE STRAIN . =',1pg20.13/)
C-----------
      RETURN
      END