i6pen3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    i6pen3                 ../starter/source/interfaces/inter3d1/i6pen3.F
!||--- called by ------------------------------------------------------
!||    iniend                 ../starter/source/interfaces/inter3d1/iniend.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    inist3                 ../starter/source/interfaces/inter3d1/inist3.F
!||--- uses       -----------------------------------------------------
!||    format_mod             ../starter/share/modules1/format_mod.F90
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE i6pen3(X     ,IRECT  ,MSR    ,NSV   ,ILOC  ,
     1                  IRTL  ,CST    ,IRTL0  ,GAP   ,NSN   ,
     2                  ITAB  ,IWPENE ,PENI   ,ICOR  ,ID    ,
     3                  INACTI,TITR   )
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
      USE format_mod , ONLY : fmw_7i, fmw_7i_2f
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "scr03_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN,IWPENE,ICOR,INACTI
      my_real GAP,PENI
      INTEGER IRECT(4,*), MSR(*), NSV(*), ILOC(*), IRTL(*), IRTL0(*),ITAB(*)
      my_real x(3,*), cst(2,*)
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE)::TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER II, I, J, K, L, JJ, NN, IER
      my_real N1, N2, N3, PEN, ALP
      my_real :: XX1(4), XX2(4),XX3(4),XS1,YS1,ZS1,XC,YC,ZC
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      alp = twoem2
      DO ii=1,nsn
        i=nsv(ii)
        j=iloc(ii)
        k=msr(j)
        l=irtl(ii)
        DO jj=1,4
          nn=msr(irect(jj,l))
          xx1(jj)=x(1,nn)
          xx2(jj)=x(2,nn)
          xx3(jj)=x(3,nn)
        ENDDO
        xs1=x(1,i)
        ys1=x(2,i)
        zs1=x(3,i)
        CALL inist3(n1,n2,n3,cst(1,ii),cst(2,ii),ier,alp,xx1,xx2,xx3,xs1,ys1,zs1,xc,yc,zc)
        IF(ier==-1)THEN
           CALL ancmsg(msgid=85,
     .                 msgtype=msgerror,
     .                 anmode=aninfo,
     .                 i1=id,
     .                 c1=titr,
     .                 i2=itab(i),
     .                 i3=itab(k),
     .                 i4=l,
     .                 i5=itab(msr(irect(1,l))),
     .                 i6=itab(msr(irect(2,l))),
     .                 i7=itab(msr(irect(3,l))),
     .                 i8=itab(msr(irect(4,l))))
        ELSE IF(ier==1)THEN
         IF(ipri>=1)WRITE(iout,fmt=fmw_7i)itab(i),itab(k),l,
     .                      (itab(msr(irect(jj,l))),jj=1,4)
        ELSE
          pen = n1*(xs1-xc)+n2*(ys1-yc)+n3*(zs1-zc) - gap
          IF (pen<=zero) irtl0(ii)=l
          IF (pen < zero) THEN
            peni = min(pen,peni)
            CALL ancmsg(msgid=346,
     .                  msgtype=msgwarning,
     .                  anmode=aninfo_blind_2,
     .                  i1=id,i2=itab(i),
     .                  c1=titr,
     .                  r1=pen)
            IF (inacti == 5) THEN
c              PEN = MIN(ZERO, PEN + GAP)
              gap = max(zero, gap + pen)   ! constant gap
            ELSEIF (inacti == 6) THEN
c              PEN = MIN(ZERO, PEN + ZEP05 * (GAP - PEN))
              gap = max(zero, gap + pen + zep05 * (gap + pen))   ! constant gap
            ENDIF
            iwpene=iwpene+1
          ENDIF
         IF(ipri>=1)WRITE(iout,fmt=fmw_7i_2f)
     .    itab(i),itab(k),l,
     .    (itab(msr(irect(jj,l))),jj=1,4),cst(1,ii),cst(2,ii)
        ENDIF
      ENDDO
      IF (icor == 0) peni = zero
C-----------
      RETURN
      END