hm_read_mat_user29_31.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat29_31       ../starter/source/materials/mat/matuser/hm_read_mat_user29_31.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat            ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    arret                  ../starter/source/system/arret.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_get_string_index    ../starter/source/devtools/hm_reader/hm_get_string_index.F
!||    init_mat_keyword       ../starter/source/materials/mat/init_mat_keyword.F
!||    user_output            ../starter/source/user_interface/user_output.F
!||--- uses       -----------------------------------------------------
!||    format_mod             ../starter/share/modules1/format_mod.F90
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    reader_old_mod         ../starter/share/modules1/reader_old_mod.F90
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat29_31(ILAW,IUSER_KEY,
     .                            USERL_AVAIL,
     .                            UPARAM,MAXUPARAM,NUPARAM,
     .                            NUVAR ,IFUNC,MAXFUNC,NFUNC,
     .                            PARMAT,
     .                            LSUBMODEL,
     .                            PM,MATPARAM)
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Read user material 29 to 31 - generic routine
C------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     USERL_AVAIL   Flag if userlibrary was load
C     MATNUM        Number of Material 29, 30, 31
C     IS_AVAILABLE  Bool / Result of HM_interface
C     LSUBMODEL     SUBMODEL Structure.
C------------------------------------------------------------------
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE submodel_mod , ONLY : nsubmod, submodel_data
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharline
      USE format_mod , ONLY : fmt_2f
      USE reader_old_mod , ONLY : kcur, kline, line,key0
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr15_c.inc"
#include      "scr17_c.inc"
#include      "param_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ILAW
      INTEGER USERL_AVAIL
      INTEGER MAXUPARAM
      INTEGER NUPARAM 
      INTEGER NUVAR
      INTEGER NFUNC,MAXFUNC
      TYPE(submodel_data),INTENT(IN)  :: LSUBMODEL(NSUBMOD)
      INTEGER, DIMENSION(MAXFUNC)     :: IFUNC
      my_real, DIMENSION(100)         :: parmat
      my_real, DIMENSION(MAXUPARAM)   :: uparam
      my_real, DIMENSION(NPROPM) ,INTENT(INOUT)   :: pm
      CHARACTER(LEN=NCHARLINE) :: IUSER_KEY
      TYPE (MATPARAM_STRUCT_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      CHARACTER(LEN=4096) :: SCR_FILE_NAME
      CHARACTER(LEN=NCHARLINE) :: RLINE
      CHARACTER (LEN=4) :: CLAW
      LOGICAL :: IS_AVAILABLE
      INTEGER NLINES,J
      INTEGER SCR_FILE_NAME_LEN
      my_real rho0,rhor
!
      CHARACTER OPTION*256
      INTEGER SIZE
C-----------------------------------------------
      is_available = .false.
!
      IF (userl_avail == 0)THEN
      ! ERROR to be printed & exit
        option='/MAT/'//iuser_key
        size=len_trim(option)
        CALL ancmsg(msgid=1130,
     .              msgtype=msgerror,c1=option(1:size),anmode=aninfo)
        CALL arret(2)
      ENDIF
 
     
      CALL hm_get_intv ('Number_of_datalines' ,nlines ,is_available, lsubmodel)
 
      IF(nlines > 1)THEN
 
        ! Rho & Rho0_r are read out of user laws
        j=1
        CALL hm_get_string_index('arraydatalines', rline, 1, ncharline, is_available)
        READ(rline,err=999,fmt=fmt_2f)rho0,rhor
 
        pm(1)=rhor
        pm(89)=rho0
 
        ! Create tempo file  
        WRITE(claw,'(I4.4)')ilaw
        scr_file_name='si'//ROOTNAM(1:ROOTLEN)//'_'//CLAW//'.scr'
        SCR_FILE_NAME_LEN=LEN_TRIM(SCR_FILE_NAME)
        OPEN(UNIT=30,FILE=TRIM(SCR_FILE_NAME),FORM='formatted',RECL=ncharline)
 
        ! Read & Dump in scratch file
        DO J=2,NLINES   
         CALL HM_GET_STRING_INDEX('arraydatalines', RLINE, J, ncharline, IS_AVAILABLE)
         WRITE(30,FMT='(a)')TRIM(RLINE)
        ENDDO
        CLOSE(UNIT=30)
  
        CALL ST_USERLIB_USERMAT(ILAW,ROOTNAM,ROOTLEN,
     .                          UPARAM,MAXUPARAM,NUPARAM,
     .                          NUVAR ,IFUNC,MAXFUNC,NFUNC   ,PARMAT)
 
        CALL USER_OUTPUT(IOUT,ILAW,ROOTNAM,ROOTLEN,1)
      ELSE
         ! Error MESSAGE_Mess
      ENDIF
 
      ! Properties compatibility
      CALL INIT_MAT_KEYWORD(MATPARAM,"SOLID_ALL")
      CALL INIT_MAT_KEYWORD(MATPARAM,"SHELL_ALL")
      CALL INIT_MAT_KEYWORD(MATPARAM,"SPH")
 
      RETURN
 999  CALL ANCMSG(MSGID=55,ANMODE=ANINFO,MSGTYPE=MSGERROR,C1=KEY0(KCUR),C2=KLINE,C3=LINE)
      CALL ARRET(2)
      END