int18_law151_alloc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    int18_law151_alloc   ../starter/source/interfaces/int18/int18_law151_alloc.F
!||--- called by ------------------------------------------------------
!||    lectur               ../starter/source/starter/lectur.F
!||--- uses       -----------------------------------------------------
!||====================================================================
        SUBROUTINE int18_law151_alloc(NPARI,NINTER,NUMNOD,NUMELS,MULTI_FVM,IPARI)
!$COMMENT
!       INT18_LAW151_ALLOC description
!       allocation of array for interface 18 combined 
!       with law151
!       
!       INT18_LAW151_ALLOC organization :
!       - check if /INT18 + /LAW151 is used
!       - allocate the arrays
!$ENDCOMMENT
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------           
        USE multi_fvm_mod
        USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(in) :: NPARI !< first dim of ipari array
        INTEGER, INTENT(in) :: NINTER !< number of interface
        INTEGER, INTENT(in) :: NUMNOD !< number of node
        INTEGER, INTENT(in) :: NUMELS !< number of solid
        INTEGER, DIMENSION(NPARI,NINTER), INTENT(in) :: IPARI !< data of intarface
        TYPE(MULTI_FVM_STRUCT) :: MULTI_FVM !< structure for multifluid solver
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: N,II,MY_SIZE
        INTEGER :: NTY,INACTI
        INTEGER, DIMENSION(NINTER) :: INT18_LIST
        INTEGER, DIMENSION(NINTER) :: IS_INTER_USED_WITH_LAW151
C-----------------------------------------------
        !   check if int18 + law151 is used in the model
        !   and create a list of int18 + law151
        multi_fvm%IS_INT18_LAW151 = .false.
        my_size = 0
        ii = 0
        ! -------------------------------
        IF(multi_fvm%IS_USED) THEN
            DO n=1,ninter
                is_inter_used_with_law151(n) = 0
                nty   =ipari(7,n)
                inacti = ipari(22,n)           
                !   int18 = int7 + inacti=7 (7+7=18) 
                IF( (nty==7).AND.(inacti ==7)) THEN
                    multi_fvm%IS_INT18_LAW151 = .true.
                    my_size = numnod + numels
                    ii = ii + 1
                    int18_list(ii) = n  !   list of interface int18
                    is_inter_used_with_law151(n) = 1
                ENDIF
            ENDDO
        ENDIF     
        ! -------------------------------  
        multi_fvm%S_APPEND_ARRAY = my_size
        ! number & list of interface 18 
        multi_fvm%NUMBER_INT18 = ii
        ALLOCATE( multi_fvm%INT18_LIST(multi_fvm%NUMBER_INT18) ) ; multi_fvm%INT18_LIST(:) = 0
        ALLOCATE( multi_fvm%IS_INTER_USED_WITH_LAW151(ninter) ) ;  multi_fvm%IS_INTER_USED_WITH_LAW151(:) = 0
        ! allocation of X/V/MASS extended to NUMNOD+NUMELS
        ! 1:NUMNOD --> classical x/v/mass
        ! NUMNOD+1:NUMNOD+NUMELS --> x/v/mass of phantom nodes (located to the center of 
        !                            the ALE elements)
        ALLOCATE( multi_fvm%X_APPEND(3*my_size) )
        ALLOCATE( multi_fvm%V_APPEND(3*my_size) )
        ALLOCATE( multi_fvm%MASS_APPEND(my_size) )
        ALLOCATE( multi_fvm%KINET_APPEND(my_size) )
        
        ! allocation of INT18_GLOBAL_LIST : marker for the interface /INT18+LAW151
        ALLOCATE( multi_fvm%INT18_GLOBAL_LIST(ninter) )
 
        IF( multi_fvm%IS_INT18_LAW151 ) THEN
            multi_fvm%INT18_LIST(1:multi_fvm%NUMBER_INT18) = int18_list(1:multi_fvm%NUMBER_INT18)
            multi_fvm%IS_INTER_USED_WITH_LAW151(1:ninter) = is_inter_used_with_law151(1:ninter)
        ENDIF
 
        RETURN
        END SUBROUTINE int18_law151_alloc
C===============================================================================