mmodul24c.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    mmodul24c   ../engine/source/elements/solid/solidez/mmodul24c.F
!||--- called by ------------------------------------------------------
!||    mdama24     ../engine/source/elements/solid/solidez/mdama24.F
!||====================================================================
      SUBROUTINE mmodul24c(NEL    ,PM     ,DAM    ,CRAK   ,
     .                     CDAM   ,G3     ,ANG    ,DAMANG ,NBDAMA)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL,NBDAMA
      my_real pm(npropm)
      my_real, DIMENSION(NEL,3)   ,INTENT(IN):: dam,crak
      my_real, DIMENSION(NEL,6)   ,INTENT(IN):: ang
      my_real, DIMENSION(MVSIZ,3,3) ,INTENT(OUT):: cdam
      my_real, DIMENSION(MVSIZ,3) ,INTENT(OUT):: g3
      my_real, DIMENSION(MVSIZ,6) ,INTENT(OUT):: damang
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,K,NBDAMA0
      INTEGER, DIMENSION(NEL) ::  DAMAI,DAMA0I
      my_real  young,nu,g,a11,a12,de1,de2,de3,de4,de5,de6,den,
     .         scal1,scal2,scal3,d_max
C=======================================================================
c     DEi = (1 - DAMi)       coefficients d endommagement de la matrice Hook
c-----------------------------------------------------------------------
      young = pm(20)
      nu    = pm(21)
      g     = pm(22)
      a11   = pm(24)
      a12   = pm(25)
c
c     test of damaged elements
c
      nbdama  = 0
      nbdama0 = 0
      d_max=zero
      DO i = 1,nel
         IF (dam(i,1) + dam(i,2) + dam(i,3) > zero) THEN
           nbdama = nbdama + 1
           damai(nbdama)=i
           d_max =max(d_max,dam(i,1),dam(i,2),dam(i,3))
         ELSE
           nbdama0 = nbdama0 + 1 
           dama0i(nbdama0)=i
         ENDIF
      ENDDO
c-----------------------------------------------------------
c     DAMAGED ELEMENT GROUP => modified Hook matrix
c-----------------------------------------------------------
      DO k=1,nbdama
        i = damai(k)
c
        de1  = one - max( zero , sign(dam(i,1),crak(i,1)) )
        de2  = one - max( zero , sign(dam(i,2),crak(i,2)) )
        de3  = one - max( zero , sign(dam(i,3),crak(i,3)) )
        scal1= half + sign(half,de1-one)
        scal2= half + sign(half,de2-one)
        scal3= half + sign(half,de3-one)    
        de4  = scal1*scal2
        de5  = scal2*scal3
        de6  = scal3*scal1
c
c       NOUVELLE MATRICE ELASTIQUE DE HOOKE ENDOMMAGEE
c
        den = one - nu**2 *(de4 + de5 + de6
     .      + two*nu*scal1*scal2*scal3)
C
        cdam(i,1,1) = young*de1*(one - nu**2*de5)/den
        cdam(i,2,2) = young*de2*(one - nu**2*de6)/den
        cdam(i,3,3) = young*de3*(one - nu**2*de4)/den
        cdam(i,1,2) = nu*young*de4 *(one + nu*scal3)/den
        cdam(i,1,3) = nu*young*de6 *(one + nu*scal2)/den
        cdam(i,2,3) = nu*young*de5 *(one + nu*scal1)/den
        cdam(i,2,1) = cdam(i,1,2)
        cdam(i,3,1) = cdam(i,1,3)
        cdam(i,3,2) = cdam(i,2,3)
c
        g3(i,1) = g*de4
        g3(i,2) = g*de5
        g3(i,3) = g*de6
        damang(i,1:6) = ang(i,1:6)
      ENDDO
c------------------------------------------------------------------------
c     NON DAMAGED ELEMENT GROUP => initial Hook matrix
c------------------------------------------------------------------------
      DO k=1,nbdama0
        i = dama0i(k)
        cdam(i,1,1) = a11
        cdam(i,2,2) = a11
        cdam(i,3,3) = a11
        cdam(i,1,2) = a12
        cdam(i,2,1) = a12
        cdam(i,1,3) = a12
        cdam(i,3,1) = a12
        cdam(i,2,3) = a12
        cdam(i,3,2) = a12
        g3(i,1:3) = g
        damang(i,1) = one
        damang(i,2) = zero
        damang(i,3) = zero
        damang(i,4) = zero
        damang(i,5) = one
        damang(i,6) = zero
      ENDDO
c-----------
      RETURN
      END