lcgeo19.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    lcgeo19                  ../starter/source/elements/shell/coque/lcgeo19.f
!||--- called by ------------------------------------------------------
!||    lecstack_ply             ../starter/source/properties/composite_options/stack/lecstack_ply.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    fretitl2                 ../starter/source/starter/freform.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE lcgeo19(GEO   ,IGEO    ,PM ,IPM ,UNITAB,IUNIT,
     .                   ISTACK,IDRAPEID,LSUBMODEL)
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
#include      "drape_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IGEO(NPROPGI),IPM(NPROPMI,*),ISTACK,IDRAPEID(*),IUNIT
      my_real
     .   geo(npropg), pm(npropm,*)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      CHARACTER ISS*3
      INTEGER IPMAT,IMID,MLAWLY1, IG,J,JREC
      my_real
     .    thickt
      INTEGER ISH3N,DRAPE_ID
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE)::TITR,TITR1
      LOGICAL :: IS_AVAILABLE, IS_ENCRYPTED
      LOGICAL :: FOUND
 
 
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      ish3n = igeo(18)
      CALL hm_get_intv('mat_ID', imid, is_available, lsubmodel)
      CALL hm_get_floatv('t', geo(1), is_available, lsubmodel, unitab)
      CALL hm_get_floatv('delta_phi', geo(2), is_available, lsubmodel, unitab)
      CALL hm_get_intv('grsh4n_ID', igeo(40), is_available, lsubmodel)
      CALL hm_get_intv('grsh3n_ID', igeo(41), is_available, lsubmodel)
      CALL hm_get_intv('Npt_ply', igeo(4), is_available, lsubmodel)
      CALL hm_get_floatv('alpha_i', geo(212), is_available, lsubmodel, unitab)
 
      CALL hm_get_intv('drape_ID', drape_id, is_available, lsubmodel)
      CALL hm_get_intv('def_orth', igeo(49), is_available, lsubmodel)
 
      ig = igeo(1)
      IF (igeo(4) <= 0) igeo(4) = 1
      IF (geo(212) == zero) geo(212) = ninty
      IF (is_encrypted) THEN
         WRITE(iout,1000)ig
 1000    FORMAT(
     &    5x,' LAYER  SHELL PROPERTY SET'/,
     &    5x,'------------------------------------'/,
     &    5x,'PROPERTY SET NUMBER . . . . . . . . . .=',i10/,
     &    5x,'CONFIDENTIAL DATA'//)
      ELSE     
          WRITE(iout,2000)ig,imid,geo(1),geo(2),igeo(40),igeo(41),igeo(4),
     .   geo(212),drape_id,igeo(49)
      ENDIF     
      geo(2)=geo(2)*pi/hundred80
      geo(212)=geo(212)*pi/hundred80
      igeo(48) = 0  !  keeped for DRAPE IDENTIFICATION NUMBER
C ------------------------------------
C
C  check for layer materials compatibility moved to "lecgeo"
C
      found = .false.
      IF(imid > 0) THEN
        DO j=1,nummat
           IF (ipm(1,j) == imid) THEN
              igeo(101) = j
              found = .true.
              EXIT
           ENDIF
        ENDDO
      ENDIF  
      IF (.NOT. found) THEN
         CALL fretitl2(titr,igeo(npropgi-ltitr+1),ltitr)
         IF(istack == 0) THEN
            CALL ancmsg(msgid=31,
     .           msgtype=msgerror,
     .           anmode=aninfo_blind_2,
     .           i1=ig,
     .           c1=titr,
     .           i2=imid)  
         ELSE
            CALL ancmsg(msgid=1151,
     .           msgtype=msgerror,
     .           anmode=aninfo_blind_2,
     .           i1=ig,
     .           c1=titr,
     .           i2=imid) 
            
         ENDIF  
         igeo(101) = 1   
      ENDIF
C
C  check for wright drape id definition
C
      IF (ndrape > 0 .OR. drape_id > 0) THEN
         found = .false.
        DO j=1,ndrape
          IF (drape_id > 0 .AND. drape_id == idrapeid(j)) THEN
             igeo(48) = drape_id
             found = .true.
             EXIT
           ENDIF 
        ENDDO
        IF (.NOT. found) THEN
           IF (drape_id > 0)THEN
              CALL fretitl2(titr,igeo(npropgi-ltitr+1),ltitr)
              CALL ancmsg(msgid=1153,
     .             msgtype=msgerror,
     .             anmode=aninfo,
     .             i1=ig,
     .             c1=titr,
     .             i2=drape_id)
           ENDIF
        ENDIF
      ENDIF ! IF (NDRAPE > 0)
c-----------
      RETURN
c-----------
 2000 FORMAT(/,
     & 5x,'PLY PROPERTY SET ',/,
     & 5x,'PROPERTY SET NUMBER . . . . . . . . . . . .  . .=',i10/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . . . .  . .=',i10/,
     & 5x,'LAYER THICKNESS . . . . . . . . . . . . . . .  .=',1pg20.13/,
     & 5x,'INCREMENTAL ANGLE (DIR 1,PROJ(DIR 1 / SHELL). . .=',1pg20.13/,      
     & 5x,'SHELL 4-nodes GROUP IDENTIFIER. . . . . . .  . .=',i10/,
     & 5x,'SHELL 3-nodes GROUP IDENTIFIER. . . . . . .  . .=',i10/,
     & 5x,'NUMBER OF INTEGRATION POINTS THROUGH LAYER.  . .=',i10/,
     & 5x,'ORTHOTROPY ANGLE BETWEEN (DIR 1,DIR 2). . . . . =',1pg20.13/,
     & 5x,'DRAPE IDENTIFIER  . . . . . . . . . . . . .  . .=',i10/,
     & 5x,'DEF_ORTH FLAG . . . . . . . . . . . . . . . . . =',i10/)
      END