meint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    meint        ../engine/source/materials/mat_share/meint.F
!||--- called by ------------------------------------------------------
!||    mmain        ../engine/source/materials/mat_share/mmain.F90
!||--- uses       -----------------------------------------------------
!||    ale_mod      ../common_source/modules/ale/ale_mod.F
!||    output_mod   ../common_source/modules/output/output_mod.F90
!||====================================================================
      SUBROUTINE meint(OUTPUT,
     1   OFF,     SNEW,    QOLD,    EINT,
     2   VNEW,    ESPE,    SOLD1,   SOLD2,
     3   SOLD3,   SOLD4,   SOLD5,   SOLD6,
     4   D1,      D2,      D3,      D4,
     5   D5,      D6,      PSH,     DVOL,
     6   DF,      QNEW,    PNEW,    VIS,
     7   TMU,     EINC,    MLN,     VOL_AVG,
     8   NEL,     JTUR,    JLAG,    JPOR)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE ale_mod
      USE output_mod , ONLY : output_ 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com06_c.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(output_), INTENT(INOUT) :: OUTPUT
      INTEGER, INTENT(IN) :: JTUR
      INTEGER, INTENT(IN) :: JLAG
      INTEGER, INTENT(IN) :: JPOR
      INTEGER MLN,NEL
      my_real OFF(*), SNEW(NEL,6), QOLD(*), EINT(*)
      my_real VNEW(*), ESPE(*), QNEW(*), PNEW(*), SOLD1(*), SOLD2(*),
     .        SOLD3(*), SOLD4(*), SOLD5(*), SOLD6(*), 
     .        dvol(*), df(*), d1(*), d2(*), d3(*), d4(*), d5(*),
     .        d6(*), psh(*), einc(*),
     .        vis(*), tmu(*), vol_avg(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "scr06_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real POLD(MVSIZ), E1, E2, E3, E4, E5, E6, DTA, WFEXTT
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      DTA = half*dt1
 
      IF(ale%GLOBAL%INCOMP == 1 .AND. jlag == 0)THEN
        DO i=1,nel
          pold(i)=(sold1(i)+sold2(i)+sold3(i))*third
          eint(i)=eint(i)+(half*dvol(i)*(pold(i)-psh(i)))*off(i)
          espe(i)=eint(i)*df(i) / max(em15,vnew(i))
          qold(i)=qnew(i)
        ENDDO
        RETURN
      ENDIF
 
      DO i=1,nel
        pold(i)=(sold1(i)+sold2(i)+sold3(i)) * third
        sold1(i)=sold1(i)-pold(i)
        sold2(i)=sold2(i)-pold(i)
        sold3(i)=sold3(i)-pold(i)
        e1=d1(i)*(sold1(i)+snew(i,1))
        e2=d2(i)*(sold2(i)+snew(i,2))
        e3=d3(i)*(sold3(i)+snew(i,3))
        e4=d4(i)*(sold4(i)+snew(i,4))
        e5=d5(i)*(sold5(i)+snew(i,5))
        e6=d6(i)*(sold6(i)+snew(i,6))
        einc(i) = vol_avg(i) * (e1+e2+e3+e4+e5+e6) * dta
      ENDDO
 
      wfextt = zero
      DO i=1,nel
        wfextt = wfextt - dvol(i)*psh(i)
      ENDDO
!$OMP ATOMIC
      output%TH%WFEXT = output%TH%WFEXT + wfextt
 
C
      IF(jtur == 0 .OR. jpor == 2)THEN
       DO i=1,nel
         eint(i)=eint(i)+(einc(i)+half*dvol(i)*(pold(i)-psh(i)-qold(i)-qnew(i)))*off(i)
       ENDDO
      ELSE
       DO i=1,nel
         eint(i)=eint(i) + (einc(i)*(vis(i)-tmu(i))/vis(i) + half*dvol(i)*(pold(i)-psh(i)-qold(i)-qnew(i)))*off(i)
       ENDDO
      ENDIF
C
      DO i=1,nel
        qold(i)=qnew(i)
        espe(i)=eint(i)*df(i) / max(em15,vnew(i)) !ESPE = 'rho0.e'
      ENDDO
 
      !NO NEED TO UPDATE PRESSURE CALLING EOSMAIN SUBROUTINE FOR THESE TWO MATERIAL LAWS SINCE PRESSURE IS NOT ENERGY DEPENDANT.
      ! embedded pressure function
      IF(mln==21)THEN
        DO i=1,nel
          eint(i) = eint(i) - half*dvol(i)*(pnew(i)+psh(i))
        ENDDO
      ENDIF
C
      RETURN
      END