i1tid3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i1tid3                 ../starter/source/interfaces/inter3d1/i1tid3.F
!||--- called by ------------------------------------------------------
!||    inint3                 ../starter/source/interfaces/inter3d1/inint3.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    inist3                 ../starter/source/interfaces/inter3d1/inist3.F
!||    kinset                 ../starter/source/constraints/general/kinset.F
!||--- uses       -----------------------------------------------------
!||    format_mod             ../starter/share/modules1/format_mod.F90
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE i1tid3(X     ,IRECT,CRST ,MSR  ,NSV,
     1                  ILOC  ,IRTL ,NSN  ,ITAB ,IKINE,
     2                  IKINE1,ID   ,TITR ,ILEV ,NTY, CSTS_BIS)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C     INTERFACE TIED CALCUL DE S,T
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE format_mod , ONLY : fmw_7i_2f
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "scr03_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN
      INTEGER IRECT(4,*), MSR(*), NSV(*), ILOC(*), IRTL(*), ITAB(*),IKINE(*),IKINE1(*),ILEV,NTY
      my_real x(3,*), crst(2,*), csts_bis(2,*)
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE) :: TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER II, I, J, K, L, JJ, NN, IER
      my_real
     .   n1, n2, n3, ss, tt, alp
      my_real :: xx1(4),xx2(4),xx3(4),xs1,ys1,zs1,xc,yc,zc
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      alp = twoem2
      DO ii=1,nsn
        i=nsv(ii)
        IF ((nty==1).OR.((nty==2).AND.(ilev /= 25 .and. ilev /= 26 .and. ilev /= 27 .and. ilev /= 28))) THEN
          CALL kinset(2,itab(i),ikine(i),1,0,ikine1(i))
          CALL kinset(2,itab(i),ikine(i),2,0,ikine1(i))
          CALL kinset(2,itab(i),ikine(i),3,0,ikine1(i))
          CALL kinset(2,itab(i),ikine(i),4,0,ikine1(i))
          CALL kinset(2,itab(i),ikine(i),5,0,ikine1(i))
          CALL kinset(2,itab(i),ikine(i),6,0,ikine1(i))
        ENDIF
        j=iloc(ii)
        k=msr(j)
        l=irtl(ii)
        DO jj=1,4
          nn=msr(irect(jj,l))
          xx1(jj)=x(1,nn)
          xx2(jj)=x(2,nn)
          xx3(jj)=x(3,nn)
        ENDDO
        xs1=x(1,i)
        ys1=x(2,i)
        zs1=x(3,i)
        CALL inist3(n1,n2,n3,ss,tt,ier,alp,xx1,xx2,xx3,xs1,ys1,zs1,xc,yc,zc)
        IF(ipri>=1)WRITE(iout,fmt=fmw_7i_2f)
     .        itab(i),itab(k),
     .        l,(itab(msr(irect(jj,l))),jj=1,4),ss,tt
         IF(ier==-1)THEN
            CALL ancmsg(msgid=85,
     .                  msgtype=msgerror,
     .                  anmode=aninfo,
     .                  i1=id,
     .                  c1=titr,
     .                  i2=itab(i),
     .                  i3=itab(k),
     .                  i4=l,
     .                  i5=itab(nsv(irect(1,l))),
     .                  i6=itab(nsv(irect(2,l))),
     .                  i7=itab(nsv(irect(3,l))),
     .                  i8=itab(nsv(irect(4,l))))
         ELSE IF(ier==1)THEN
            CALL ancmsg(msgid=86,
     .                  msgtype=msgwarning,
     .                  anmode=aninfo_blind_2,
     .                  i1=id,
     .                  c1=titr,
     .                  i2=itab(i),
     .                  i3=itab(k),
     .                  i4=l,
     .                  i5=itab(msr(irect(1,l))),
     .                  i6=itab(msr(irect(2,l))),
     .                  i7=itab(msr(irect(3,l))),
     .                  i8=itab(msr(irect(4,l))),
     .                  r1=ss,
     .                  r2=tt)
         ENDIF
        crst(1,ii)=ss
        crst(2,ii)=tt
        IF (nty == 2) THEN
          csts_bis(1,ii)=ss
          csts_bis(2,ii)=tt
        ENDIF
      enddo!next II
C-----------------------------------------------
      RETURN
      END