hm_read_mat69.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat69            ../starter/source/materials/mat/mat069/hm_read_mat69.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.f
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.f
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat69(UPARAM ,MAXUPARAM,NUPARAM  ,ISRATE   , IMATVIS,
     .                         NUVAR  ,IFUNC    ,MAXFUNC  ,NFUNC    , PARMAT, 
     .                         UNITAB ,ID       ,TITR     ,MTAG     , LSUBMODEL,
     .                         PM     ,MATPARAM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW59 WITH HM READER ( TO BE COMPLETED )
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      my_real, INTENT(INOUT)                :: PM(NPROPM),PARMAT(100),UPARAM(MAXUPARAM)
      INTEGER, INTENT(INOUT)                :: ISRATE,IFUNC(MAXFUNC),NFUNC,MAXFUNC,MAXUPARAM,NUPARAM, NUVAR
      TYPE(mlaw_tag_),INTENT(INOUT)         :: MTAG
      INTEGER,INTENT(IN)                    :: ID
      INTEGER,INTENT(INOUT)                    :: IMATVIS
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN)       :: TITR
      TYPE(submodel_data),INTENT(IN)        :: LSUBMODEL(*)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,BULK_FNCT,NTABLE_,NMUAL,LAWID,ILAW
      my_real MU(5),AL(5),RHO0,RHOR
      my_real BULK,TENSCUT,GS,NU,FSCAL,ZEP495,FSCAL_UNIT
      INTEGER ICHECK, NSTART
      my_real errtol
      INTEGER IDUMMY
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      idummy = 0
      nstart = 0
      errtol = zero
      ilaw   = 69
      imatvis = 1
 
      CALL hm_option_is_encrypted(is_encrypted)
      
      !line-1
      CALL hm_get_floatv('MAT_RHO'    ,rho0     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho'  ,rhor     ,is_available, lsubmodel, unitab)
      !line-2
      CALL hm_get_intv('MAT_Iflag'    ,lawid    ,is_available, lsubmodel)
      CALL hm_get_intv('FUN_A1'       ,bulk_fnct      ,is_available, lsubmodel)
      CALL hm_get_floatv('MAT_NU'     ,nu       ,is_available, lsubmodel, unitab) 
      CALL hm_get_floatv('MAT_FScale' ,fscal    ,is_available, lsubmodel, unitab) 
      CALL hm_get_intv('NIP'          ,nmual    ,is_available, lsubmodel) 
      CALL hm_get_intv('Gflag'        ,icheck   ,is_available, lsubmodel) 
      !-line3
      CALL hm_get_intv  ('FUN_B1'     ,ntable_  ,is_available, lsubmodel) 
 
      !units
      CALL hm_get_floatv_dim('MAT_FScale' ,fscal_unit    ,is_available, lsubmodel, unitab)
                        
C-----------------------------------------------
      nuparam = 21
      nfunc   = 2
      nuvar   = 9
C-----------------------------------------------
      zep495 = zep4 + nine*em02 + five*em03
      IF(icheck == 0    ) icheck = -3
      IF(nstart == 0    ) nstart = 100
      IF(errtol == zero ) errtol = fiveem3
      IF(nmual  == 0    ) nmual  = 2
      IF(fscal  == zero ) fscal  = one*fscal_unit
      IF(lawid  == 0    ) lawid  = -1
      IF(lawid == -1) THEN
       icheck = -3
       nstart = 100
       errtol = fiveem3
       nmual = 2
      ENDIF
      IF (ntable_ == 0) THEN
        CALL ancmsg(msgid=894,
     .              msgtype=msgerror,
     .              anmode=aninfo,
     .              i1=id,
     .              c1=titr)
      ENDIF
      IF (lawid == 0)  lawid = 1
      IF (lawid /= 1 .AND. lawid /= 2 .AND.  lawid /= -1 ) THEN ! New flag (automatic fitting)
        CALL ancmsg(msgid=882,
     .              msgtype=msgerror,
     .              anmode=aninfo,
     .              i1=id,
     .              c1=titr,i2=lawid)
      ENDIF
 
      tenscut = ep20
      DO i=1,5
        mu(i)=ten*fscal_unit  !pressure
        al(i)=ten*fscal_unit  !pressure
      ENDDO
      gs = zero
      IF (lawid == 1) THEN
        DO i=1,5
          gs = gs + mu(i)*al(i)
        ENDDO
      ELSEIF (lawid == 2) THEN
        DO i=1,2
          gs = gs + mu(i)*al(i)
        ENDDO
      ENDIF
C---
      IF (nu == zero ) nu = zep495
      bulk     = gs*(one+nu)/max(em20,three*(one-two*nu))
      ifunc(1) = bulk_fnct
      ifunc(2) = ntable_
      parmat(1)= gs
      parmat(2)= gs*(one+nu)
      parmat(3)= nu
      parmat(6)= bulk      
      mu = gs/two
C---
      IF (rhor == zero) rhor=rho0
      pm(1)  = rhor
      pm(2)  = gs
      pm(89) = rho0
      pm(100)= bulk
      
      uparam(1) = mu(1)    
      uparam(2) = mu(2)    
      uparam(3) = mu(3)    
      uparam(4) = mu(4)    
      uparam(5) = mu(5)    
      uparam(6) = al(1)    
      uparam(7) = al(2)    
      uparam(8) = al(3)    
      uparam(9) = al(4)    
      uparam(10)= al(5)    
      uparam(11)= bulk       
      uparam(12)= tenscut     
      uparam(13)= lawid    
      uparam(14)= nu       
      uparam(15)= fscal    
      uparam(17)= gs       
      uparam(18)= nmual    
      uparam(19)= icheck 
      uparam(20)= nstart
      uparam(21) = zero
      IF(is_encrypted)uparam(21)= one 
c-----------------
      CALL init_mat_keyword(matparam,"INCOMPRESSIBLE")
      CALL init_mat_keyword(matparam,"total")
      CALL INIT_MAT_KEYWORD(MATPARAM,"hook")
      ! Properties compatibility  
      CALL INIT_MAT_KEYWORD(MATPARAM,"shell_isotropic")
      CALL INIT_MAT_KEYWORD(MATPARAM,"solid_isotropic")
c-----------------
      WRITE(IOUT,1100) TRIM(TITR),ID,69
      WRITE(IOUT,1000)
      IF(IS_ENCRYPTED)THEN
        WRITE(IOUT,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(IOUT,1200) RHO0
        IF (NTABLE_ /= 0) THEN
          WRITE(IOUT,'(5X,A,//)')'HYPERELASTIC MATERIAL CONSTANTS WILL BE DETERMINED BY NONLINEAR LEAST SQUARE FITTING '
          WRITE(IOUT,1300) NU,LAWID,BULK_FNCT,FSCAL,NMUAL,ICHECK          
        ENDIF
      ENDIF
C-----     
      RETURN
C---------------------------------------------------------------       
 1000 FORMAT
     & (5X,29H  TABULATED HYPER-ELASTIC LAW,/,
     &  5X,29H  ---------------------------,//)
 1100 FORMAT(/
     & 5X,A,/,
     & 5X,'MATERIAL NUMBER . . . . . . . . . . . .=',I10/,
     & 5X,'MATERIAL LAW. . . . . . . . . . . . . .=',I10/)
 1200 FORMAT(
     & 5X,'INITIAL DENSITY . . . . . . . . . . . .=',1PG20.13/)  
 1300 FORMAT
     &(5X,'POISSON RATIO . . . . . . . . . . . . .=',1PG20.13/ 
     &,5X,'LAW TYPE. . . . . . . . . . . . . . . .=',I10/
     &,5X,'BULK FUNCTION ID. . . . . . . . . . . .=',I10/
     &,5X,'SCALE FACTOR FOR BULK FUNCTION. . . . .=',1PG20.13/ 
     &,5X,'FIT ORDER . . . . . . . . . . . . . . .=',I10/
     &,5X,'ICHECK = ', I10//)
C---------------------------------------------------------------       
      END SUBROUTINE HM_READ_MAT69