m1lawt.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    m1lawt   ../engine/source/materials/mat/mat001/m1lawt.F
!||--- called by ------------------------------------------------------
!||    tforc3   ../engine/source/elements/truss/tforc3.F
!||====================================================================
      SUBROUTINE m1lawt(
     1   PM,      GEO,     OFF,     FOR,
     2   EINT,    AREA,    AL0,     STI,
     3   MAT,     MGM,     EPS,     AL,
     4   NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER MAT(MVSIZ),MGM(MVSIZ)
      my_real
     .   PM(NPROPM,*),GEO(NPROPG,*),OFF(*),FOR(*),EINT(*),
     .   area(*),al0(*),sti(*),eps(mvsiz),al(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J
      my_real
     .   PR(MVSIZ),YM(MVSIZ),GAP(MVSIZ),YMA
C-----------------------------------------------      
      DO i=1,nel
        ym(i)  = pm(20,mat(i))
        pr(i)  = pm(21,mat(i))
        gap(i) = geo(2,mgm(i))
      ENDDO
c
      DO i=1,nel
        IF(gap(i) > zero .AND. al(i) <= (al0(i)-gap(i))) off(i)=one
      ENDDO
c
      DO i=1,nel
        eint(i)=eint(i)+for(i)*eps(i)*al(i)*dt1*half
      ENDDO
c
      DO i=1,nel
        area(i)=area(i)*(one - two*pr(i)*eps(i)*dt1*off(i))
      ENDDO
c
      DO i=1,nel
        yma    = ym(i)*area(i)
        for(i) = for(i)+yma*eps(i)*dt1
        sti(i) = zero
        IF (al(i) /= zero)
     .  sti(i) = yma / al(i)
        sti(i) = sti(i)*off(i)
        for(i) = for(i)*off(i)
      ENDDO
c
      DO i=1,nel
        eint(i)=eint(i)+for(i)*eps(i)*al(i)*dt1*half
      ENDDO
C-----------------------------------------------
      RETURN
      END