i18xsave.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i18xsave     ../engine/source/interfaces/int18/i18xsave.F
!||--- called by ------------------------------------------------------
!||    i7main_tri   ../engine/source/interfaces/intsort/i7main_tri.F
!||====================================================================
      SUBROUTINE i18xsave(
     1       X        ,NSV  , MSR   , NSN   , NMN     ,
     2       ITASK    ,XSAV , XMIN  , YMIN  , ZMIN    ,
     3       XMAX     ,YMAX , ZMAX  , C_MAX , CURV_MAX,
     4       ICURV    ,IRECT, NRTM_T, SX    , SY      ,
     5       SZ       ,SX2  , SY2   , SZ2   , NMN_L   )
C saving XSAV and computing domain bounds
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "impl1_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN,NMN,ITASK, ICURV, NRTM_T,
     . NSV(*),MSR(*), IRECT(4,*),NMN_L
      my_real
     .        XMAX, YMAX, ZMAX, XMIN, YMIN, ZMIN, C_MAX,
     .        SX, SY, SZ, SX2, SY2, SZ2,
     .        x(3,*), xsav(3,*), curv_max(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NSNF,NMNF,NSNL,NMNL,I, J, II
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
C
      nsnf=1+itask*nsn/nthread
      nsnl=(itask+1)*nsn/nthread
      nmnf=1+itask*nmn/nthread
      nmnl=(itask+1)*nmn/nthread
 
      xmin=ep30
      xmax=-ep30
      ymin=ep30
      ymax=-ep30
      zmin=ep30
      zmax=-ep30
 
      sx=zero
      sy=zero
      sz=zero
      sx2=zero
      sy2=zero
      sz2=zero
      nmn_l = 0
       
      IF(nsn+nmn < numnod)THEN
        DO i=nsnf,nsnl
          j=nsv(i)        
          IF(j>0.AND.inconv==1)THEN
            xsav(1,i)=x(1,j)
            xsav(2,i)=x(2,j)
            xsav(3,i)=x(3,j)
          ENDIF
        END DO
 
        DO i=nmnf,nmnl
          ii = i+nsn
          j=msr(i)
          ! msr < 0 <=> shooting nodes
          IF(j>0) THEN 
            xmin= min(xmin,x(1,j))
            ymin= min(ymin,x(2,j))
            zmin= min(zmin,x(3,j))
            xmax= max(xmax,x(1,j))
            ymax= max(ymax,x(2,j))
            zmax= max(zmax,x(3,j))
            IF (inconv==1) THEN
              xsav(1,ii)=x(1,j)
              xsav(2,ii)=x(2,j)
              xsav(3,ii)=x(3,j)
            END IF
            sx=sx+x(1,j)
            sy=sy+x(2,j)
            sz=sz+x(3,j)
            sx2=sx2+x(1,j)**2
            sy2=sy2+x(2,j)**2
            sz2=sz2+x(3,j)**2
            nmn_l= nmn_l + 1
          ENDIF
        END DO
      ELSE
C
        DO i=nsnf,nsnl
          j=nsv(i)
          IF(j>0.AND.inconv==1)THEN
            xsav(1,j)=x(1,j)
            xsav(2,j)=x(2,j)
            xsav(3,j)=x(3,j)
          END IF
        END DO
        DO i=nmnf,nmnl
          j=msr(i)
           ! msr < 0 <=> shooting nodes
          IF(j>0) THEN 
            xmin= min(xmin,x(1,j))
            ymin= min(ymin,x(2,j))
            zmin= min(zmin,x(3,j))
            xmax= max(xmax,x(1,j))
            ymax= max(ymax,x(2,j))
            zmax= max(zmax,x(3,j))
            IF (inconv==1) THEN
              xsav(1,j)=x(1,j)
              xsav(2,j)=x(2,j)
              xsav(3,j)=x(3,j)
            END IF
            sx=sx+x(1,j)
            sy=sy+x(2,j)
            sz=sz+x(3,j)
            sx2=sx2+x(1,j)**2
            sy2=sy2+x(2,j)**2
            sz2=sz2+x(3,j)**2
            nmn_l= nmn_l + 1
          END IF
        END DO
      ENDIF
C
      c_max = zero
      DO i=1,nrtm_t
        curv_max(i)=zero
      ENDDO
C
      RETURN
      END