hm_read_mat73.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat73            ../starter/source/materials/mat/mat073/hm_read_mat73.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.f
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat73(UPARAM  ,MAXUPARAM,NUPARAM  ,ISRATE   ,IMATVIS  ,
     .                         NUVAR   ,IFUNC    ,MAXFUNC  ,NFUNC    ,PARMAT   , 
     .                         UNITAB  ,MAT_ID   ,TITR     ,MTAG     ,LSUBMODEL,
     .                         ITABLE  ,MAXTABL  ,NTABLE   ,PM       ,IPM      ,
     .                         MATPARAM)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW43 WITH HM READER ( TO BE COMPLETED )
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     MAT_ID          MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      my_real, INTENT(INOUT)                :: PM(NPROPM),PARMAT(100),UPARAM(MAXUPARAM)
      INTEGER, INTENT(INOUT)                :: IPM(NPROPMI),ISRATE,IFUNC(MAXFUNC),NFUNC,MAXFUNC,MAXUPARAM,NUPARAM, NUVAR,IMATVIS
     .                                         ,NTABLE,ITABLE(MAXTABL)
      TYPE(mlaw_tag_),INTENT(INOUT)         :: MTAG
      INTEGER,INTENT(IN)                    :: MAT_ID,MAXTABL
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN)       :: TITR
      TYPE(SUBMODEL_DATA),INTENT(IN)        :: LSUBMODEL(*)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,NRATE,NPS,IR0,ILAW
      MY_REAL 
     .         E,NU,G,C1,EPSMAX,EPSR1,EPSR2,
     .         R0,R45,R90,R,H,FISOKIN,M,
     .         einf,ce,t0, rhocp,x2fac,yfac,fac_pres,fac_freq
      INTEGER IFUNCE, OPTE, NUM_FUNC
      my_real :: RHO0, RHOR
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------      
      is_encrypted = .false.
      is_available = .false.
      mtag%G_PLA  = 1
      mtag%G_SEQ  = 1
      mtag%L_SEQ  = 1
      mtag%L_PLA  = 1
      israte=0
      imatvis=0
      ilaw=73
 
 
      CALL hm_option_is_encrypted(is_encrypted)
      !line+1
      CALL hm_get_floatv('MAT_RHO'    ,rho0        ,is_available, lsubmodel, unitab)
      !line-2
      CALL hm_get_floatv('MAT_E'      ,e           ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_NU'     ,nu          ,is_available, lsubmodel, unitab)
      !line-3
      CALL hm_get_intv  ('Yr_fun'     ,ifunce      ,is_available, lsubmodel)
      CALL hm_get_floatv('MAT_EFIB'   ,einf        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_C'      ,ce          ,is_available, lsubmodel, unitab)
      !line-4
      CALL hm_get_floatv('MAT_R00'    ,r0          ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_R45'    ,r45         ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_R90'    ,r90         ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_CHARD'  ,fisokin     ,is_available, lsubmodel, unitab)
      CALL hm_get_intv  ('MAT_Iyield' ,ir0         ,is_available, lsubmodel)
      !line-5
      CALL hm_get_floatv('MAT_EPS'    ,epsmax      ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_EPST1'  ,epsr1       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_EPST2'  ,epsr2       ,is_available, lsubmodel, unitab)
      !line-6
      CALL hm_get_intv  ('FUN_A1'      ,itable(1)   ,is_available, lsubmodel)
      CALL hm_get_floatv('MAT_FScale'  ,yfac        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_PScale'  ,x2fac       ,is_available, lsubmodel, unitab) 
      !line-7
      CALL hm_get_floatv('T_Initial'   ,t0          ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_SPHEAT'  ,rhocp       ,is_available, lsubmodel, unitab)
      !unit
      CALL hm_get_floatv_dim('MAT_FScale'  ,fac_pres    ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv_dim('MAT_PScale'  ,fac_freq    ,is_available, lsubmodel, unitab)
      !========== DEFAULT VALUES=============!              
      rhor=rho0
      IF(rhor==zero)rhor=rho0
      pm(1) =rhor
      pm(89)=rho0
!!
      IF(yfac == zero)yfac=fac_pres
      IF(x2fac == zero)x2fac=fac_freq
C          
C tab(1st entry = plastic strain, 2nd entry = strain rate, 3rd entry = temperature)
C
      IF(r0 == zero) r0    = one
      IF(r45 == zero) r45   = one
      IF(r90 == zero) r90   = one
      IF(epsr1 == zero)epsr1=infinity
      IF(epsr2 == zero)epsr2=two*infinity
      IF(t0 == zero) t0=twohundred93
C
      IF(epsr1 >= epsr2)THEN
         CALL ancmsg(msgid=1044,
     .                msgtype=msgerror,
     .                anmode=aninfo_blind_1,
     .                i1=mat_id,
     .                c1=titr)
       
      ENDIF
      ntable=1
      uparam(1)=fisokin
      uparam(2)=e
      uparam(3)=e/(one-nu*nu)
      uparam(4)=nu*uparam(3)
      g=half*e/(1.+nu)
      uparam(5)=g
      uparam(6)=nu
      r=(r0+r45+r45+r90)*fourth
      h=r/(one+r)
C-----------A1,A2,A3,A12--------
      uparam(7)=h*(one+one/r0)
      uparam(8)=h*(one+one/r90)
      uparam(9)=h*two
      uparam(10)=(r45*two + one)*(uparam(7)+uparam(8)-uparam(9))
      IF (ir0 > 0) THEN
       uparam(8)=uparam(8)/uparam(7)
       uparam(9)=uparam(9)/uparam(7)
       uparam(10)=uparam(10)/uparam(7)
       uparam(7)=one
      END IF
      uparam(11)=one/x2fac
      uparam(12)=yfac
      uparam(13)=epsmax
      uparam(14)=epsr1
      uparam(15)=epsr2
      uparam(16)=two*g
      uparam(17)=three*g
      c1=e/3./(one - two*nu)
      uparam(18)=c1
      uparam(19)=c1+ four_over_3*g
      uparam(20)=t0
      IF(rhocp==zero)THEN
        uparam(21)=zero
      ELSE
        uparam(21)=one/rhocp
      END IF
c--------------------------------
      opte = 0
      IF (ifunce > 0 )opte = 1
      nfunc = 1
      ifunc(nfunc) = ifunce
      uparam(22) = nfunc
      uparam(23) = opte
      uparam(24) = einf
      uparam(25) = ce
c--------------------------------
      nuparam   =25
C
      parmat(1)=c1
      parmat(2)=e
      parmat(3)=nu
      nuvar = 7
CC     Formulation for solid elements time step computation.
      parmat(16) = 2
      parmat(17) =  (one - two*nu)/(one - nu) ! == TWO*G/(C1+FOUR_OVER_3*G)
C
      CALL init_mat_keyword(matparam,"ELASTO_PLASTIC")
      CALL init_mat_keyword(matparam,"INCREMENTAL")
      CALL init_mat_keyword(matparam,"LARGE_STRAIN") 
      ! MATPARAM keywords
      CALL init_mat_keyword(matparam,"ORTHOTROPIC")
C
      ! Properties compatibility  
      CALL init_mat_keyword(matparam,"SHELL_ORTHOTROPIC")   
C      
      WRITE(iout,1001) trim(titr),mat_id,73
      WRITE(iout,1000)  
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE 
        WRITE(iout,1002)rho0  
        WRITE(iout,1100)e,nu,g,r0,r45,r90,fisokin
        IF (ir0 >0) WRITE(iout,1110)
        WRITE(iout,1300)epsmax,epsr1,epsr2
        WRITE(iout,1200)itable(1),x2fac,yfac
        WRITE(iout,1400)t0,rhocp,ifunce,einf,ce
        WRITE(iout,*)' '
      ENDIF
C
      RETURN 
 1001 FORMAT(
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . .=',i10/,
     & 5x,'MATERIAL LAW. . . . . . . . . . . . . .=',i10/)
 1002 FORMAT(
     & 5x,'INITIAL DENSITY . . . . . . . . . . . .=',1pg20.13/) 
 1000 FORMAT(
     & 5x,47h  thermal tabulated hill orthotropic plasticity,/,
     & 5x,47h  ---------------------------------------------,//)
 1100 FORMAT(
     & 5x,'YOUNG MODULUS . . . . . . . . . . . . .=',1pg20.13/
     & 5x,'POISSON RATIO . . . . . . . . . . . . .=',1pg20.13/
     & 5x,'SHEAR MODULUS . . . . . . . . . . . . .=',1pg20.13/
     & 5x,'LANKFORD COEFFICIENT R00. . . . . . . .=',1pg20.13/
     & 5x,'LANKFORD COEFFICIENT R45. . . . . . . .=',1pg20.13/
     & 5x,'LANKFORD COEFFICIENT R90. . . . . . . .=',1pg20.13/
     & 5x,'ISO-KINEMATIC HARDENNING FACTOR. . . . =',1pg20.13)
 1110 FORMAT(
     & 5x,'YIELD STRESS IS SUPPOSSD IN ORTHOTROPIC DIR. 1 '/)
 1200 FORMAT(
     & 5x,'YIELD STRESS TABLE NUMBER . . . . . . .=',i10/
     & 5x,'2ND ENTRY (STRAIN RATE) SCALE FACTOR. .=',1pg20.13/
     & 5x,'YIELD SCALE FACTOR. . . . . . . . . . .=',1pg20.13)
 1300 FORMAT(
     & 5x,'MAXIMUM PLASTIC STRAIN. . . . . . . . .=',1pg20.13/
     & 5x,'TENSILE FAILURE STRAIN 1. . . . . . . .=',1pg20.13/
     & 5x,'TENSILE FAILURE STRAIN 2. . . . . . . .=',1pg20.13)
 1400 FORMAT(
     & 5x,'INITIAL TEMPERATURE . . . . . . . . . .=',1pg20.13/
     & 5x,'HEAT CAPACITY PER VOLUME UNIT . . . . .=',1pg20.13/
     & 5x,'YOUNG MODULUS SCALE FACTOR FUNCTION . .=',i10/
     & 5x,'YOUNG MODULUS EINF. . . . . . . . . . .=',1pg20.13/
     & 5x,'PARAMETER CE. . . . . . . . . . . . . .=',1pg20.13)
      END