multi_fluxout_ebcs.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    multi_fluxout_ebcs   ../engine/source/multifluid/multi_fluxout_ebcs.F
!||--- uses       -----------------------------------------------------
!||    multi_fvm_mod        ../common_source/modules/ale/multi_fvm_mod.F90
!||====================================================================
      SUBROUTINE multi_fluxout_ebcs(MULTI_FVM, NELEM, ELEM_LIST, FACE_LIST, 
     .     IXS, IXQ, IXTG, XGRID, WGRID)
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------
      USE multi_fvm_mod
C-----------------------------------------------
C     I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C     C o m m o n   B l o c k s
C-----------------------------------------------  
! NIXS
! ISPMD
! ALE
! NUMELS, NUMELQ, NUMELTG
C-----------------------------------------------
C     D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(multi_fvm_struct), INTENT(INOUT) :: MULTI_FVM
      INTEGER, INTENT(IN) :: NELEM, ELEM_LIST(NELEM), FACE_LIST(NELEM)
      INTEGER, INTENT(IN) :: IXS(NIXS, *), IXQ(NIXQ, *), IXTG(NIXTG, *)
      my_real, INTENT(IN) :: xgrid(3, *), wgrid(3, *)
C-----------------------------------------------
C     L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: IELEM, ELEMID, NODE_ID
      INTEGER :: KFACE, NB_NOD_FOUND, KNOD, KK, JJ
      my_real :: x1(3), x2(3), x3(3), x4(3), p, normvel, vx, vy, vz, ssp, surf, nx, ny, nz
      my_real :: rho, sstar, pstar, pfac, sl, sr, wfac(3), vii(5), vjj(5), vel2, normalw
      my_real :: fii(5), fjj(5), viistar(5), vjjstar(5), fiistar(5), fjjstar(5), pp(5)
      INTEGER :: NODE1, NODE2, IMAT
C-----------------------------------------------
C     B e g i n n i n g   o f   s u b r o u t i n e
C-----------------------------------------------
      DO ielem = 1, nelem
         elemid = elem_list(ielem)
 
C     Face of the element
         kface = face_list(ielem)
         
         nx = multi_fvm%FACE_DATA%NORMAL(1, kface, elemid)
         ny = multi_fvm%FACE_DATA%NORMAL(2, kface, elemid)
         nz = multi_fvm%FACE_DATA%NORMAL(3, kface, elemid)
         surf = multi_fvm%FACE_DATA%SURF(kface, elemid)
         wfac(1:3) = multi_fvm%FACE_DATA%WFAC(1:3, kface, elemid) 
         vx = multi_fvm%VEL(1, elemid)
         vy = multi_fvm%VEL(2, elemid)
         vz = multi_fvm%VEL(3, elemid)
         normvel = vx * nx + vy * ny + vz * nz
         normalw = wfac(1) * nx + wfac(2) * ny + wfac(3) * nz
         ssp = multi_fvm%SOUND_SPEED(elemid)
         p = multi_fvm%PRES(elemid)
         rho = multi_fvm%RHO(elemid)
 
         vel2 = vx * vx + vy * vy + vz * vz 
 
         vii(1) = rho
         vii(2) = rho * vx
         vii(3) = rho * vy
         vii(4) = rho * vz
         vii(5) = multi_fvm%EINT(elemid) + half * rho * vel2
 
         fii(1) = vii(1) * normvel
         fii(2) = vii(2) * normvel + p * nx
         fii(3) = vii(3) * normvel + p * ny
         fii(4) = vii(4) * normvel + p * nz
         fii(5) = (vii(5) + p) * normvel
        
         multi_fvm%FLUXES(1:5, kface, elemid) = (fii(1:5) - normalw * vii(1:5)) * surf
         multi_fvm%FLUXES(6, kface, elemid) = surf * normvel
 
         IF (multi_fvm%NBMAT > 1) THEN
            multi_fvm%FLUXES(1, kface, elemid) = zero
            DO imat = 1, multi_fvm%NBMAT
               vii(1) = multi_fvm%PHASE_ALPHA(imat, elemid)
               vii(2) = multi_fvm%PHASE_ALPHA(imat, elemid) * 
     .              multi_fvm%PHASE_RHO(imat, elemid)
               vii(3) = multi_fvm%PHASE_ALPHA(imat, elemid) * 
     .              multi_fvm%PHASE_EINT(imat, elemid)
               fii(1:3) = vii(1:3) * normvel
               multi_fvm%SUBVOL_FLUXES(imat, kface, elemid) = 
     .              (fii(1) - normalw * vii(1)) * surf
               multi_fvm%SUBMASS_FLUXES(imat, kface, elemid) = 
     .              (fii(2) - normalw * vii(2)) * surf
               multi_fvm%SUBENER_FLUXES(imat, kface, elemid) = 
     .              (fii(3) - normalw * vii(3)) * surf
               multi_fvm%FLUXES(1, kface, elemid) = multi_fvm%FLUXES(1, kface, elemid) +
     .              (fii(2) - normalw * vii(2)) * surf
            ENDDO
         ENDIF
      ENDDO
C-----------------------------------------------
C     E n d   o f   s u b r o u t i n e 
C-----------------------------------------------
      END SUBROUTINE multi_fluxout_ebcs