itrimhpsort.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    itrimhpsort       ../starter/source/output/cluster/itrimhpsort.F
!||--- called by ------------------------------------------------------
!||    hm_read_cluster   ../starter/source/output/cluster/hm_read_cluster.F
!||====================================================================
      SUBROUTINE itrimhpsort(TAB,LEN)
C-----------------------------------------------
c in place heap sort algorithm of integer table with elimination 
c of double entries. Returns the sorted table and final length.
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: LEN, TAB(LEN)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K,L,VAL 
c=======================================================================    
      IF (len < 2) RETURN
      l  = len/2 + 1
      k = len
c
      !The index L will be decremented from its initial value during the
      !"hKing" (heap creation) phase. Once it reaches 1, the index K 
      !will be decremented from its initial value down to 1 during the
      !"retKement-and-promotion" (heap selection) phase.
 
      DO   ! main heap sort loop 
        IF (l > 1)THEN
          l=l-1
          val=tab(l)
        ELSE
          val=tab(k)
          tab(k)=tab(1)
          k=k-1
          IF (k == 1) THEN
            tab(1)=val
            EXIT
          END IF
        END IF
        i=l
        j=l+l
        DO WHILE (j <= k)
          IF(j < k) THEN
            IF (tab(j) < tab(j+1)) j=j+1
          END IF
          IF (val < tab(j)) THEN
            tab(i)=tab(j)
            i=j
            j=j+j
          ELSE
            j=k+1
          END IF
        END DO
        tab(i)=val
      ENDDO  ! main heap sort loop
c
c-----------      
c     eliminate double entries
c-----------      
      j   = 1
      val = tab(1)
      DO i=2,len                
        IF (tab(i) == val) cycle
        val = tab(i)
        j   = j+1                
        tab(j) = val           
      END DO                     
      len = j                 
c-----------      
      RETURN
      END