m18law.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    m18law   ../engine/source/materials/mat/mat018/m18law.F
!||--- called by ------------------------------------------------------
!||    mmain    ../engine/source/materials/mat_share/mmain.F90
!||--- calls      -----------------------------------------------------
!||    interp   ../engine/source/tools/curve/interp.F
!||====================================================================
      SUBROUTINE m18law(
     1   PM,      VOLU,    EINT,    THETA,
     2   DELTAX,  TF,      NPF,     DT2T,
     3   NELTST,  ITYPTST, IPM,     STI,
     4   VOLN,    MAT,     NGL,     CONDE,
     5   NEL,     ITY,     IDT_THERM,DT_THERM)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "param_c.inc"
#include      "scr18_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: ITY
      INTEGER, INTENT(IN) :: IDT_THERM
      INTEGER NPF(*),IPM(NPROPMI,*),MAT(*),NGL(*)
      INTEGER NELTST,ITYPTST
      my_real, INTENT(INOUT) :: dt_therm
      my_real :: dt2t
 
      my_real
     .   pm(npropm,*), volu(*), eint(*), theta(*), deltax(*), tf(*),
     .   sti(*),voln(mvsiz), conde(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, IFUNC, NPOINT, ITFUN, IKFUN, MX
      my_real A(MVSIZ), B(MVSIZ),
     .   DTX(MVSIZ), SPH(MVSIZ), RHO0, ESPE, DTDE, T0, BID,
     .   TIMESCAL,TSCAL,ESCAL,KSCAL,
     .   SPH_1,A_1,B_1
C-----------------------------------------------
C=======================================================================
      mx = mat(1)
      sph_1=pm(69,mx)
      a_1  =pm(75,mx)
      b_1  =pm(76,mx)
      DO i=1,nel
        voln(i)=volu(i)
        sph(i)=sph_1
        a(i)  =a_1
        b(i)  =b_1
      ENDDO
 
      DO i=1,nel
        ifunc = ipm(12,mx)
        IF(ifunc/=0)THEN
          rho0=pm( 1,mx)
          npoint=(npf(ifunc+1)-npf(ifunc))/2
          tscal = pm(42,mx)
          escal = pm(43,mx)
          espe  = escal * eint(i) / rho0
          CALL interp(tf(npf(ifunc)),espe,npoint,theta(i),dtde)
          theta(i) = tscal*theta(i)
          sph(i) = rho0 / max(em20,dtde)
        ELSE
          theta(i)=eint(i)/sph(i)
        ENDIF
      ENDDO
 
      itfun = ipm(11,mx)
      IF(itfun/=0)THEN
       t0=pm(79,mx)
       timescal = pm(41,mx)*tt
       npoint=(npf(itfun+1)-npf(itfun))/2
       DO i=1,nel
          CALL interp(tf(npf(itfun)),timescal,npoint,theta(i),bid)
         theta(i) = t0*theta(i)
         eint(i)  = sph(i)*theta(i)
       ENDDO
      ENDIF
 
      DO i=1,nel
        ikfun = ipm(13,mx)
        IF (ikfun /= 0) THEN
          tscal = theta(i) / pm(42,mx) 
          kscal = pm(44,mx)   
          npoint=(npf(ikfun+1)-npf(ikfun))/2
          CALL interp(tf(npf(ikfun)),tscal,npoint,a(i),bid)
          a(i) = kscal * a(i)
          b(i) = zero
        ENDIF
        dtx(i)=half*deltax(i)**2*sph(i)/(a(i)+b(i)*theta(i))        
      ENDDO
 
C--------------------------
C     THERMAL TIME STEP
C--------------------------
        IF(idt_therm == 1)THEN
          DO i=1,nel
             IF(dtx(i)<dt_therm)  dt_therm = dtx(i)
             conde(i) = four*volu(i)*(a(i)+b(i)*theta(i))/deltax(i)*deltax(i)
c             CONDE(I) = CONDE(I)*OFF(I)  
          ENDDO     
        ENDIF  
 
      DO i=1,nel
        ! dt2, nelts, itypts remplaces par dt2t, neltst, ityptst
        IF(dtx(i)>dt2t) cycle
        dt2t=dtx(i)
        neltst =ngl(i)
        ityptst=ity        
      ENDDO
 
      DO i=1,nel
        sti(i)=zero
      END DO
 
      RETURN
      END