hm_read_mat34.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat34            ../starter/source/materials/mat/mat034/hm_read_mat34.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat34(UPARAM ,MAXUPARAM,NUPARAM  ,ISRATE   , IMATVIS  ,
     .                         NUVAR  ,IFUNC    ,MAXFUNC  ,NFUNC    , PARMAT   , 
     .                         UNITAB ,MAT_ID   ,TITR     ,MTAG     , LSUBMODEL,
     .                         PM     ,MATPARAM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW33 WITH HM READER ( TO BE COMPLETED )
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     IPM             MATERIAL ARRAY(INTEGER)
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     MAT_ID          MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      my_real, DIMENSION(NPROPM) ,INTENT(INOUT)     :: PM     
      my_real, DIMENSION(100)    ,INTENT(INOUT)     :: PARMAT
      my_real, DIMENSION(MAXUPARAM) ,INTENT(INOUT)  :: uparam
      INTEGER, DIMENSION(MAXFUNC)   ,INTENT(INOUT)  :: IFUNC
      INTEGER, INTENT(INOUT)          :: ISRATE,IMATVIS,NFUNC,MAXFUNC,MAXUPARAM,NUPARAM,NUVAR
      TYPE(mlaw_tag_),INTENT(INOUT)   :: MTAG
      INTEGER,INTENT(IN)              :: MAT_ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN) :: TITR
      TYPE(submodel_data),INTENT(IN)  :: LSUBMODEL(*)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real :: bulk,young
      my_real :: g0,gi,beta
      my_real :: p0,phi,gama0 
      my_real :: rhor,rho0,nu   
      LOGICAL :: IS_ENCRYPTED,IS_AVAILABLE
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      israte=0
      imatvis=1
      is_encrypted = .false.
      is_available = .false.
 
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_RHO'      ,rho0     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho'    ,rhor     ,is_available, lsubmodel, unitab)
      
      CALL hm_get_floatv('MAT_BULK'     ,bulk     ,is_available, lsubmodel, unitab)
 
 
      CALL hm_get_floatv('MAT_G0'       ,g0       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_GI'       ,gi       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_DECAY'    ,beta     ,is_available, lsubmodel, unitab)
 
      CALL hm_get_floatv('MAT_P0'       ,p0       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_PHI'      ,phi      ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_GAMA0'    ,gama0    ,is_available, lsubmodel, unitab)
 
        !GAMA0 = GAMA0 * FAC_L * FAC_L * FAC_L
 
      
      IF (rhor==zero) rhor=rho0
 
      nuparam=7
      nfunc=0
      nuvar=8
 
      uparam(1)=bulk
      uparam(2)=g0
      uparam(3)=gi
      uparam(4)=beta
      uparam(5)=p0
      uparam(6)=phi
      uparam(7)=gama0
      
      young = (nine*bulk*g0)/(three*bulk + g0)
 
      parmat(1) = bulk
!      PARMAT(1) = TWO*GI
      parmat(2) = young
C     Formulation for solid elements time step computation.
      parmat(16) = 2
      parmat(17) = two*g0/(bulk + four_over_3*g0) 
      
      pm(1)  = rhor
      pm(89) = rho0
      pm(12) = sqrt(max(zero, g0)) !done by default in lecmuser.F for law34
      pm(22) = g0
      pm(27) = sqrt(young/rho0)  ! Sound speed   
c
      ! MATPARAM keywords
      CALL init_mat_keyword(matparam,"HOOK")
c
      ! Properties compatibility
      CALL init_mat_keyword(matparam,"SHELL_ISOTROPIC")
      CALL init_mat_keyword(matparam,"SOLID_ISOTROPIC")
      CALL init_mat_keyword(matparam,"SPH")   
      CALL init_mat_keyword(matparam,"TRUSS")
      CALL init_mat_keyword(matparam,"BEAM_INTEGRATED")
c
      WRITE(iout,1001) trim(titr),mat_id,34
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1002) rho0           
        WRITE(iout,1100) bulk,g0,gi,beta,p0,phi,gama0
      ENDIF
       
      RETURN
 
 1000 FORMAT
     & (5x,14h  viscoelastic,/,
     &  5x,14h  ------------,//)
 1001 FORMAT(/
     & 5x,a,/,
     & 5x,   'MATERIAL NUMBER . . . . . . . . . . . .=',i10/,
     & 5x,   'MATERIAL LAW. . . . . . . . . . . . . .=',i10/)
 1002 FORMAT(
     &  5x,  'INITIAL DENSITY . . . . . . . . . . . .=',1pg20.13/)
 1100 FORMAT
     & (5x,  'BULK MODULUS. . . . . . . . . . . . . .=',1pg20.13/
     & ,5x,  'SHEAR MODULUS (SHORT TIME). . . . . . .=',1pg20.13/ 
     & ,5x,  'SHEAR MODULUS (LONG TIME) . . . . . . .=',1pg20.13/
     & ,5x,  'DECAY CONSTANT. . . . . . . . . . . . .=',1pg20.13//
     & ,5x,  'INITIAL FOAM PRESSURE . . . . . . . . .=',1pg20.13/
     & ,5x,  'RATIO OF FOAM TO POLYMER DENSITY. . . .=',1pg20.13/
     & ,5x,  'INITIAL VOLUMETRIC STRAIN. . . .. . . .=',1pg20.13//)
 
      END