m27crak.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C  _clean      SUBROUTINE M27CRAK(JFT,JLT,PM,DAMT,DIR,MATLY,ILAYER,OFF)
!||====================================================================
!||    m27crak     ../engine/source/materials/mat/mat027/m27crak.F
!||--- called by ------------------------------------------------------
!||    sigeps27c   ../engine/source/materials/mat/mat027/sigeps27c.F
!||====================================================================
      SUBROUTINE m27crak(JFT    ,JLT    ,PM     ,DAMT   ,DIR    ,
     2                   IMAT   ,ILAYER ,OFF    ,NGL    ,NEL    ,
     3                   STRN1  ,STRN2  ,STRN3  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT,JLT,ILAYER,NEL
      INTEGER NGL(MVSIZ),IMAT
C     REAL
      my_real
     .   pm(npropm,*),damt(nel,2),dir(nel,2),off(*),
     .   strn1(mvsiz),strn2(mvsiz),strn3(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,NINDX,IDIR
      INTEGER INDX(MVSIZ)
C     REAL
      my_real
     .   cc,bb,cr,norm,
     .   epst1(mvsiz),epst2(mvsiz),epsm1(mvsiz),epsm2(mvsiz),
     .   strp1(mvsiz),strp2(mvsiz),dmax1(mvsiz),dmax2(mvsiz),
     .   epsf1(mvsiz),epsf2(mvsiz)
C-----------------------------------------------
      DO i=jft,jlt
        epst1(i) = pm(60,imat)
        epst2(i) = pm(61,imat)
        epsm1(i) = pm(62,imat)
        epsm2(i) = pm(63,imat)
        dmax1(i) = pm(64,imat)
        dmax2(i) = pm(65,imat)
        epsf1(i) = pm(66,imat)
        epsf2(i) = pm(67,imat)
      ENDDO
C
      DO i=jft,jlt
        cc = (strn1(i)+strn2(i))*half
        bb = (strn1(i)-strn2(i))*half
        cr = sqrt(bb**2+strn3(i)**2)
        strp1(i) = cc + cr
        strp2(i) = cc - cr
      ENDDO
C
C.....GATHER DIRECTION 1
C
      nindx=0
      DO i=jft,jlt
        IF (strp1(i) < epst1(i) .OR. damt(i,1) > zero
     .                          .OR. off(i) == zero) cycle
        nindx=nindx+1
        indx(nindx)=i
      ENDDO
C
      DO i=jft,jlt
        IF (epsf1(i) > zero .AND. strp1(i) > epsf1(i)
     .                      .AND. off(i) == one) THEN
          off(i) = zero
#include "lockon.inc"
          WRITE(iout, *)
     +        ' TOTAL ELEMENT TENSION FAILURE, ELEMENT #',ngl(i)
#include "lockoff.inc"
        ENDIF
      ENDDO
C
C.....1.FIRST FAILURE DIRECTION 1
C
      IF (nindx > 0) THEN
        idir = 1
        DO j=1,nindx
          i = indx(j)
          dir(i,1) = strn3(i)
          dir(i,2) = strp1(i) - strn1(i)
          norm = sqrt(dir(i,1)*dir(i,1)+dir(i,2)*dir(i,2))
          IF (norm < em8) THEN
            dir(i,1) = one
            dir(i,2) = zero
          ELSE
            dir(i,1) = dir(i,1)/norm
            dir(i,2) = dir(i,2)/norm
          ENDIF
          damt(i,1) = (strp1(i)-epst1(i))/(epsm1(i)-epst1(i))
          damt(i,1) =  min(damt(i,1),dmax1(i))
#include "lockon.inc"
          WRITE(iout, '(A,I1,A,I10,5X,A,I3)')
     +        ' FAILURE-',idir,' ELEMENT #',ngl(i),
     +        ' LAYER #',ilayer     
#include "lockoff.inc"
        ENDDO
      ENDIF      
C
      RETURN
      END