init_i25_edge.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    init_i25_edge   ../engine/source/interfaces/int25/init_i25_edge.F
!||--- called by ------------------------------------------------------
!||    resol           ../engine/source/engine/resol.F
!||--- uses       -----------------------------------------------------
!||    intbufdef_mod   ../common_source/modules/interfaces/intbufdef_mod.F90
!||====================================================================
        SUBROUTINE init_i25_edge(NLEDGE,NINTER,NPARI,IPARI,INTBUF_TAB)
!$COMMENT
!       INIT_I25_EDGE description :
!       for interface type 25, find the solid edge & non-main edge
!
!       init_i25_edge organization :
!           loop over the interface
!               * if NiN is an interface type 25 with edge to edge --> find the solid edge
!$ENDCOMMENT
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE intbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "i25edge_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(in) :: NLEDGE !< dim of ledge array
        INTEGER, INTENT(in) :: NINTER !< number of interface
        INTEGER, INTENT(in) :: NPARI !< dim of IPARI array
        INTEGER, DIMENSION(NPARI,NINTER), INTENT(in) :: IPARI !< interface data
        TYPE(intbuf_struct_), DIMENSION(NINTER), INTENT(inout) :: INTBUF_TAB !< interface data
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
        INTEGER :: I,J
        INTEGER :: INTERFACE_TYPE
        INTEGER :: SOL_EDGE,SH_EDGE,IEDGE,NEDGE
        INTEGER, DIMENSION(:), ALLOCATABLE :: TMP_ARRAY
C-----------------------------------------------
    
        ! ------------------------
        ! loop over the interface
        DO i=1,ninter
          intbuf_tab(i)%NUMBER_EDGE_TYPE1 = 0
          intbuf_tab(i)%NUMBER_EDGE_TYPE1_0 = 0
          interface_type = ipari(7,i)
          iedge = ipari(58,i)
          ! -----------------
          ! check if the interface is a type 25 with edge to edge
          IF(interface_type==25.AND.iedge/=0) THEN
            nedge = ipari(68,i)
            ALLOCATE (tmp_array(nedge) )
            ! ----------
            ! loop over the edge to find the edge solid
            DO j=1,nedge
              IF(intbuf_tab(i)%LEDGE((j-1)*nledge+ledge_type)==1) THEN
                intbuf_tab(i)%NUMBER_EDGE_TYPE1 = intbuf_tab(i)%NUMBER_EDGE_TYPE1 + 1
                tmp_array(intbuf_tab(i)%NUMBER_EDGE_TYPE1) = j
              ENDIF
            ENDDO
            ALLOCATE( intbuf_tab(i)%EDGE_TYPE1(intbuf_tab(i)%NUMBER_EDGE_TYPE1) )
            intbuf_tab(i)%EDGE_TYPE1(1:intbuf_tab(i)%NUMBER_EDGE_TYPE1) = tmp_array(1:intbuf_tab(i)%NUMBER_EDGE_TYPE1)
            ! ----------
 
            ! ----------
            ! loop over the edge to find the edge solid & the edge S
            sol_edge = iedge/10 ! solids
            sh_edge = iedge-10*sol_edge ! shells
            DO j=1,nedge
              IF(intbuf_tab(i)%LEDGE((j-1)*nledge+ledge_type)>=0.AND.
     .           (intbuf_tab(i)%LEDGE((j-1)*nledge+ledge_type)==1.OR.sh_edge==0) ) THEN
                intbuf_tab(i)%NUMBER_EDGE_TYPE1_0 = intbuf_tab(i)%NUMBER_EDGE_TYPE1_0 + 1
                tmp_array(intbuf_tab(i)%NUMBER_EDGE_TYPE1_0) = j
              ENDIF
            ENDDO
            ALLOCATE( intbuf_tab(i)%EDGE_TYPE1_0(intbuf_tab(i)%NUMBER_EDGE_TYPE1_0) )
            intbuf_tab(i)%EDGE_TYPE1_0(1:intbuf_tab(i)%NUMBER_EDGE_TYPE1_0) = tmp_array(1:intbuf_tab(i)%NUMBER_EDGE_TYPE1_0)
            ! ----------
 
            DEALLOCATE( tmp_array )
          ELSE
            ALLOCATE( intbuf_tab(i)%EDGE_TYPE1(intbuf_tab(i)%NUMBER_EDGE_TYPE1) )
            ALLOCATE( intbuf_tab(i)%EDGE_TYPE1_0(intbuf_tab(i)%NUMBER_EDGE_TYPE1_0) )
          ENDIF
          ! -----------------
        ENDDO
        ! ------------------------
 
        RETURN
        END SUBROUTINE init_i25_edge