iombr.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    iombr            ../starter/source/initial_conditions/detonation/iombr.f
!||--- called by ------------------------------------------------------
!||    ecran1           ../starter/source/initial_conditions/detonation/ecran1.F
!||    ecran2           ../starter/source/initial_conditions/detonation/ecran2.F
!||--- uses       -----------------------------------------------------
!||    detonators_mod   ../starter/share/modules1/detonators_mod.F
!||====================================================================
      INTEGER FUNCTION iombr(DETONATOR_WAVE_SHAPER,X,IECR,DDMX,VDET_ARG)
      USE detonators_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real ddmx
      INTEGER iecr(*)
      my_real x(3,numnod)
      my_real vdet_arg
      TYPE(detonator_wave_shaper_struct_) :: detonator_wave_shaper
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr11_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER jombr, kombr, ii, i,npe
      my_real yld, zld, dd, d2, eps, dd_up, dd_down,
     .        y2, z2,  y1, z1, cross_prod_1,cross_prod_2,
     .        d1, y12, z12, a1, a2, a3, y3, z3, d3
C-----------------------------------------------
 
      npe = detonator_wave_shaper%NUMNOD !number of points
      iombr=0 !function result
      jombr=0
      kombr=0
      !YD,ZD : detonation source
      !YL,ZL : point for which lightening time is going to be computed
      yld=yl-yd
      zld=zl-zd
      dd=yld**2+zld**2 !distance from source
 
      IF(dd > ddmx)THEN
       iombr=2  !function result
       GOTO 999
      ENDIF
 
      !--initialization first node
      eps=em5*dd
      dd_up=dd+eps
      dd_down=dd-eps
      ii=iecr(1)
      y2=x(2,ii)
      z2=x(3,ii)
      cross_prod_2=yld*(z2-zd)-zld*(y2-yd)
      d2 =(y2-yd)*yld+(z2-zd)*zld
 
      !--loop over nodes
      DO i=2,npe
        y1=y2
        z1=z2
        cross_prod_1=cross_prod_2
        d1 =d2
        ii=iecr(i)
        y2=x(2,ii)
        z2=x(3,ii)
        cross_prod_2=yld*(z2-zd)-zld*(y2-yd)
        d2=(y2-yd)*yld+(z2-zd)*zld
        IF(cross_prod_1*cross_prod_2 <= eps)THEN
           !Pi-1 and Pi in different half planes of boundary (DL)
         IF(d2 > dd_up .AND. d1 > dd_up)THEN
           !Pi-1 and Pi after L
           iombr=0
         ELSEIF(d2 < -eps.AND.d1 < -eps)THEN
           !Pi-1 and Pi before D
           iombr=0
         ELSE
           !SEARCHING INTERSECTION [Pi-1,Pi] with [DL]
           y12=y1-y2
           z12=z1-z2
           a1=yl*zld-zl*yld
           a2=y1*z12-z1*y12
           a3=y12*zld-z12*yld
           IF(abs(a3) > eps)THEN
             y3=(y12*a1-yld*a2)/a3
             z3=(z12*a1-zld*a2)/a3
             d3=(y3-yd)*yld+(z3-zd)*zld
             IF(d3 > dd_up.OR.d3 < -eps)THEN
               iombr=0
             ELSEIF(d3 > eps.AND.d3 < dd_down)THEN
               !intersection inside
               iombr=1
               GOTO 999
             ELSEIF(abs(d3) <= eps)THEN
               !intersection in extremity D
               IF(a3 > eps)jombr=1
             ELSEIF(abs(d3-dd) <= eps)THEN
               !intersection in extremity L
               IF(a3 < -eps)kombr=1
             ELSE
               iombr=0
             ENDIF !(D3 > DD_UP.OR.D3 < -EPS)
           ELSE
             iombr=0
           ENDIF !(ABS(A3) > EPS)
         ENDIF !(D2 > DD_UP.AND.D1 > DD_UP)
        ELSE
            !(CROSS_PROD_1*CROSS_PROD_2 > EPS) Pi-1 and Pi are in the same half plane of boundary (DL)
          iombr=0
        ENDIF !(CROSS_PROD_1*CROSS_PROD_2<=EPS)
      END DO !I=2,NPE
 
      IF(jombr+kombr == 2)THEN
        iombr=1
      ELSE
        dto=dto0+sqrt(dd)/vdet_arg
      ENDIF
 
 999  CONTINUE
      IF(iombr == 0)ddmx=dd
 
      RETURN
      END