hm_read_inicrack.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_inicrack           ../starter/source/initial_conditions/inicrack/hm_read_inicrack.F
!||--- called by ------------------------------------------------------
!||    lectur                     ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    hm_get_float_array_index   ../starter/source/devtools/hm_reader/hm_get_float_array_index.F
!||    hm_get_int_array_index     ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    hm_get_intv                ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key         ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start            ../starter/source/devtools/hm_reader/hm_option_start.F
!||    udouble_igr                ../starter/source/system/sysfus.F
!||    usr2sys                    ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod         ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod                ../starter/share/message_module/message_mod.F
!||    submodel_mod               ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_inicrack(ITABM1   ,INICRACK ,UNITAB   ,LSUBMODEL)
C-----------------------------------------------
      USE my_alloc_mod
      USE message_mod
      USE optiondef_mod
      USE submodel_mod
      USE hm_option_read_mod    
      USE unitab_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com_xfem1.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITABM1(*)
      TYPE (INICRACK_) , DIMENSION(NINICRACK) :: INICRACK
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      TYPE(SUBMODEL_DATA) LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,ID,NSEG,LIST_INICRACK(NINICRACK)
      INTEGER J2(2)
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER MESS*40
      my_real
     .        bid,ratio
      LOGICAL IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS
      DATA mess/'INITIAL CRACK DEFINITION                '/
C-----------------------------------------------
c     INICRACK            ! Crack storage array
C     INICRACK(IGS)%ID    : INICRACK IDENTIFIER
C     INICRACK(IGS)%NSEG  : INICRACK NUMBER OF SEGMENTS
C     INICRACK(IGS)%TITLE : INICRACK title
C     INICRACK(IGS)%RATIO : INICRACK RATIO OF ONE SEGMENT
C     INICRACK(IGS)%SEG   : SEGMENTS OF INICRACK
C=======================================================================
C     
      ! Variable initialization
      bid = zero
C      
      ! Start reading /INICRACK cards
      CALL hm_option_start('/INICRACK')
C      
      ! Loop over INICRACK
      DO i = 1,ninicrack
C      
        ! Reading title and keys
        titr = ''   
        CALL hm_option_read_key(lsubmodel, 
     .                          option_id      = id,
     .                          option_titr    = titr)               
C        
        ! Storing IDs and Title
        inicrack(i)%ID    = id
        inicrack(i)%TITLE = titr
C
        ! Count number of segment
        CALL hm_get_intv('segmax',nseg,is_available,lsubmodel)
        inicrack(i)%NSEG  = nseg
C    
        ! Allocation of segment data structure
        ALLOCATE(inicrack(i)%SEG(nseg))
        DO j = 1,nseg
          CALL my_alloc(inicrack(i)%SEG(j)%NODES,2)
        ENDDO
C
        ! Filling the segment data structure
        DO j = 1,nseg      
          CALL hm_get_int_array_index('node_ID1',j2(1),j,is_available,lsubmodel)
          CALL hm_get_int_array_index('node_ID2',j2(2),j,is_available,lsubmodel)
          CALL hm_get_float_array_index('Ratio', ratio,j,is_available,lsubmodel,unitab)
          inicrack(i)%SEG(j)%NODES(1) = usr2sys(j2(1),itabm1,mess,id)
          inicrack(i)%SEG(j)%NODES(2) = usr2sys(j2(2),itabm1,mess,id)
          inicrack(i)%SEG(j)%RATIO    = ratio
        ENDDO
      ENDDO
C-------------------------------------
C Recherche des ID doubles
C-------------------------------------
      DO j = 1,ninicrack
        list_inicrack(j) = inicrack(j)%ID
      ENDDO
      CALL udouble_igr(list_inicrack,ninicrack,mess,0,bid)
C=======================================================================
c-----------
c-----------
      RETURN
      END