hm_read_prop19.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_prop19           ../starter/source/properties/shell/hm_read_prop19.F
!||--- called by ------------------------------------------------------
!||    hm_read_properties       ../starter/source/properties/hm_read_properties.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    arret                    ../starter/source/system/arret.F
!||    fretitl2                 ../starter/source/starter/freform.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_prop19(IG, IGTYP, ISTACK, GEO, IGEO, PM, IPM, UNITAB, 
     .     IDRAPEID, LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
#include      "drape_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_), INTENT(IN) ::UNITAB
      INTEGER, INTENT(INOUT) :: IGEO(NPROPGI)
      INTEGER, INTENT(IN) :: IPM(NPROPMI,*), IDRAPEID(*), IG, IGTYP, ISTACK
      my_real, INTENT(INOUT) :: geo(npropg)
      my_real, INTENT(IN) ::  pm(npropm,*)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: IMID, J, DRAPE_ID, ID
      my_real :: thickt, fac_gen, pun
      CHARACTER(LEN = NCHARTITLE) :: TITR, TITR1, IDTITL
      LOGICAL :: IS_AVAILABLE, IS_ENCRYPTED, LFOUND
C-------------------------------------------------
C     B e g i n n i n g   o f  S u b r o u t i n e
C-------------------------------------------------
      pun = 0.1
      igeo(1) = ig
      igeo(11) = igtyp
      geo(12) = igtyp + pun
      
      is_available = .false.
      is_encrypted = .false.
!     Encryption flag
      CALL hm_option_is_encrypted(is_encrypted)      
!     Line 1
      CALL hm_get_intv('material', imid, is_available, lsubmodel)
      CALL hm_get_floatv('thickness1', geo(1), is_available, lsubmodel, unitab)  
      CALL hm_get_floatv('orientangle', geo(2), is_available, lsubmodel, unitab)  
      CALL hm_get_intv('grsh4n_ID', igeo(40), is_available, lsubmodel)
      CALL hm_get_intv('grsh3n_ID', igeo(41), is_available, lsubmodel)
      CALL hm_get_intv('integrationpoints', igeo(4), is_available, lsubmodel)
      CALL hm_get_floatv('orientangle2', geo(212), is_available, lsubmodel, unitab)  
!     Line 2
      CALL hm_get_intv('table', drape_id, is_available, lsubmodel)
      
      IF (igeo(4) <= 0) igeo(4) = 1   ! default value
      igeo(44) = igeo(4) ! Used with drape for OUPT
      IF (geo(212) == zero) THEN
         CALL hm_get_floatv_dim('orientangle2',fac_gen, is_available, lsubmodel, unitab)
         geo(212) = ninty * fac_gen ! default value   
      ENDIF
 
      IF (is_encrypted) THEN
         WRITE(iout, 1000) ig
      ELSE
         WRITE(iout, 2000) ig, imid, geo(1), geo(2), igeo(40), igeo(41), igeo(4),
     .        geo(212), drape_id
      ENDIF
     
      geo(2) = geo(2) * pi / hundred80
      geo(212) = geo(212) * pi / hundred80
      igeo(48) = 0 
 
!     *********************************************************    !
!     Check for layer materials compatibility moved to "lecgeo"
!     *********************************************************    !
      lfound = .false.
      DO j=1,nummat-1
         IF (ipm(1,j) == imid) THEN
            igeo(101) = j
            lfound = .true.
            EXIT
         ENDIF
      ENDDO
      IF (.NOT. lfound) THEN
         CALL fretitl2(titr, igeo(npropgi-ltitr+1), ltitr)
         IF (istack == 0) THEN
            CALL ancmsg(msgid = 31, msgtype = msgerror, anmode = aninfo_blind_2,
     .           i1 = ig, c1 = titr, i2 = imid)  
         ELSE
            CALL ancmsg(msgid = 1151, msgtype = msgerror, anmode = aninfo_blind_2,
     .           i1 = ig, c1 = titr, i2 = imid) 
         ENDIF
         igeo(101) = 1   
      ELSE 
!     ***********************************    ! 
!     check for right drape id definition
!     ***********************************    ! 
         IF (ndrape > 0 .OR. drape_id > 0) THEN
            lfound = .false.
            DO j=1,ndrape
               IF (drape_id > 0 .AND. drape_id == idrapeid(j)) THEN
                  igeo(48) = drape_id
                  lfound = .true.
                  EXIT
               ENDIF 
            ENDDO
            IF (.NOT. lfound) THEN
               IF (drape_id > 0)THEN
                  CALL fretitl2(titr, igeo(npropgi-ltitr+1), ltitr)
                  CALL ancmsg(msgid = 1153, msgtype = msgerror, anmode = aninfo,
     .                 i1 = ig, c1 = titr, i2 = drape_id)
               ENDIF
            ENDIF
         ENDIF                  
      ENDIF
      IF (igeo(4) > 10) THEN
         CALL ancmsg(msgid = 788, msgtype = msgerror, anmode = aninfo,
     .        i1 = ig, c1 = idtitl)
         CALL arret(2)
      ENDIF
      RETURN
 1000 FORMAT(
     &    5x,' LAYER  SHELL PROPERTY SET'/,
     &    5x,'------------------------------------'/,
     &    5x,'PROPERTY SET NUMBER . . . . . . . . . .=',i10/,
     &    5x,'CONFIDENTIAL DATA'//)
 2000 FORMAT(
     & 5x,'LAYER PROPERTY SET ',/,
     & 5x,'PROPERTY SET NUMBER . . . . . . . . . . . . . . =',i10/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . . . . . . =',i10/,
     & 5x,'LAYER THICKNESS . . . . . . . . . . . . . . . . =',1pg20.13/,
     & 5x,'INCREMENTAL ANGLE (DIR 1,PROJ(DIR 1 / SHELL). . =',1pg20.13/,      
     & 5x,'SHELL 4-nodes GROUP IDENTIFIER. . . . . . . . . =',i10/,
     & 5x,'SHELL 3-nodes GROUP IDENTIFIER. . . . . . . . . =',i10/,
     & 5x,'NUMBER OF INTEGRATION POINTS THROUGH LAYER. . . =',i10/,
     & 5x,'ORTHOTROPY ANGLE BETWEEN (DIR 1,DIR 2). . . . . =',1pg20.13/,
     & 5x,'DRAPE IDENTIFIER  . . . . . . . . . . . . . . . =',i10/)
      END SUBROUTINE hm_read_prop19