multi_var2buf.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    multi_var2buf   ../engine/source/multifluid/multi_var2buf.F
!||--- called by ------------------------------------------------------
!||    alemain         ../engine/source/ale/alemain.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod    ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    multi_fvm_mod   ../common_source/modules/ale/multi_fvm_mod.F90
!||====================================================================
      SUBROUTINE multi_var2buf(ITASK, IPARG, MULTI_FVM, ELBUF_TAB)
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
      USE multi_fvm_mod
C-----------------------------------------------
C     I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C     C o m m o n   B l o c k s
C-----------------------------------------------
C     NPARG
#include      "param_c.inc"
C     NGROUP
#include      "com01_c.inc"
C     NTHREAD
#include      "task_c.inc"
C     MVSIZ
#include      "mvsiz_p.inc"
C-----------------------------------------------
C     D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: ITASK, IPARG(NPARG, *)
      TYPE(multi_fvm_struct), INTENT(INOUT) :: MULTI_FVM
      TYPE(ELBUF_STRUCT_), TARGET, DIMENSION(NGROUP), INTENT(INOUT) :: ELBUF_TAB
C-----------------------------------------------
C     L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NBMAT, IMAT, II, I, NG, MATLAW, NEL, NFT
      my_real :: vol, cumul_alpha(mvsiz)
      TYPE(g_bufel_), POINTER :: GBUF
      TYPE(l_bufel_), POINTER :: LBUF
 
      nbmat = multi_fvm%NBMAT
      DO ng = itask + 1, ngroup, nthread
         matlaw = iparg(1, ng)
         IF (matlaw == 151) THEN
            nel = iparg(2, ng)
            nft = iparg(3, ng)
            gbuf => elbuf_tab(ng)%GBUF
            DO ii = 1, nel
               i = ii + nft
C     Mass density
               gbuf%RHO(ii) = multi_fvm%RHO(i)
C     Volumic internal energy
               gbuf%EINT(ii) = multi_fvm%EINT(i)
C     Velocity
               gbuf%MOM(ii + 0 * nel) = multi_fvm%VEL(1, i)
               gbuf%MOM(ii + 1 * nel) = multi_fvm%VEL(2, i)
               gbuf%MOM(ii + 2 * nel) = multi_fvm%VEL(3, i)
               gbuf%SIG(ii + 0 * nel) = -multi_fvm%PRES(i)
               gbuf%SIG(ii + 1 * nel) = -multi_fvm%PRES(i)
               gbuf%SIG(ii + 2 * nel) = -multi_fvm%PRES(i)
            ENDDO
            IF (nbmat > 1) THEN
               cumul_alpha(1:nel) = zero
C     Fill partial values
               DO imat = 1, nbmat
                  DO ii = 1, nel
                     i = ii + nft
                     cumul_alpha(ii) = cumul_alpha(ii) + multi_fvm%PHASE_ALPHA(imat, i)
                  ENDDO
               ENDDO
               DO imat = 1, nbmat
                  lbuf => elbuf_tab(ng)%BUFLY(imat)%LBUF(1, 1, 1)
                  DO ii = 1, nel
                     i = ii + nft 
                     vol = gbuf%VOL(ii)
C     Normalize volumic fraction
                     multi_fvm%PHASE_ALPHA(imat, i) = multi_fvm%PHASE_ALPHA(imat, i) / 
     .                    cumul_alpha(ii)
C     Volume
                     lbuf%VOL(ii) = multi_fvm%PHASE_ALPHA(imat, i) * vol
C     Mass density
                     lbuf%RHO(ii) = multi_fvm%PHASE_RHO(imat, i)
C     Volumic internal energy
                     lbuf%EINT(ii) = multi_fvm%PHASE_EINT(imat, i)
C     PRessure
                     lbuf%SIG(ii + 0 * nel) = -multi_fvm%PHASE_PRES(imat, i)
                     lbuf%SIG(ii + 1 * nel) = -multi_fvm%PHASE_PRES(imat, i)
                     lbuf%SIG(ii + 2 * nel) = -multi_fvm%PHASE_PRES(imat, i)
                  ENDDO
               ENDDO
CCCCC 
               IF (multi_fvm%MUSCL > 0) THEN
                  DO ii = 1, nel
                     i = ii + nft
                     multi_fvm%RHO(i) = zero
                  ENDDO
                  DO imat = 1, nbmat
                     DO ii = 1, nel
                        i = ii + nft
                        multi_fvm%RHO(i) = multi_fvm%RHO(i) + 
     .                       multi_fvm%PHASE_ALPHA(imat, i) * multi_fvm%PHASE_RHO(imat, i)
                     ENDDO
                  ENDDO
               ENDIF
            ENDIF
         ENDIF !IF (MATLAW == 151) THEN
      ENDDO  ! NG
      END SUBROUTINE multi_var2buf