lecacc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C=======================================================================
!||====================================================================
!||    lecacc                 ../starter/source/tools/accele/lecacc.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    anodset                ../starter/source/output/analyse/analyse_node.c
!||    fretitl                ../starter/source/starter/freform.F
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    usr2sys                ../starter/source/system/sysfus.F
!||    vdouble                ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE lecacc(LACCELM,ACCELM,ITABM1,UNITAB,IXC,
     .                  ISKN, NOM_OPT, LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
      use element_mod , only : nixc
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   A n a l y s e   M o d u l e
C-----------------------------------------------
#include      "analyse_name.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "sphcom.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER ITABM1(*), LACCELM(3,*),
     .   ixc(nixc,*),iskn(liskn,*)
      INTEGER NOM_OPT(LNOPT1,*)
C     REAL
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      my_real accelm(llaccelm,*)
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, ID, NOD, ISK, UID, IG, L
      INTEGER N, NS
      my_real :: f, bid ,dist
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER(LEN=NCHARKEY) :: KEY2
      LOGICAL :: IS_AVAILABLE, FOUND
C-----------------------------------------------
C   D a t a
C-----------------------------------------------
      DATA mess/'ACCELEROMETER DEFINITION                '/  
C---------------------------------------------------
C     B e g i n n i n g   o f   S u b r o u t i n e 
C---------------------------------------------------
      WRITE(istdo,'(A)')' .. ACCELEROMETERS'
      is_available = .false.
      CALL hm_option_start('/ACCEL')
      DO i = 1, naccelm
        CALL hm_option_read_key(lsubmodel, option_titr = titr, option_id = id, unit_id = uid)
        nom_opt(1, i) = id
        CALL fretitl(titr, nom_opt(lnopt1-ltitr+1, i), ltitr)
        found = .false.
          DO j=1,unitab%NUNITS
            IF (unitab%UNIT_ID(j) == uid) THEN  
              found = .true.  
              EXIT
           ENDIF
        ENDDO
        IF (.NOT. (uid == 0 .OR. found)) THEN
           CALL ancmsg(msgid = 659, anmode = aninfo, msgtype = msgerror,
     .          c1 = 'ACCELEROMETER', c2 = 'ACCELEROMETER', c3 = titr, 
     .          i2 = uid, i1 = id)
        ENDIF
        dist = zero
        CALL hm_get_intv('nodeid', nod, is_available, lsubmodel)
        CALL hm_get_intv('skewid', isk, is_available, lsubmodel)
        CALL hm_get_floatv('cutoff', f, is_available, lsubmodel, unitab)
C
        found = .false.
        DO j = 0, numskw + min(1, nspcond) * numsph + nsubmod
          IF(isk == iskn(4, j + 1)) THEN
            isk = j + 1
            found = .true.
            EXIT
          ENDIF
        ENDDO
        IF (.NOT. found) THEN
           CALL ancmsg(msgid = 137, anmode = aninfo, msgtype = msgerror,
     .          c1 = 'ACCELEROMETER', c2 = 'ACCELEROMETER', c3 = titr,
     .          i1 = id, i2 = isk)
        ENDIF
 
C
        laccelm(1,i)=usr2sys(nod,itabm1,mess,id)
        CALL anodset(laccelm(1,i), check_used)
        laccelm(2,i)=id
        laccelm(3,i)=isk
        accelm(1,i)=f
C-------------------------------------
        WRITE (iout,'(///,A)')'          ACCELEROMETER'
        WRITE (iout,'(A/)')   '          -------------'
        WRITE (iout,'(A,I10)')
     .    ' ACCELEROMETER NUMBER . . . . . . . . .',id,
     .    ' NODE NUMBER. . . . . . . . . . . . . .',nod,
     .    ' SKEW FRAME NUMBER. . . . . . . . . . .',iskn(4,isk)
        WRITE (iout,'(A,1PG20.13)')
     .    ' 4-POLE BUTTERWORTH CORNER FREQUENCY. .',f
      ENDDO
C-------------------------------------
C     Searching for duplicate ID
C-------------------------------------
      naccelm=naccelm
      CALL vdouble(nom_opt,lnopt1,naccelm,mess,0,bid)
C----
      RETURN
      END