mating.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    mating   ../starter/source/materials/mat_share/mating.F
!||--- called by ------------------------------------------------------
!||    matini   ../starter/source/materials/mat_share/matini.F
!||====================================================================
      SUBROUTINE mating(PM   ,VOL ,OFF    ,EINT  ,RHO ,
     .                  SIG  ,IX  ,NIX    ,SIGI  ,EPSP,
     .                  NSIG ,MAT ,NUMS   ,PT    ,NEL ,
     .                  FILL ,TEMP,TEMPEL )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scry_c.inc"
#include      "sphcom.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER   NIX, NSIG, NUMS, NEL
      INTEGER   IX(NIX,*),PT(*),MAT(*)
      my_real :: PM(NPROPM,*), SIG(NEL,6), SIGI(NSIG,*)
      my_real, DIMENSION(NEL) :: vol,off,eint,rho,epsp,fill
      my_real, DIMENSION(NEL) :: temp,tempel
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,II,JJ,N,MA,IFLAGINI
C=======================================================================
      DO I=lft,llt
       iflagini = 0
       ma=mat(i)
       off(i) =one
       IF(ma == 0)cycle
       eint(i)=pm(23,ma)
       rho(i) =pm(89,ma)
       IF (tempel(i) > zero) THEN
         temp(i) = tempel(i)
       ELSE
         temp(i) = pm(79,ma)
       END IF
C-----------------------------
       IF (isigi == 0) THEN
C-----------------------------
        sig(i,1)=-pm(104,ma)
        sig(i,2)=-pm(104,ma)
        sig(i,3)=-pm(104,ma)
C 
        IF (jlag/=0 .AND. jsph == 0) THEN
          vol(i) = vol(i) * ( rho(i) / pm(1,ma) )
        ENDIF
        IF (jeul+jale /= 0 .AND.  pm(1,ma)/=zero) THEN
          eint(i) = eint(i) * rho(i) / pm(1,ma)
        ENDIF
C 
        fill(i)=one
C-----------------------------
       ELSE ! CONTRAINTES INITIALES
C-----------------------------
        IF (abs(isigi)/=3.AND.abs(isigi)/=4.AND.abs(isigi)/=5) THEN
          ii = i+nft
          n = nint(sigi(7,ii))
          IF(n == ix(nix,ii))THEN
            jj = ii
            iflagini = 1
          ELSE
            IF(jsph == 0)THEN
              DO j = 1,max(numsol+numquad,numels+numelq)
                jj= j
                n = nint(sigi(7,j))
                IF(n==0)GOTO 200
                IF(n==ix(nix,ii))THEN
                  iflagini = 1
                  GOTO 60
                ENDIF
              ENDDO
            ELSE
              DO j = 1,numsph
                jj= j
                n = nint(sigi(7,j))
                IF(n==0)GOTO 200
                IF(n==ix(nix,ii))THEN
                  iflagini = 1
                  GOTO 60
                ENDIF
              ENDDO
            ENDIF
            GOTO 200
  60        CONTINUE
          ENDIF
        ELSE
          ii=nft+i
          n =ix(nix,ii)
          jj=pt(ii)
          IF (jj == 0)GOTO 200
          iflagini = 1
        END IF
C-----------
        IF (iflagini == 1)THEN
          sig(i,1)=sigi(1,jj)
          sig(i,2)=sigi(2,jj)
          sig(i,3)=sigi(3,jj)
          sig(i,4)=sigi(4,jj)
          sig(i,5)=sigi(5,jj)
          sig(i,6)=sigi(6,jj)
          IF (isigi == 3.OR.isigi == 4.OR.isigi == 5) THEN
            IF(sigi(8,jj)/=zero) THEN
              IF(jlag/=0.AND.jsph == 0)THEN
                vol(i) = sigi(8,jj)*vol(i) / pm(1,ma)
                rho(i) = sigi(8,jj)
              ELSE
                rho(i) = sigi(8,jj)
              ENDIF
            ELSEIF (jlag/=0.AND.jsph == 0) THEN
              vol(i) = vol(i) * rho(i) / pm(1,ma)
            ENDIF
C           EPSP NON UTILISE DANS MAT TYPE 1 ET ECRASE PAR EINT
            IF (sigi(10,jj)/=zero) epsp(i) = sigi(10,jj)
            IF (sigi( 9,jj)/=zero) eint(i) = sigi(9,jj)
C           TAUX DE REMPLISSAGE
            IF(sigi(11,jj)/=zero) fill(i)=sigi(11,jj)
          ENDIF
        ENDIF
  200   CONTINUE
       ENDIF
      ENDDO
C-----------
      RETURN
      END