nsvisul.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    nsvisul         ../engine/source/materials/mat_share/nsvisul.F
!||--- called by ------------------------------------------------------
!||    mulaw           ../engine/source/materials/mat_share/mulaw.F90
!||    usermat_solid   ../engine/source/materials/mat_share/usermat_solid.F
!||====================================================================
      SUBROUTINE nsvisul(NEL ,OFF ,RHO  ,GEO ,
     2                   PID ,SSP ,AIRE ,VOL ,D1  ,
     3                   D2  ,D3  ,D4   ,D5  ,D6  ,
     4                   SV1 ,SV2 ,SV3  ,SV4 ,SV5 ,
     5                   SV6 ,S3  ,E3   ,RHO0,RHOREF)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL
      INTEGER PID(*)
      my_real
     .   OFF(*), RHO(*),GEO(NPROPG,*), SSP(*),
     .   aire(*), vol(*), d1(*), d2(*), d3(*),
     .   d4(*), d5(*), d6(*),sv1(*), sv2(*), sv3(*),
     .   sv4(*), sv5(*), sv6(*),s3(*),e3(*),rho0(*),rhoref(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .   DD(MVSIZ), AL(MVSIZ), NRHO(MVSIZ), CNS1, CNS2, CNS3, DAV, PVIS
c=======================================================================     
      dd(1:nel)=-d1(1:nel)-d2(1:nel)-d3(1:nel)
C      
      IF(n2d > 0) THEN
        DO i=1,nel
          al(i)=zero
          IF(off(i) >= one)al(i)=sqrt(aire(i))
        ENDDO
      ELSE 
        DO  i=1,nel
         al(i)=zero
         IF(off(i) >= one) al(i)=exp(third*log(vol(i)))
        ENDDO
      ENDIF
C-----------------------------------------------
C     Large strain :: Critical damping D = L * rho * c, c = sqrt(A11/rho)
C       BUT c is computed as sqrt(A11/rho0) for most of the materials
C       <=> D = L * sqrt(rho) * sqrt(rho0) * sqrt(A11/rho0)
C     Note : if for a given material, c is computed as sqrt(A11/rho), 
C     ----     then damping will result in L * sqrt(rho) * sqrt(rho0) * c
C              and will be in the ratio sqrt(rho0) / sqrt(rho) wrt critical damping
C                                       < 1 in compression
C                                       > 1 in tension 
C                                       this ratio will be more likely limited.
C
C     Small strain :: Critical damping D = L * rhoref * c, c = sqrt(A11/rhoref)
C       BUT c is computed as sqrt(A11/rho0) for most of the materials
C       <=> D = L * sqrt(rhoref) * sqrt(rho0) * sqrt(A11/rho0)
C
C-----------------------------------------------
      DO i=1,nel
        nrho(i) = sqrt(rhoref(i)*rho0(i))
      ENDDO
C
      IF(geo(16,pid(1)) >= zero)THEN
        DO i=1,nel
          cns1=geo(16,pid(1))*al(i)*nrho(i)*ssp(i)*off(i)
          cns2=geo(17,pid(1))*al(i)*nrho(i)*ssp(i)*off(i)
          cns3=half*cns2
          dav=dd(i) * third
          pvis=-cns1*dd(i)
          sv1(i)= sv1(i) + cns2 *(d1(i)+dav)+pvis
          sv2(i)= sv2(i) + cns2 *(d2(i)+dav)+pvis
          sv3(i)= sv3(i) + cns2 *(d3(i)+dav)+pvis
          sv4(i)= sv4(i) + cns3 * d4(i)
          sv5(i)= sv5(i) + cns3 * d5(i)
          sv6(i)= sv6(i) + cns3 * d6(i)
C          IF(GEO(16,PID(I)) /= ZERO .OR. GEO(17,PID(I))/=ZERO) ISVIS = 1
        ENDDO 
      ELSE
        DO i=1,nel
          cns1=geo(16,pid(1))*nrho(i)*ssp(i)**2*off(i)
          cns2=geo(17,pid(1))*nrho(i)*ssp(i)**2*off(i)
          cns3=half*cns2
          dav=dd(i) * third
          pvis=-cns1*dd(i)
          sv1(i)= sv1(i) + cns2 *(d1(i)+dav)+pvis
          sv2(i)= sv2(i) + cns2 *(d2(i)+dav)+pvis
          sv3(i)= sv3(i) + cns2 *(d3(i)+dav)+pvis
          sv4(i)= sv4(i) + cns3 * d4(i)
          sv5(i)= sv5(i) + cns3 * d5(i)
          sv6(i)= sv6(i) + cns3 * d6(i)
C          IF(GEO(16,PID(I)) /= ZERO .OR. GEO(17,PID(I))/=ZERO) ISVIS = 1
        ENDDO 
      END IF
C
      RETURN
      END