inintmass.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    inintmass       ../starter/source/interfaces/inter3d1/inintmass.F
!||--- called by ------------------------------------------------------
!||    initia          ../starter/source/elements/initia/initia.F
!||--- uses       -----------------------------------------------------
!||    message_mod     ../starter/share/message_module/message_mod.f
!||====================================================================
      SUBROUTINE inintmass( IPARI, INTBUF_TAB, MS  ,ISTIF_DT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE intbufdef_mod 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER , INTENT(INOUT) :: ISTIF_DT
      INTEGER , INTENT(IN   ) :: IPARI(NPARI,NINTER) 
      my_real , INTENT(IN   ) :: ms(numnod) 
      TYPE(intbuf_struct_) , INTENT(INOUT) ::  INTBUF_TAB(NINTER)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER 
     .   N ,NS ,N1, N2, N3 ,N4 ,I ,NI ,NTY ,NRTM ,NSN ,ISTIF_MSDT ,FLAGDT ,
     .   NEDGE
      my_real 
     .   stfacm ,ms1 ,ms2 ,ms3 ,ms4 ,dtstif
C----------------------------------------------------------
C    Main and secondary masses needed for contact stiffness computation 
C----------------------------------------------------------
          DO n=1,ninter
             nty = ipari(7,n)
             IF(nty==24.OR.nty==25) THEN
                istif_msdt = ipari(97,n)
                IF(istif_msdt > 0) THEN
                   nrtm     = ipari(4,n)
                   nsn      = ipari(5,n)
                   stfacm   = intbuf_tab(n)%VARIABLES(47)
                   DO i=1,nsn
                      ns = intbuf_tab(n)%NSV(i)
                      intbuf_tab(n)%STIFMSDT_S(i)  = stfacm*ms(ns)
                   ENDDO  
                   DO i=1,nrtm
                      n1=intbuf_tab(n)%IRECTM(4*(i-1)+1)
                      ms1 = ms(n1)
                      n2=intbuf_tab(n)%IRECTM(4*(i-1)+2)
                      ms2 = ms(n2)
                      n3=intbuf_tab(n)%IRECTM(4*(i-1)+3)
                      ms3 = ms(n3)
                      n4=intbuf_tab(n)%IRECTM(4*(i-1)+4)
                      IF (n3 /= n4) THEN
                         ms4 = ms(n4)
                         intbuf_tab(n)%STIFMSDT_M(i) = stfacm*fourth*(ms1+ms2+ms3+ms4)
                      ELSE
                        intbuf_tab(n)%STIFMSDT_M(i) = stfacm*third*(ms1+ms2+ms3)
                      ENDIF
                    ENDDO  
 
                    IF(nty==25.AND.ipari(58,n) > 0) THEN
                       nedge = ipari(68,n)
                       DO i=1,nedge
                          n1= intbuf_tab(n)%LEDGE(nledge*(i-1)+5)
                          n2= intbuf_tab(n)%LEDGE(nledge*(i-1)+6)
                          ms1 = ms(n1)
                          ms2 = ms(n2)
                          intbuf_tab(n)%STIFMSDT_EDG(i) = half*stfacm*(ms1+ms2)
                       ENDDO
                    ENDIF               
                ENDIF
             ENDIF
          ENDDO
C---- ISTIF_DT flag to compute initial time step if no contact time step is set -----
          flagdt = 0
          DO n=1,ninter
             nty = ipari(7,n)
             IF(nty==24.OR.nty==25) THEN
                istif_msdt = ipari(97,n)
                dtstif   = intbuf_tab(n)%VARIABLES(48)
                IF(istif_msdt > 0) THEN
                   IF (dtstif == zero) flagdt = 1
                ENDIF
             ENDIF
          ENDDO
          istif_dt =    flagdt
 
      RETURN
      END SUBROUTINE inintmass