lecm85_void.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    lecm85_void   ../starter/source/materials/mat/mat085/lecm85_void.F
!||====================================================================
      SUBROUTINE lecm85_void(IIN  ,IOUT ,UPARAM ,MAXUPARAM,NUPARAM,
     .                  NUVAR,IFUNC,MAXFUNC,NFUNC    ,PARMAT )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C----------+---------+---+---+--------------------------------------------
C VAR      | SIZE    |TYP| RW| DEFINITION
C----------+---------+---+---+--------------------------------------------
C IIN      |  1      | I | R | INPUT FILE UNIT (D00 file) 
C IOUT     |  1      | I | R | OUTPUT FILE UNIT (L00 file)
C UPARAM   | NUPARAM | F | W | USER MATERIAL PARAMETER ARRAY
C MAXUPARAM|  1      | I | R | MAXIMUM SIZE OF UPARAM 
C NUPARAM  |  1      | I | W | SIZE OF UPARAM =< MAXUPARAM
C NUVAR    |  1      | I | W | NUMBER OF USER ELEMENT VARIABLES
C----------+---------+---+---+--------------------------------------------
C IFUNC    | NFUNC   | I | W | FUNCTION NUMBER ARRAY
C MAXFUNC  |  1      | I | R | MAXIMUM SIZE OF IFUNC
C NFUNC    |  1      | I | W | SIZE OF IFUNC =< MAXFUNC
C----------+---------+---+---+--------------------------------------------
C (STIFINT)|                 | Replaced by PARMAT(1)
C PARMAT   |  3      | F | W | 1)STIFNESS MODULUS FOR INTERFACE
C          |(in v31) |   |   |       (AND INITIAL TIME STEP COMPUTATION)
C          |         |   |   | 2)YOUNG MODULUS (only needed for shells)
C          |         |   |   | 3)POISSON'S RATIO (only needed for shells)
C          |         |   |   | 4... Possible future use
C----------+---------+---+---+--------------------------------------------
C
C     This subroutine read the user material parameters.
C     The material cards that are common for all materials
C     (card 1 to 7 in version 2.2) have previously been read.
C     The NUPARAM material datas have to bee stored in UPARAM array.
C     If some standard radioss functions (time function or 
C     x,y function) are needed, this NFUNC function numbers have to 
C     bee stored in IFUNC array.  
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IIN,IOUT,MAXUPARAM,NUPARAM,NUVAR,MAXFUNC,NFUNC,
     .        ifunc(maxfunc)
      my_real   uparam(maxuparam),parmat(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real e,nu,a11,a12,a44
C=======================================================================
C
C     EXAMPLE : ELASTIC LAW 
C
C=======================================================================
C
      READ(iin,'(2F16.0)')e,nu
      a11 = e * (one - nu) / (one + nu) / (one - two*nu)
      a12 = e * nu / (one + nu) / (one - two*nu)
      a44 = e / two / (one+nu)
C
      IF(nu<zero.OR.nu>=half)THEN
         WRITE(iout,*)' ** ERROR : WRONG NU VALUE'
      ENDIF
      nuparam = 7
      IF(nuparam>maxuparam)THEN
        WRITE(iout,*)' ** ERROR : NUPARAM GT MAXUPARAM'
        WRITE(iout,*)'      NUPARAM =',nuparam,
     .                ' MAXUPARAM =',maxuparam
      ELSE
C used in sigeps29 (solid 2d,3d)
        uparam(1) = a11 
        uparam(2) = a12
        uparam(3) = a44
        uparam(4) = e/(one-nu*nu)
        uparam(5) = nu*e/(one - nu*nu)
        uparam(6) = half*e/(one + nu)
 
        uparam(7) = e
      ENDIF
C
      nuvar = 0
      nfunc = 0
C used for interface (solid+shell)
      parmat(1) = a11
C used for shell
      parmat(2) = e
      parmat(3) = nu
C
      WRITE(iout,1000)
      WRITE(iout,1100)e,nu
C
 1000 FORMAT(
     & 5x,'  ELASTIC USER LAW ',/,
     & 5x,'  ---------------- ',//)
 1100 FORMAT(
     & 5x,'E . . . . . . . . . . . . . . . . . . .=',e12.4/
     & 5x,'NU. . . . . . . . . . . . . . . . . . .=',e12.4//)
C
      RETURN
      END