hm_read_mat01.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat01            ../starter/source/materials/mat/mat001/hm_read_mat01.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.f
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat01(IPM,PM,UNITAB,ID,TITR,
     .                         LSUBMODEL,ISRATE,MATPARAM)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   READ MAT LAW01 WITH HM READER
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     IPM             MATERIAL ARRAY(INTEGER)
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE    
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod 
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C INPUT ARGUMENTS
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER,INTENT(IN)::ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN)::TITR
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
C MODIFIED ARGUMENT
      INTEGER,INTENT(INOUT)::IPM(NPROPMI),ISRATE
      my_real,INTENT(INOUT)::pm(npropm)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real
     .   young, anu, g, c0, c1, e0, e1mn2, en1n2, sdsp, rho0, rhor
      LOGICAL IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_RHO',  rho0  ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho',rhor  ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_E',    young ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_NU',   anu   ,is_available,lsubmodel,unitab)
C--------------------------------------------------
      IF(rhor == zero ) rhor=rho0
C
      IF (young<=zero) THEN
          CALL ancmsg(msgid=683,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=id,
     .                c1=titr,
     .                c2='YOUNG''S MODULUS')
      ENDIF
      IF(anu==half)anu=zep499                  
C
      g=young/(two*(one+anu))
      c0=zero
      c1=young/(three*(one-two*anu))
      e0=zero
      e1mn2=young/(one-anu**2)
      en1n2=anu*e1mn2
      sdsp =sqrt(young/max(rhor,em20))
      israte = 0 
      
      pm(1) =rhor
      pm(20)=young
      pm(21)=anu
      pm(22)=g
      pm(23)=e0
      pm(24)=e1mn2
      pm(25)=en1n2
      pm(26)=five_over_6
      pm(27)=sdsp
      pm(31)=c0
      pm(32)=c1
      pm(89) =rho0     
c-----------------
      CALL init_mat_keyword(matparam,"TOTAL")
      IF (anu > 0.49) THEN
        CALL init_mat_keyword(matparam,"INCOMPRESSIBLE")
      ELSE
        CALL init_mat_keyword(matparam,"COMPRESSIBLE")
      END IF
      CALL init_mat_keyword(matparam,"hook")
      ! Properties compatibility
      CALL init_mat_keyword(matparam,"SOLID_ISOTROPIC")
      CALL init_mat_keyword(matparam,"SHELL_ISOTROPIC")
      CALL init_mat_keyword(matparam,"BEAM_CLASSIC")
      CALL init_mat_keyword(matparam,"TRUSS")
      CALL init_mat_keyword(matparam,"SPH")
c-----------------
      WRITE(iout,1001) trim(titr),id,01
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1100)rho0
        WRITE(iout,1300)young,anu,g
      ENDIF
C
      ipm(252)= 2
      pm(105) = two*g/(c1+four_over_3*g)
C-----------
      RETURN
 1000 FORMAT(
     & 5x,'  ELASTIC MATERIAL (/MAT/LAW01)',/,
     & 5x,'  -----------------------------')
 1001 FORMAT(
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . .=',i10/,
     & 5x,'MATERIAL LAW. . . . . . . . . . . . . .=',i10/)
 1100 FORMAT(
     & 5x,'INITIAL DENSITY . . . . . . . . . . . .=',1pg20.13/) 
 1300 FORMAT(
     & 5x,'YOUNG''S MODULUS . . . . . . . . . . . .=',e12.4/,
     & 5x,'POISSON''S RATIO . . . . . . . . . . . .=',e12.4/,
     & 5x,'shear modulus . . . . . . . . . . . . .=',E12.4//)
C-----------
      RETURN
      END