lecfill.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    lecfill                    ../starter/source/elements/initia/lecfill.F
!||--- called by ------------------------------------------------------
!||    lectur                     ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                     ../starter/source/output/message/message.F
!||    hm_get_float_array_index   ../starter/source/devtools/hm_reader/hm_get_float_array_index.F
!||    hm_get_int_array_index     ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    hm_get_intv                ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_count            ../starter/source/devtools/hm_reader/hm_option_count.F
!||    hm_option_read_key         ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start            ../starter/source/devtools/hm_reader/hm_option_start.F
!||    uel2sys                    ../starter/source/initial_conditions/inista/yctrl.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod         ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod                ../starter/share/message_module/message_mod.F
!||    submodel_mod               ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE lecfill(IXS,FILLSOL,UNITAB,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE submodel_mod
      USE unitab_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : ncharkey
      use element_mod , only : nixs
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXS(NIXS,*)
      my_real fillsol(*)
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB
      TYPE(submodel_data) LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: INI,J,N,ID_ELEM,IE,UID,SUB_ID,STAT,NB_INIBRI, IFLAGUNIT,IUNIT,NB_ELEMENTS
      INTEGER :: WORKS(70000)
      INTEGER, DIMENSION(:), ALLOCATABLE :: KSYSUSRS,INDEXS,ITRIS
      CHARACTER(LEN=NCHARKEY) :: KEY
      my_real :: fill
      LOGICAL :: IS_AVAILABLE
      INTEGER, EXTERNAL ::  UEL2SYS
C=======================================================================
      DO n=1,numels
        fillsol(n)=one
      END DO
C------------------------------------
      is_available = .false.
!-----------------------------------------
!       pre-reading of FILL for interfaces stiffness computation
!             ---  /INIBRI/FILL  ---
!-----------------------------------------
      CALL hm_option_count('/INIBRI', nb_inibri)
!
      IF ( nb_inibri > 0 ) THEN
!
        ! Start reading /INIBRI card 
        CALL hm_option_start('/INIBRI')
!
        nfilsol=0
        DO ini=1,nb_inibri
!
          CALL hm_option_read_key(lsubmodel,
     .                            unit_id  = uid,
     .                            submodel_id = sub_id,
     .                            keyword2 = key)
!
          SELECT CASE (key(1:len_trim(key)))
            CASE ( 'FILL' )
              nfilsol = 1
          END SELECT ! SELECT CASE(KEY)
!
        ENDDO ! DO INI=1,NB_INIBRI
C---------
C---------
        IF(nfilsol==0)RETURN
C---------
C---------
C------------------------------------
        ALLOCATE (itris(numels)                      ,stat=stat)
        IF (stat /= 0) THEN
          CALL ancmsg(msgid=268,anmode=aninfo,
     .                          msgtype=msgerror,
     .                          c1='ITRIS')
          RETURN
        END IF
        ALLOCATE (indexs(2*numels)                   ,stat=stat)
        IF (stat /= 0) THEN
          CALL ancmsg(msgid=268,anmode=aninfo,
     .                          msgtype=msgerror,
     .                          c1='INDEXS')
          RETURN
        END IF
        ALLOCATE (ksysusrs(2*numels)                 ,stat=stat)
        IF (stat /= 0) THEN
          CALL ancmsg(msgid=268,anmode=aninfo,
     .                          msgtype=msgerror,
     .                          c1='KSYSUSRS')
          RETURN
        END IF
        itris  = 0
        indexs = 0
        ksysusrs=0
!
        DO ie = 1, numels
          itris(ie) = ixs(nixs,ie)
        END DO
        CALL my_orders(0,works,itris,indexs,numels,1)
        DO j = 1, numels
          ie=indexs(j)
          ksysusrs(j)       =ixs(nixs,ie)
          ksysusrs(numels+j)=ie
        END DO
C------------------------------------
        CALL hm_option_start('/INIBRI')
        DO ini=1,nb_inibri
!
          CALL hm_option_read_key(lsubmodel,
     .                            unit_id  = uid,
     .                            submodel_id = sub_id,
     .                            keyword2 = key)
!
          iflagunit = 0
          DO iunit=1,unitab%NUNITS
            IF (unitab%UNIT_ID(iunit) == uid) THEN    
              iflagunit = 1
              EXIT
            ENDIF
          ENDDO
          IF (uid/=0.AND.iflagunit == 0) THEN
            CALL ancmsg(msgid=659,anmode=aninfo,msgtype=msgerror,
     .                  i2=uid,i1=sub_id,c1='INIBRI',
     .                  c2='INIBRI',c3=' ')
          ENDIF
c---------------------------------------
          SELECT CASE (key(1:len_trim(key)))
C---------
            CASE ( 'FILL' )
C---------
              nfilsol = 1
              CALL hm_get_intv('inibri_fill_count',nb_elements,is_available,lsubmodel)
!
              DO j=1,nb_elements
                ! Reading  ---  ID_ELEM, FILL  ---
                CALL hm_get_int_array_index('brick_ID',id_elem,j,is_available,lsubmodel)
                CALL hm_get_float_array_index('value',fill,j,is_available,lsubmodel,unitab)
!
                ie=uel2sys(id_elem,ksysusrs,numels)
                IF(ie/=0) fillsol(ie)=fill
              ENDDO ! DO J=1,NB_ELEMENTS
C---------
          END SELECT ! SELECT CASE(KEY)
!
        ENDDO ! DO INI=1,NB_INIBRI
!
        DEALLOCATE(ksysusrs,indexs,itris)
!
      ENDIF ! IF ( NB_INIBRI > 0 ) THEN
!
C-----------------------------------------------
      RETURN
      END