iniparsen.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    iniparsen     ../starter/source/tools/sensor/iniparsen.F
!||--- called by ------------------------------------------------------
!||    inisen        ../starter/source/tools/sensor/inisen.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE iniparsen(SENSORS,NSECT,NINTER,NINTSUB,NRWALL,NRBODY)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------  
      USE message_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
c#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NSECT,NINTER,NINTSUB,NRWALL,NRBODY
      TYPE (SENSORS_) ,INTENT(INOUT) :: SENSORS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,NOSYS,ISECT,IINT,IRWAL,IRBOD,COMPTEUR,SENS_TYPE,SECT_ID,INT_ID,SUB_ID,RWAL_ID,RBOD_ID
      INTEGER, DIMENSION(0:NSECT+NINTER+NINTSUB+NRWALL+NRBODY) :: TABLOCAL
C-----------------------------------------------
C     Special treatment of sensors with Parith/on (type 6,11,12,13)
C     Tabsensor(i) pointe vers les interfaces/sections/rwalls/rbodies concernees 
C     par les sensors type force
c=======================================================================
      tablocal(:) = 0
c
      DO i=1,sensors%NSENSOR
        sens_type = sensors%SENSOR_TAB(i)%TYPE
        IF (sens_type == 12 ) THEN         ! sensort type section
          isect = sensors%SENSOR_TAB(i)%IPARAM(1)
          tablocal(isect) = i
        ELSEIF (sens_type == 6) THEN       ! sensort type interface
          int_id = sensors%SENSOR_TAB(i)%IPARAM(1)
          iint   = int_id + nsect
          tablocal(iint) = i
        ELSEIF (sens_type == 7) THEN       ! sensort type rwall
          rwal_id = sensors%SENSOR_TAB(i)%IPARAM(1)
          irwal   = rwal_id + nsect + ninter+ nintsub
          tablocal(irwal) = i
        ELSEIF (sens_type == 11) THEN      ! sensort type rbody
          rbod_id = sensors%SENSOR_TAB(i)%IPARAM(1)
          irbod   = rbod_id + nsect + ninter+ nintsub + nrwall
          tablocal(irbod) = i
        ELSEIF (sens_type == 13) THEN      ! sensort type work
          sect_id = sensors%SENSOR_TAB(i)%IPARAM(3)
          int_id  = sensors%SENSOR_TAB(i)%IPARAM(4)
          sub_id  = sensors%SENSOR_TAB(i)%IPARAM(5)
          rwal_id = sensors%SENSOR_TAB(i)%IPARAM(6)
          rbod_id = sensors%SENSOR_TAB(i)%IPARAM(7)
        
          isect = sect_id
          IF (isect > 0) tablocal(isect) = i
c
          iint = int_id + nsect
          IF (int_id > 0) tablocal(iint)=i     ! interface
          iint = sub_id + nsect
          IF (sub_id > 0) tablocal(iint)=i     ! sub-interface
c
          irwal = rwal_id + nsect + ninter+ nintsub
          IF (rwal_id > 0) tablocal(irwal)=i 
c
          irbod = rbod_id + nsect + ninter+ nintsub + nrwall
          IF (rbod_id > 0) tablocal(irbod)=i 
        ENDIF
      ENDDO
c------------
      nosys=1      ! No systeme section,interface,rwall, rbody
      DO WHILE (tablocal(nosys) == 0)
        nosys=nosys+1
      ENDDO
C
      DO i=1,nosys
        sensors%TABSENSOR(i) = tablocal(nosys)
      ENDDO
C
      compteur=1
      DO i = nosys, nsect+ninter+nintsub+nrwall+nrbody
        IF (tablocal(i)==0) THEN
          sensors%TABSENSOR(i+1) = sensors%TABSENSOR(i)
        ELSE
          sensors%TABSENSOR(i+1) = sensors%TABSENSOR(i) + compteur
          compteur=compteur+1
        ENDIF
      ENDDO
C------------
      RETURN
      END