pchetd2.f

Go to the documentation of this file.

      SUBROUTINE pchetd2( UPLO, N, A, IA, JA, DESCA, D, E, TAU, WORK,
     $                    LWORK, INFO )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, LWORK, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               D( * ), E( * )
      COMPLEX            A( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCHETD2 reduces a complex Hermitian matrix sub( A ) to Hermitian
*  tridiagonal form T by an unitary similarity transformation:
*  Q' * sub( A ) * Q = T, where sub( A ) = A(IA:IA+N-1,JA:JA+N-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          Hermitian matrix sub( A ) is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          Hermitian distributed matrix sub( A ).  If UPLO = 'U', the
*          leading N-by-N upper triangular part of sub( A ) contains
*          the upper triangular part of the matrix, and its strictly
*          lower triangular part is not referenced. If UPLO = 'L', the
*          leading N-by-N lower triangular part of sub( A ) contains the
*          lower triangular part of the matrix, and its strictly upper
*          triangular part is not referenced. On exit, if UPLO = 'U',
*          the diagonal and first superdiagonal of sub( A ) are over-
*          written by the corresponding elements of the tridiagonal
*          matrix T, and the elements above the first superdiagonal,
*          with the array TAU, represent the unitary matrix Q as a
*          product of elementary reflectors; if UPLO = 'L', the diagonal
*          and first subdiagonal of sub( A ) are overwritten by the
*          corresponding elements of the tridiagonal matrix T, and the
*          elements below the first subdiagonal, with the array TAU,
*          represent the unitary matrix Q as a product of elementary
*          reflectors. See Further Details.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local output) REAL array, dimension LOCc(JA+N-1)
*          The diagonal elements of the tridiagonal matrix T:
*          D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local output) REAL array, dimension LOCc(JA+N-1)
*          if UPLO = 'U', LOCc(JA+N-2) otherwise. The off-diagonal
*          elements of the tridiagonal matrix T: E(i) = A(i,i+1) if
*          UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. E is tied to the
*          distributed matrix A.
*
*  TAU     (local output) COMPLEX, array, dimension
*          LOCc(JA+N-1). This array contains the scalar factors TAU of
*          the elementary reflectors. TAU is tied to the distributed
*          matrix A.
*
*  WORK    (local workspace/local output) COMPLEX array,
*                                                    dimension (LWORK)
*          On exit, WORK( 1 ) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          LWORK >= 3*N.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Further Details
*  ===============
*
*  If UPLO = 'U', the matrix Q is represented as a product of elementary
*  reflectors
*
*     Q = H(n-1) . . . H(2) H(1).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a complex scalar, and v is a complex vector with
*  v(i+1:n) = 0 and v(i) = 1; v(1:i-1) is stored on exit in
*  A(ia:ia+i-2,ja+i), and tau in TAU(ja+i-1).
*
*  If UPLO = 'L', the matrix Q is represented as a product of elementary
*  reflectors
*
*     Q = H(1) H(2) . . . H(n-1).
*
*  Each H(i) has the form
*
*     H(i) = I - tau * v * v'
*
*  where tau is a complex scalar, and v is a complex vector with
*  v(1:i) = 0 and v(i+1) = 1; v(i+2:n) is stored on exit in
*  A(ia+i+1:ia+n-1,ja+i-1), and tau in TAU(ja+i-1).
*
*  The contents of sub( A ) on exit are illustrated by the following
*  examples with n = 5:
*
*  if UPLO = 'U':                       if UPLO = 'L':
*
*    (  d   e   v2  v3  v4 )              (  d                  )
*    (      d   e   v3  v4 )              (  e   d              )
*    (          d   e   v4 )              (  v1  e   d          )
*    (              d   e  )              (  v1  v2  e   d      )
*    (                  d  )              (  v1  v2  v3  e   d  )
*
*  where d and e denote diagonal and off-diagonal elements of T, and vi
*  denotes an element of the vector defining H(i).
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrix sub( A ) must verify some alignment proper-
*  ties, namely the following expression should be true:
*  ( MB_A.EQ.NB_A .AND. IROFFA.EQ.ICOFFA ) with
*  IROFFA = MOD( IA-1, MB_A ) and ICOFFA = MOD( JA-1, NB_A ).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            HALF, ONE, ZERO
      parameter( half = ( 0.5e+0, 0.0e+0 ),
     $                   one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER
      INTEGER            IACOL, IAROW, ICOFFA, ICTXT, II, IK, IROFFA, J,
     $                   jj, jk, jn, lda, lwmin, mycol, myrow, npcol,
     $                   nprow
      COMPLEX            ALPHA, TAUI
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, caxpy, cgebr2d,
     $                   cgebs2d, chk1mat, chemv,
     $                   cher2, clarfg, infog2l, pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX            CDOTC
      EXTERNAL           lsame, cdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(600+ctxt_)
      ELSE
         upper = lsame( uplo, 'U' )
         CALL chk1mat( n, 2, n, 2, ia, ja, desca, 6, info )
         lwmin = 3 * n
*
         work( 1 ) = cmplx( real( lwmin ) )
         lquery = ( lwork.EQ.-1 )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -1
            ELSE IF( iroffa.NE.icoffa ) THEN
               info = -5
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -(600+nb_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -11
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PCHETD2', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Compute local information
*
      lda = desca( lld_ )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              iarow, iacol )
*
      IF( upper ) THEN
*
*        Process(IAROW, IACOL) owns block to be reduced
*
         IF( mycol.EQ.iacol ) THEN
            IF( myrow.EQ.iarow ) THEN
*
*              Reduce the upper triangle of sub( A )
*
               ik = ii+n-1+(jj+n-2)*lda
               a( ik ) = real( a( ik ) )
               DO 10 j = n-1, 1, -1
                  ik = ii + j - 1
                  jk = jj + j - 1
*
*                 Generate elementary reflector H(i) = I - tau * v * v'
*                 to annihilate A(IA:IA+J-1,JA:JA+J-1)
*
                  alpha = a( ik+jk*lda )
                  CALL clarfg( j, alpha, a( ii+jk*lda ), 1, taui )
                  e( jk+1 ) = real( alpha )
*
                  IF( taui.NE.zero ) THEN
*
*                    Apply H(i) from both sides to
*                    A(IA:IA+J-1,JA:JA+J-1)
*
                     a( ik+jk*lda ) = one
*
*                    Compute  x := tau * A * v  storing x in TAU(1:i)
*
                     CALL chemv( uplo, j, taui, a( ii+(jj-1)*lda ),
     $                           lda, a( ii+jk*lda ), 1, zero,
     $                           tau( jj ), 1 )
*
*                    Compute  w := x - 1/2 * tau * (x'*v) * v
*
                     alpha = -half*taui*cdotc( j, tau( jj ), 1,
     $                                         a( ii+jk*lda ), 1 )
                     CALL caxpy( j, alpha, a( ii+jk*lda ), 1,
     $                           tau( jj ), 1 )
*
*                    Apply the transformation as a rank-2 update:
*                       A := A - v * w' - w * v'
*
                     CALL cher2( uplo, j, -one, a( ii+jk*lda ), 1,
     $                           tau( jj ), 1, a( ii+(jj-1)*lda ),
     $                           lda )
                  END IF
*
*                 Copy D, E, TAU to broadcast them columnwise.
*
                  a( ik+jk*lda ) = cmplx( e( jk+1 ) )
                  d( jk+1 ) = real( a( ik+1+jk*lda ) )
                  work( j+1 ) = cmplx( d( jk+1 ) )
                  work( n+j+1 ) = cmplx( e( jk+1 ) )
                  tau( jk+1 ) = taui
                  work( 2*n+j+1 ) = tau( jk+1 )
*
   10          CONTINUE
               d( jj ) = real( a( ii+(jj-1)*lda ) )
               work( 1 ) = cmplx( d( jj ) )
               work( n+1 ) = zero
               work( 2*n+1 ) = zero
*
               CALL cgebs2d( ictxt, 'columnwise', ' ', 1, 3*N, WORK, 1 )
*
            ELSE
               CALL CGEBR2D( ICTXT, 'columnwise', ' ', 1, 3*N, WORK, 1,
     $                       IAROW, IACOL )
               DO 20 J = 2, N
                  JN = JJ + J - 1
                  D( JN ) = REAL( WORK( J ) )
                  E( JN ) = REAL( WORK( N+J ) )
                  TAU( JN ) = WORK( 2*N+J )
   20          CONTINUE
               D( JJ ) = REAL( WORK( 1 ) )
            END IF
         END IF
*
      ELSE
*
*        Process (IAROW, IACOL) owns block to be factorized
*
.EQ.         IF( MYCOLIACOL ) THEN
.EQ.            IF( MYROWIAROW ) THEN
*
*              Reduce the lower triangle of sub( A )
*
               A( II+(JJ-1)*LDA ) = REAL( A( II+(JJ-1)*LDA ) )
               DO 30 J = 1, N - 1
                  IK = II + J - 1
                  JK = JJ + J - 1
*
*                 Generate elementary reflector H(i) = I - tau * v * v'
*                 to annihilate A(IA+J-JA+2:IA+N-1,JA+J-1)
*
                  ALPHA = A( IK+1+(JK-1)*LDA )
                  CALL CLARFG( N-J, ALPHA, A( IK+2+(JK-1)*LDA ), 1,
     $                         TAUI )
                  E( JK ) = REAL( ALPHA )
*
.NE.                  IF( TAUIZERO ) THEN
*
*                    Apply H(i) from both sides to
*                    A(IA+J-JA+1:IA+N-1,JA+J+1:JA+N-1)
*
                     A( IK+1+(JK-1)*LDA ) = ONE
*
*                    Compute  x := tau * A * v  storing y in TAU(i:n-1)
*
                     CALL CHEMV( UPLO, N-J, TAUI, A( IK+1+JK*LDA ),
     $                           LDA, A( IK+1+(JK-1)*LDA ), 1,
     $                           ZERO, TAU( JK ), 1 )
*
*                    Compute  w := x - 1/2 * tau * (x'*v) * v
*
                     ALPHA = -HALF*TAUI*CDOTC( N-J, TAU( JK ), 1,
     $                        A( IK+1+(JK-1)*LDA ), 1 )
                     CALL CAXPY( N-J, ALPHA, A( IK+1+(JK-1)*LDA ),
     $                           1, TAU( JK ), 1 )
*
*                    Apply the transformation as a rank-2 update:
*                       A := A - v * w' - w * v'
*
                     CALL CHER2( UPLO, N-J, -ONE,
     $                           A( IK+1+(JK-1)*LDA ), 1,
     $                           TAU( JK ), 1, A( IK+1+JK*LDA ),
     $                           LDA )
                  END IF
*
*                 Copy D(JK), E(JK), TAU(JK) to broadcast them
*                 columnwise.
*
                  A( IK+1+(JK-1)*LDA ) = CMPLX( E( JK ) )
                  D( JK ) = REAL( A( IK+(JK-1)*LDA ) )
                  WORK( J ) = CMPLX( D( JK ) )
                  WORK( N+J ) = CMPLX( E( JK ) )
                  TAU( JK ) = TAUI
                  WORK( 2*N+J ) = TAU( JK )
   30          CONTINUE
               JN = JJ + N - 1
               D( JN ) = REAL( A( II+N-1+(JN-1)*LDA ) )
               WORK( N ) = CMPLX( D( JN ) )
               TAU( JN ) = ZERO
               WORK( 2*N ) = ZERO
*
               CALL CGEBS2D( ICTXT, 'columnwise', ' ', 1, 3*N-1, WORK,
     $                            1 )
*
            ELSE
               CALL CGEBR2D( ICTXT, 'columnwise', ' ', 1, 3*N-1, WORK,
     $                       1, IAROW, IACOL )
               DO 40 J = 1, N - 1
                  JN = JJ + J - 1
                  D( JN ) = REAL( WORK( J ) )
                  E( JN ) = REAL( WORK( N+J ) )
                  TAU( JN ) = WORK( 2*N+J )
   40          CONTINUE
               JN = JJ + N - 1
               D( JN ) = REAL( WORK( N ) )
               TAU( JN ) = ZERO
            END IF
         END IF
      END IF
*
      WORK( 1 ) = CMPLX( REAL( LWMIN ) )
*
      RETURN
*
*     End of PCHETD2
*
      END