jwl.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    jwl       ../common_source/eos/jwl.F
!||--- called by ------------------------------------------------------
!||    eosmain   ../common_source/eos/eosmain.F
!||====================================================================
      SUBROUTINE jwl
     1              (iflag,nel  ,pm   ,off  ,eint ,mu  ,mu2 ,
     2               espe ,dvol ,df   ,vnew ,mat  ,psh ,
     3               pnew ,dpdm ,dpde )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of JWL EOS
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
#include      "scr06_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER MAT(NEL), IFLAG, NEL
        my_real pm(npropm,nummat),
     .          off(nel)  ,eint(nel) ,mu(nel)   ,
     .          mu2(nel)  ,espe(nel) ,dvol(nel) ,df(nel)  ,
     .          vnew(nel) ,pnew(nel) ,dpdm(nel),
     .          dpde(nel)
        my_real, INTENT(INOUT) :: psh(nel)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I,MX,IBFRAC
        my_real vdet,bfrac(nel),
     .          rho0 , aa , bb , r1,
     .          r2, w1,  bhe, p0, bulk,
     .          r1df,r2df,er1df,er2df,dpdmu
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
 
        IF(iflag == 0) THEN
 
        ELSEIF(iflag == 1) THEN
 
        ELSEIF(iflag == 2) THEN
          mx     = mat(1)
          rho0   = pm( 1,mx)
          aa     = pm(33,mx)
          bb     = pm(34,mx)
          r1     = pm(35,mx)
          r2     = pm(36,mx)
          w1     = pm(45,mx)
          vdet   = pm(38,mx)
          bhe    = pm(40,mx)
          p0     = pm(31,mx)
          bulk   = pm(44,mx)
          ibfrac = nint(pm(41,mx))
          psh(1:nel) = pm(88,mx)
          DO i=1,nel
            bfrac(i)=one
          ENDDO
          DO i=1, nel
            IF (vnew(i) > zero) THEN
              r1df = r1*df(i)
              r2df = r2*df(i)
              er1df = exp(-r1df)
              er2df = exp(-r2df)
              pnew(i) =  - psh(i) + aa*(one-w1/r1df)*er1df + bb*(one-w1/r2df)*er2df + w1*espe(i)/df(i)
              pnew(i) = max(zero - psh(i), pnew(i))
              ! dPdE  : partial derivative
              ! dPdmu : partial derivative
              ! DPDM  : total derivative
              dpde(i) = w1/df(i)
              dpdmu   =
     .              -aa*w1*er1df/r1 + aa*(one-w1/(r1df))*r1df*r1df*er1df
     .              -bb*w1*er2df/r2 + bb*(one-w1/(r2df))*r2df*r2df*er2df
     .              +w1*espe(i)
              dpdm(i) = dpdmu + (pnew(i)+psh(i))*df(i)*df(i)*dpde(i)
            ENDIF
          ENDDO
        ENDIF
 
C-----------------------------------------------
        RETURN
      END