nlocal_init_sta.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    nlocal_init_sta   ../starter/source/materials/fail/nlocal_init_sta.F
!||--- calls      -----------------------------------------------------
!||    ancmsg            ../starter/source/output/message/message.F
!||    c3fint_reg_ini    ../starter/source/elements/sh3n/coque3n/c3fint_reg_ini.F
!||    cbafint_reg_ini   ../starter/source/elements/shell/coqueba/cbafint_reg_ini.F
!||    cdkfint_reg_ini   ../starter/source/elements/sh3n/coquedk/cdkfint_reg_ini.F
!||    cfint_reg_ini     ../starter/source/elements/shell/coque/cfint_reg_ini.F
!||--- uses       -----------------------------------------------------
!||    message_mod       ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE nlocal_init_sta(ELBUF_TAB,NLOC_DMG ,IPARG    ,IXC      ,
     .                           IXS      ,IXTG     ,AREA     ,X        ,
     .                           XREFS    ,XREFC    ,XREFTG   ,IPM      ,
     .                           BUFMAT   )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod            
      USE message_mod
      USE nlocal_reg_mod
      USE message_mod
      use element_mod , only : nixs,nixc,nixtg
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(elbuf_struct_), TARGET, DIMENSION(NGROUP) :: ELBUF_TAB
      TYPE (NLOCAL_STR_) , TARGET                    :: NLOC_DMG 
      INTEGER IPARG(NPARG,NGROUP),IXS(NIXS,*),IXC(NIXC,*),IXTG(NIXTG,*),
     .        ipm(npropmi,*)
      my_real ,DIMENSION(NUMELC+NUMELTG),INTENT(IN)        :: 
     .   area 
      my_real
     .   x(3,*),xrefc(4,3,*),xreftg(3,3,*),xrefs(8,3,*),bufmat(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      LOGICAL :: CONVERGED,FAILURE
      INTEGER :: L_NLOC,NG,ILOC,NEL,NFT,ITY,FORMU
      my_real
     .   dt_nl,time,norm_1,norm,d
      my_real,
     .  PARAMETER :: tol1 = 5.0d-4
      my_real,
     .  PARAMETER :: tol2 = 1.0d-8
      my_real, 
     .  DIMENSION(:), POINTER :: fnl,unl,vnl,dnl,mnl
 
        ! Initialization of the convergence flag
        converged = .false.
        ! Initialization of the failure flag
        failure   = .false.
        ! Size of the non-local vectors
        l_nloc = nloc_dmg%L_NLOC
        ! Pointing the non-local forces vector
        fnl => nloc_dmg%FNL(1:l_nloc,1)
        vnl => nloc_dmg%VNL(1:l_nloc)
        dnl => nloc_dmg%DNL(1:l_nloc)
        unl => nloc_dmg%UNL(1:l_nloc)
        mnl => nloc_dmg%MASS(1:l_nloc)
        ! Initialization of the non-local time step
        dt_nl = hundred
        fnl   = zero
        vnl   = zero
        dnl   = zero
        unl   = zero
        time  = zero
        ! Loop of the initialization
        DO WHILE (.NOT.converged)
          ! Loop over the element groups
          DO ng = 1,ngroup
            ! Non-local flag
            iloc = iparg(78,ng)
            ! If the group is non-local
            IF (iloc>0) THEN
              ! Number of elements in the group
              nel   = iparg(2,ng)
              ! NFT value
              nft   = iparg(3,ng) 
              ! Type of elements
              ity   = iparg(5,ng)
              ! Formulation of the element
              formu = iparg(23,ng)
              ! If the elements are shells
              IF (ity == 3) THEN 
                IF ((formu>10).AND.(formu<29)) THEN
                  CALL cbafint_reg_ini(elbuf_tab,nloc_dmg ,area     ,ixc     ,
     .                                 dt_nl    ,x        ,xrefc    ,nft     ,
     .                                 nel      ,ng       ,ipm      ,bufmat  ,
     .                                 time     ,failure  )
                ELSE
                  CALL cfint_reg_ini(elbuf_tab,nloc_dmg ,area     ,ixc     ,
     .                               dt_nl    ,x        ,xrefc    ,nft     ,
     .                               nel      ,ng       ,ipm      ,bufmat  ,
     .                               time     ,failure  )
                ENDIF
              ELSEIF (ity == 7) THEN 
                IF ((formu==1).OR.(formu==2)) THEN
                  CALL c3fint_reg_ini(elbuf_tab,nloc_dmg ,area     ,ixtg     ,
     .                                dt_nl    ,x        ,xreftg   ,nft      ,
     .                                nel      ,ng       ,ipm      ,bufmat   ,
     .                                time     ,failure  )
                ELSEIF ((formu==30).OR.(formu==31)) THEN
                  CALL cdkfint_reg_ini(elbuf_tab,nloc_dmg ,area     ,ixtg     ,
     .                                 dt_nl    ,x        ,xreftg   ,nft      ,
     .                                 nel      ,ng       ,ipm      ,bufmat   ,
     .                                 time     ,failure  )
                ENDIF
              ENDIF
            ENDIF
          ENDDO
          ! Computation of the accelerations
          fnl = fnl / mnl
          ! Computation of the velocities
          vnl = vnl + dt_nl*fnl
          ! Resetting the forces
          fnl = zero
          ! Norm of the previous increment
          norm_1 = sqrt(dot_product(dnl,dnl))
          ! Computation of the increments
          dnl = dt_nl*vnl
          ! Norm of the current increment
          norm = sqrt(dot_product(dnl,dnl))
          ! Computation of the cumulated variable
          unl = unl + dnl
          ! Convergence criterion
          converged = ((norm<tol1).AND.(abs(norm-norm_1)<tol2).AND.(time/=zero))
          d = (sqrt(dot_product(dnl,dnl)))
          IF (d .NE. d) THEN 
            CALL ancmsg(msgid=1765,msgtype=msgerror,
     .                  anmode=aninfo_blind_1) 
            EXIT
          ENDIF
          ! Updating time 
          time = time + dt_nl
        ENDDO
        ! Resetting the non-local vectors
        fnl = zero
        vnl = zero
        dnl = zero
        ! Checking failure
        IF (failure) THEN 
          CALL ancmsg(msgid=1767,msgtype=msgwarning,
     .                anmode=aninfo_blind_1)         
        ENDIF
c-----------
      END