i12chk3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i12chk3                ../starter/source/interfaces/inter3d1/i12chk3.F
!||--- called by ------------------------------------------------------
!||    inint3                 ../starter/source/interfaces/inter3d1/inint3.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    i12sol3                ../starter/source/interfaces/inter3d1/insol3.F
!||    icinv3                 ../starter/source/interfaces/inter3d1/icinv3.F
!||    local_index            ../starter/source/interfaces/interf1/local_index.F
!||--- uses       -----------------------------------------------------
!||    format_mod             ../starter/share/modules1/format_mod.F90
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE i12chk3(X   ,IRECT,IXS,NRT   ,IXC,
     .                  NINT,NSN  ,NSV,NOINT ,MWA,
     .                  IXTG,PM,ISEG,ALE_CONNECTIVITY,
     .                  VARCONVINT,FCOUNT,ITIED,ITAB,KNOD2ELS,
     .                  NOD2ELS,NTY,ID,TITR)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE ale_connectivity_mod
      USE names_and_titles_mod , ONLY : nchartitle
      USE format_mod , ONLY : fmw_10i
      use element_mod , only :nixs,nixc,nixtg
C-----------------------------------
C     CHECK ELEMENT FOR TYPE 12
C------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr03_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NRT, NINT, NSN, NOINT, NTY, ID, ITIED
      INTEGER IRECT(4,*), IXS(NIXS,*), IXC(NIXC,*), MWA(*),
     .   NSV(*), IXTG(NIXTG,*), ISEG(*), VARCONVINT,
     .   ITAB(*), FCOUNT(*), KNOD2ELS(*), NOD2ELS(*)
      my_real
     .   x(3,*), pm(npropm,*)
      CHARACTER(LEN=NCHARTITLE) ::  TITR
      TYPE(t_ale_connectivity), INTENT(INOUT) :: ALE_CONNECTIVITY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, INRT, NELS, J, NN, NF, M, IG, IL, VARCONV,IAD
      my_real
     .   AREA
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
 
      IF(itied/=3)THEN
        CALL icinv3(ixs,ixc,ixtg,mwa,mwa(1+(2+numnod)))
        IF(ipri>=1 .AND. nint<0)WRITE(iout,1000)
        IF(ipri>=1 .AND. nint>0)WRITE(iout,1001)
        DO i=1,nrt
          inrt=i
          CALL i12sol3(x,irect,ixs,nint,nels,inrt,
     .                 area,noint,mwa ,mwa(1+(2+numnod)),nf,itab,
     .                 knod2els,nod2els,nty,id,titr)
          IF(nels/=0) THEN
            m=ixs(1,nels)
            varconv=int(pm(10,m))
            IF(varconvint==-1)varconvint=varconv
            IF(varconv==varconvint)THEN
              segindx = segindx+1
              iseg(i) = segindx
              iad = ale_connectivity%ee_connect%iad_connect(nels)
              ale_connectivity%ee_connect%connected(iad + nf - 1) = -segindx
              IF(ipri>=1)
     .        WRITE(iout,fmt=fmw_10i)i,ixs(11,nels),nf,segindx,nels
            ELSE
              IF(nint>0) WRITE (iout,1101) i, noint
              IF(nint<0) WRITE (iout,1201) i, noint
              ierr=ierr+1
            ENDIF
          ELSE
            IF(nint>0) WRITE (iout,1100) i, noint
            IF(nint<0) WRITE (iout,1200) i, noint
            ierr=ierr+1
          ENDIF !(NELS/=0)
        END DO !I=1,NRT 
        CALL ancmsg(msgid=1245,
     .                  msgtype=msgerror,
     .                  anmode=aninfo_blind,
     .                  i1=id,
     .                  c1=titr,
     .                  prmod=msg_print)
        CALL ancmsg(msgid=1246,
     .                  msgtype=msgerror,
     .                  anmode=aninfo_blind,
     .                  i1=id,
     .                  c1=titr,
     .                  prmod=msg_print) 
      END IF !(ITIED/=3)
      
      !------------------------------------------------------------------------!
      ! !     THE GLOBAL NODE IS REPLACED BY THE LOCAL NODE IN IRECT         !
      !------------------------------------------------------------------------!
      DO i=1,nrt
        DO j=1,4
          ig=irect(j,i)
          CALL local_index(il,ig,nsv,nsn)
          irect(j,i)=il
        ENDDO
      ENDDO
      !------------------------------------------------------------------------!
      ! !     COUNTING THE NUMBER OF FACETS CONNECTED BY NODE (SECONDARY ONLY!)  !
      !------------------------------------------------------------------------!
      IF(nint>0)THEN
         DO  i=1,nsn
           fcount(i)=0
         ENDDO
         DO  i=1,nrt
           DO j=1,4
             nn=irect(j,i)
             fcount(nn)=fcount(nn)+1
           ENDDO
         ENDDO
      ENDIF
 
      RETURN
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8----+----9----+----A----+----B----+----C
 1000 FORMAT(//'  MAIN     ELT    FACE        ')
 1001 FORMAT(//'  SECONDARY      ELT    FACE        ')
 1100 FORMAT(2x,'** ERROR ** CANNOT FIND FLUID ELT OF MAIN  SEGMENT',i10,' OF INTERFACE',i10)
 1200 FORMAT(2x,'** ERROR ** CANNOT FIND FLUID ELT OF SECONDARY   SEGMENT',i10,' OF INTERFACE',i10)
 1101 FORMAT(2x,'** ERROR ** VARIABLES NOT CONSISTENT IN SECONDARY  ELEMENT',i10,' FOR INTERFACE',i10)
 1201 FORMAT(2x,'** ERROR ** VARIABLES NOT CONSISTENT IN MAIN ELEMENT',i10,' FOR INTERFACE',i10)
       END