i12_nearest_seg.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i12_nearest_seg   ../engine/source/interfaces/inter3d/i12_nearest_seg.F
!||--- called by ------------------------------------------------------
!||    i12msr3           ../engine/source/interfaces/inter3d/i12msr3.F
!||====================================================================
      SUBROUTINE i12_nearest_seg(XS, XM, IS, M1, M2, M3, LSEG, LSEG_NEW, BMIN, BMAX)
C  
C  COMPUTE BARYCENTRIC COORDINATES OF PROJECTION OF NODE IS ON TRIANGLE M1 M2 M3
C  WOLFGANG HEIDRICH, 2005
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN)  :: IS, M1, M2, M3, LSEG
      INTEGER, INTENT(OUT) :: LSEG_NEW 
      my_real, INTENT(IN)  :: xs(3,*), xm(3,*)
      my_real, INTENT(OUT) :: bmin
      my_real, INTENT(INOUT) :: bmax
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real n(3), u(3), v(3), w(3), uw(3), wv(3)
      my_real b0, b1, b2, fac
C-------------------------------------------------
      u(1)=xm(1,m2)-xm(1,m1)
      u(2)=xm(2,m2)-xm(2,m1)
      u(3)=xm(3,m2)-xm(3,m1)
C
      v(1)=xm(1,m3)-xm(1,m1)
      v(2)=xm(2,m3)-xm(2,m1)
      v(3)=xm(3,m3)-xm(3,m1)
C
      n(1)=u(2)*v(3)-u(3)*v(2)
      n(2)=u(3)*v(1)-u(1)*v(3)
      n(3)=u(1)*v(2)-u(2)*v(1)
C
      w(1)=xs(1,is)-xm(1,m1)
      w(2)=xs(2,is)-xm(2,m1)
      w(3)=xs(3,is)-xm(3,m1)
C
      uw(1)=u(2)*w(3)-u(3)*w(2)
      uw(2)=u(3)*w(1)-u(1)*w(3)
      uw(3)=u(1)*w(2)-u(2)*w(1)
C
      wv(1)=w(2)*v(3)-w(3)*v(2)
      wv(2)=w(3)*v(1)-w(1)*v(3)
      wv(3)=w(1)*v(2)-w(2)*v(1)
C
      fac=one/(n(1)*n(1)+n(2)*n(2)+n(3)*n(3))
      b2 =(uw(1)*n(1)+uw(2)*n(2)+uw(3)*n(3))*fac
      b1 =(wv(1)*n(1)+wv(2)*n(2)+wv(3)*n(3))*fac
      b0 = one - b1 - b2
      bmin=min(b0,b1,b2)    
C BMIN > 0 Projection est a l'interieur du triangle
C BMIN = 0 Projection est sur un cote du triangle
C BMIN < 0 Projection est a l'exterieur du triangle
      IF(bmin > bmax) THEN
         lseg_new=lseg
         bmax=bmin
      ENDIF
      RETURN
      END