multi_buf2var.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    multi_buf2var   ../engine/source/multifluid/multi_buf2var.F
!||--- called by ------------------------------------------------------
!||    alemain         ../engine/source/ale/alemain.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod    ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    multi_fvm_mod   ../common_source/modules/ale/multi_fvm_mod.F90
!||====================================================================
      SUBROUTINE multi_buf2var(ITASK, IPARG, MULTI_FVM, ELBUF_TAB)
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
      USE multi_fvm_mod
C-----------------------------------------------
C     I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C     C o m m o n   B l o c k s
C-----------------------------------------------
C     NPARG
#include      "param_c.inc"
C     NGROUP
#include      "com01_c.inc"
C     NTHREAD
#include      "task_c.inc"
C     MVSIZ
#include      "mvsiz_p.inc"
C-----------------------------------------------
C     D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: ITASK, IPARG(NPARG, *)
      TYPE(MULTI_FVM_STRUCT), INTENT(INOUT) :: MULTI_FVM
      TYPE(elbuf_struct_), TARGET, DIMENSION(NGROUP), INTENT(INOUT) :: ELBUF_TAB
C-----------------------------------------------
C     L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NBMAT, IMAT, II, I, NG, MATLAW, NEL, NFT
      my_real :: vol
      TYPE(g_bufel_), POINTER :: GBUF
      TYPE(l_bufel_), POINTER :: LBUF
 
      nbmat = multi_fvm%NBMAT
      DO ng = itask + 1, ngroup, nthread
         matlaw = iparg(1, ng)
         IF (matlaw == 151) THEN
            nel = iparg(2, ng)
            nft = iparg(3, ng)
            gbuf => elbuf_tab(ng)%GBUF
            DO ii = 1, nel
               i = ii + nft
C     Mass density
               multi_fvm%RHO(i) = gbuf%RHO(ii)
C     Volumic internal energy
               multi_fvm%EINT(i) = gbuf%EINT(ii)
C     Velocity
               multi_fvm%VEL(1, i) = gbuf%MOM(ii + 0 * nel)
               multi_fvm%VEL(2, i) = gbuf%MOM(ii + 1 * nel)
               multi_fvm%VEL(3, i) = gbuf%MOM(ii + 2 * nel)
               multi_fvm%PRES(i) = - third * (gbuf%SIG(ii + 0 * nel) + 
     .              gbuf%SIG(ii + 1 * nel) + 
     .              gbuf%SIG(ii + 2 * nel))
            ENDDO
            IF (nbmat > 1) THEN
               DO imat = 1, nbmat
                  lbuf => elbuf_tab(ng)%BUFLY(imat)%LBUF(1, 1, 1)
                  DO ii = 1, nel
                     i = ii + nft 
                     vol = gbuf%VOL(ii)
C     Volume fraction
                     multi_fvm%PHASE_ALPHA(imat, i) = lbuf%VOL(ii) / vol
C     Mass density
                     multi_fvm%PHASE_RHO(imat, i) = lbuf%RHO(ii)
C     internal energy
                     multi_fvm%PHASE_EINT(imat, i) = lbuf%EINT(ii)
C     PRessure
                     multi_fvm%PHASE_PRES(imat, i) = - third * (
     .                    lbuf%SIG(ii + 0 * nel) +
     .                    lbuf%SIG(ii + 1 * nel) + 
     ;                    lbuf%SIG(ii + 2 * nel))
                  ENDDO
               ENDDO
            ENDIF
         ENDIF
      ENDDO
      END SUBROUTINE multi_buf2var