inigrav_m37.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    inigrav_m37    ../starter/source/initial_conditions/inigrav/inigrav_m37.F
!||--- called by ------------------------------------------------------
!||    inigrav_load   ../starter/source/initial_conditions/inigrav/inigrav_load.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE inigrav_m37(NELG, NEL, NG, MATID, IPM, GRAV0, DEPTH, PM, BUFMAT, ELBUF_TAB, PSURF, LIST)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
!     NPROPMI, NPROPM
#include      "param_c.inc"
!     NGROUP
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL, NG, MATID, IPM(NPROPMI, *), LIST(NEL),NELG
      my_real, INTENT(IN) :: grav0, depth(*), pm(npropm, *), bufmat(*)
      my_real, INTENT(INOUT) :: psurf
      TYPE(elbuf_struct_), DIMENSION(NGROUP), TARGET, INTENT(IN) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,ISOLVER, K
      my_real :: r1, c1, p0, pgrav, rho10, rho20, rho1, rho2, gam, rho0, 
     .     alpha1, alpha2,psh
      TYPE(g_bufel_), POINTER :: GBUF
      TYPE(buf_mat_) ,POINTER :: MBUF  
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
C LIST IS SUBGROUP TO TREAT : ONLY ELEM WITH RELEVANT PARTS ARE KEPT
C NEL IS ISEZ OF LIST
C NELG IS SIZE OF ORIGINAL GROUP : needed to shift indexes in GBUF%SIG & MBUF%VAR
 
C     Global buffer
      gbuf => elbuf_tab(ng)%GBUF
C     Material buffer
      mbuf  => elbuf_tab(ng)%BUFLY(1)%MAT(1,1,1)
C     EOS parameters, common
      p0 = bufmat(9)
      psh= bufmat(16)
C     EOS parameters mat 1: 
      rho10 = bufmat(11)
      c1 = bufmat(4)
      r1 = bufmat(6)
C     EOS parameters mat2:
      gam = bufmat(5)
      rho20 = bufmat(12)
      isolver = bufmat(17)
 
      IF(psurf==zero .AND. isolver<=1)THEN
        psurf=p0  !historical solver requires a total pressure formulation
        print *, "**WARNING : INIGRAV CARD, PREF PARAMETER MUST BE A TOTAL PRESSURE WITH LAW37, SETTING PREF=P0"
      ENDIF      
 
      DO k = 1, nel
         i = list(k)
         alpha1 = mbuf%VAR(i + (4 - 1) * nelg)
         alpha2 = one - alpha1
         rho0 = alpha1 * rho10 + alpha2 * rho20
         pgrav = psurf - rho0  * grav0 * depth(k)
         rho1 = (pgrav-p0)/r1 + rho10
         rho2 = rho20 * (pgrav/p0) ** (one / gam)
         gbuf%RHO(i) = alpha1 * rho1 + alpha2 * rho2
         mbuf%VAR(i + (4 - 1) * nelg) = alpha1
         mbuf%VAR(i + (5 - 1) * nelg) = one - alpha1
         mbuf%VAR(i + (2 - 1) * nelg) = rho2
         mbuf%VAR(i + (3 - 1) * nelg) = rho1
         mbuf%VAR(i + (1 - 1) * nelg) = alpha1 * rho1
         gbuf%SIG(i)            = - (pgrav-p0-psh)
         gbuf%SIG(i + nelg)     = - (pgrav-p0-psh)
         gbuf%SIG(i + 2 * nelg) = - (pgrav-p0-psh)
      ENDDO
      
      END SUBROUTINE inigrav_m37