line_decomp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    line_decomp    ../starter/source/model/group/line_decomp.F
!||--- called by ------------------------------------------------------
!||    lectur         ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    my_exit        ../starter/source/output/analyse/analyse.c
!||--- uses       -----------------------------------------------------
!||    front_mod      ../starter/share/modules1/front_mod.F
!||====================================================================
      SUBROUTINE line_decomp(IGRSLIN)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE front_mod
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
       TYPE (SURF_)   , DIMENSION(NSLIN)   :: IGRSLIN
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NN,IAD,IAD1,IAD2,IAD11,ND1,ND2,P,P1,P2
      INTEGER I,J
      LOGICAL PSEARCH
C---------------------------------------------------------------
C Care : In lines -  Element ID is wrong after Element grouping
C I reuse last field to store the processor ID.
C When lines are taken care in Element Grouping 
C   1. Set processor only when no element is set in lines
C   2. Split lines accordingly
!       /LINE are not used in the engine and the split is wrong in
!       case of useless line (ie. when a line is defined but not 
!       used by an interface or other stuffs) --> 
!       2 nodes (defining a segment) can be on 2 different processors
!       in this case, the segment is not written in the restart file
!       one could also define the nodes on the same processor but
!       it will increase the comm.
C---------------------------------------------------------------
      DO i = 1, nslin
        nn  = igrslin(i)%NSEG
        DO j = 1, nn
          p=0
          psearch= .true.
          nd1 = igrslin(i)%NODES(j,1)
          nd2 = igrslin(i)%NODES(j,2)
C For better performance, I don't use nlocal, but use low level system
          iad1 = ifront%IENTRY(nd1) 
          iad2 = ifront%IENTRY(nd2) 
 
          iad11 = iad1
C
C Initialization
C
          p1 = ifront%P(1,iad1)
          p2 = ifront%P(1,iad2)
C
C Common case : node are on same domain
C
          IF(p1==p2) THEN
             p=p1
             psearch= .false.
          ENDIF
C
          DO WHILE (psearch)
 
C P1 equal to p2 found
            IF(p1 == p2) THEN
               p=p1
               psearch= .false.
            ENDIF
 
C Search leaves - in case 2 nodes from segments are in different domain.
            IF(p1 == 0)THEN
               print*,'ERROR P1',nd1,nd2
               CALL my_exit(2)
            ENDIF
            IF(p2 == 0)THEN
               print*,'ERROR P2',nd1,nd2
               CALL my_exit(2)
            ENDIF
C Move forward
 
            !   ---------------------
            IF(p1 < p2)THEN
              iad1 = ifront%P(2,iad1)
            ENDIF
 
            IF(p1 > p2)THEN
              iad2 = ifront%P(2,iad2)
            ENDIF            
            !   ---------------------
            !   iad1 = 0 or iad2 = 0 --> the last processor id 
            !   is reached
            IF(iad1==0.OR.iad2==0) THEN
                ! skip this segment 
                p1=0
                p2=0
                p=0
                psearch= .false.
            ELSE
                p1 = ifront%P(1,iad1)
                p2 = ifront%P(1,iad2)
            ENDIF
            !   ---------------------
          ENDDO  ! DO WHILE (PSEARCH)
C For this split - I use 3rd field to set Processor (supposed empty)
 
          igrslin(i)%PROC(j) = p
 
        ENDDO    ! DO J = 1, NN
      ENDDO      ! DO I = 1, NSLIN
 
      RETURN
      END