ig3dfint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ig3dfint     ../engine/source/elements/ige3d/ig3dfint.F
!||--- called by ------------------------------------------------------
!||    ig3duforc3   ../engine/source/elements/ige3d/ig3duforc3.F
!||====================================================================
      SUBROUTINE ig3dfint(
     1   PM,      MXT,     KXIG3D,  SIG,
     2   NCTRL,   MATB,    FX,      FY,
     3   FZ,      VOL,     BtDBA,   DBA,
     4   SSP_EQ,  STIG,    NEL,     NFT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NFT
      INTEGER NCTRL, KXIG3D(NIXIG3D,*), MXT(*),NEL
      my_real
     .   SIG(NEL,6), VOL(*), PM(NPROPM,*)
      my_real,
     .  DIMENSION(3*NCTRL,MVSIZ) :: matb
      my_real
     .  fx(mvsiz,*),fy(mvsiz,*),fz(mvsiz,*),btdba(3*nctrl,mvsiz),
     .  dba(6,mvsiz),stig(mvsiz,*),ssp_eq(*),sumx,sumy,sumz
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, INCTRL
      my_real
     .   AA,WIP(MVSIZ),STIN(MVSIZ,NCTRL)
C-----------------------------------------------
C            _
C           /   t
C     F = _/ [B]  sig dvol
C
C                   NEL
C   [B] = [dNi/dx  dNk/dx  ..  ] \  3
C         [dNi/dy  dNk/dy  ..  ] |  *
C         [dNi/dz  dNk/dz  ..  ] |  N
C         [dNj/dx  dNl/dx  ..  ] |  C
C         [dNj/dy  dNl/dy  ..  ] |  T
C         [dNj/dz  dNl/dz  ..  ] |  R
C         [  ..      ..    ..  ] /  L
C
      DO i=1,nel
       sumx=zero 
       sumy=zero
       sumz=zero
       DO j=1,nctrl
        IF( j <= kxig3d(3,i+nft) ) THEN
         inctrl = (j-1)*3
         sumx=sumx+abs(matb(inctrl+1,i))
         sumy=sumy+abs(matb(inctrl+2,i))
         sumz=sumz+abs(matb(inctrl+3,i))
        ENDIF
       ENDDO
       DO j=1,nctrl
        IF( j <= kxig3d(3,i+nft) ) THEN
         inctrl = (j-1)*3
         fx(i,j)=fx(i,j)-vol(i)*(matb(inctrl+1,i)*sig(i,1)
     +                         + matb(inctrl+2,i)*sig(i,4)  
     +                         + matb(inctrl+3,i)*sig(i,6))
 
         fy(i,j)=fy(i,j)-vol(i)*(matb(inctrl+1,i)*sig(i,4)
     +                         + matb(inctrl+2,i)*sig(i,2)
     +                         + matb(inctrl+3,i)*sig(i,5))
 
         fz(i,j)=fz(i,j)-vol(i)*(matb(inctrl+1,i)*sig(i,6)
     +                         + matb(inctrl+2,i)*sig(i,5) 
     +                         + matb(inctrl+3,i)*sig(i,3))
         stin(i,j)= half*vol(i)*
     .      (abs(matb(inctrl+1,i))*sumx 
     .     + abs(matb(inctrl+2,i))*sumy 
     .     + abs(matb(inctrl+3,i))*sumz)
         aa=pm(89,mxt(i))*ssp_eq(i)*ssp_eq(i)
         stig(i,j)=stig(i,j)+stin(i,j)*aa
        ENDIF
       ENDDO
      ENDDO
 
 
      RETURN
      END