piparmq.f

Go to the documentation of this file.

      INTEGER FUNCTION piparmq( ICTXT, ISPEC, NAME, OPTS, N, ILO, IHI,
     $                          LWORKNB )
*
*     Contribution from the Department of Computing Science and HPC2N,
*     Umea University, Sweden
*
*  -- ScaLAPACK auxiliary routine (version 2.0.1) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     Univ. of Colorado Denver and University of California, Berkeley.
*     January, 2012
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      INTEGER            ictxt, ihi, ilo, ispec, lworknb, n
      CHARACTER          name*( * ), opts*( * )
*
*  Purpose
*  =======
*
*       This program sets problem and machine dependent parameters
*       useful for PxHSEQR and its subroutines. It is called whenever
*       PILAENVX is called with 12 <= ISPEC <= 16
*
*  Arguments
*  =========
*
*       ICTXT  (local input) INTEGER
*              On entry,  ICTXT  specifies the BLACS context handle,
*              indicating the global  context of the operation. The
*              context itself is global, but the value of ICTXT is
*              local.
*
*       ISPEC  (global input) INTEGER
*              ISPEC specifies which tunable parameter PIPARMQ should
*              return.
*
*              ISPEC=12: (INMIN)  Matrices of order nmin or less
*                        are sent directly to PxLAHQR, the implicit
*                        double shift QR algorithm.  NMIN must be
*                        at least 11.
*
*              ISPEC=13: (INWIN)  Size of the deflation window.
*                        This is best set greater than or equal to
*                        the number of simultaneous shifts NS.
*                        Larger matrices benefit from larger deflation
*                        windows.
*
*              ISPEC=14: (INIBL) Determines when to stop nibbling and
*                        invest in an (expensive) multi-shift QR sweep.
*                        If the aggressive early deflation subroutine
*                        finds LD converged eigenvalues from an order
*                        NW deflation window and LD.GT.(NW*NIBBLE)/100,
*                        then the next QR sweep is skipped and early
*                        deflation is applied immediately to the
*                        remaining active diagonal block.  Setting
*                        PIPARMQ(ISPEC=14) = 0 causes PxLAQR0 to skip a
*                        multi-shift QR sweep whenever early deflation
*                        finds a converged eigenvalue.  Setting
*                        PIPARMQ(ISPEC=14) greater than or equal to 100
*                        prevents PxLAQR0 from skipping a multi-shift
*                        QR sweep.
*
*              ISPEC=15: (NSHFTS) The number of simultaneous shifts in
*                        a multi-shift QR iteration.
*
*              ISPEC=16: (IACC22) PIPARMQ is set to 1 or 2 with the
*                        following meanings.
*                        1:  During the multi-shift QR sweep,
*                            PxLAQR5 and/or xLAQR6 accumulates reflections
*                            and uses matrix-matrix multiply to update
*                            the far-from-diagonal matrix entries.
*                        2:  During the multi-shift QR sweep.
*                            PxLAQR5 accumulates reflections and takes
*                            advantage of 2-by-2 block structure during
*                            matrix-matrix multiplies.
*
*                        ( IACC22=0 is valid in LAPACK but not here.
*                        Householder reflections are always accumulated
*                        for the performance consideration.
*                        If xTRMM is slower than xGEMM or NB is small,
*                        PIPARMQ(ISPEC=16)=1 may be more efficient than
*                        PIPARMQ(ISPEC=16)=2 despite the greater level of
*                        arithmetic work implied by the latter choice. )
*
*       NAME    (global input) character string
*               Name of the calling subroutine
*
*       OPTS    (global input) character string
*               This is a concatenation of the string arguments to
*               TTQRE.
*
*       N       (global input) integer scalar
*               N is the order of the Hessenberg matrix H.
*
*       ILO     (global input) INTEGER
*       IHI     (global input) INTEGER
*               It is assumed that H is already upper triangular
*               in rows and columns 1:ILO-1 and IHI+1:N.
*
*       LWORKNB   (global input) INTEGER
*               The amount of workspace available or the blockfactor.
*
*  Further Details
*  ===============
*
*       Little is known about how best to choose these parameters.
*       It is possible to use different values of the parameters
*       for each of PCHSEQR, PDHSEQR, PSHSEQR and PZHSEQR.
*
*       It is probably best to choose different parameters for
*       different matrices and different parameters at different
*       times during the iteration, but this has not been fully
*       implemented --- yet.
*
*
*       The best choices of most of the parameters depend
*       in an ill-understood way on the relative execution
*       rate of PxLAQR3 and PxLAQR5 and on the nature of each
*       particular eigenvalue problem.  Experiment may be the
*       only practical way to determine which choices are most
*       effective.
*
*       Following is a list of default values supplied by PIPARMQ.
*       These defaults may be adjusted in order to attain better
*       performance in any particular computational environment.
*
*       PIPARMQ(ISPEC=12) The PxLAQR1 vs PxLAQR0 crossover point.
*                         Default: 220. (Must be at least 11.)
*
*       PIPARMQ(ISPEC=13) Recommended deflation window size.
*                         This depends on ILO, IHI and NS, the
*                         number of simultaneous shifts returned
*                         by PIPARMQ(ISPEC=15).  The default for
*                         (IHI-ILO+1).LE.500 is NS.  The default
*                         for (IHI-ILO+1).GT.500 is 3*NS/2.
*
*       PIPARMQ(ISPEC=14) Nibble crossover point.
*                         The default for the serial case is 14.
*                         The default for the parallel case is
*                         335 * N**(-0.44) * NPROCS.
*
*       PIPARMQ(ISPEC=15) Number of simultaneous shifts, NS.
*                         a multi-shift QR iteration.
*
*                         If IHI-ILO+1 is ...
*
*                         greater than      ...but less    ... the
*                         or equal to ...      than        default is
*
*                                 0               30       NS =    2+
*                                30               60       NS =    4+
*                                60              150       NS =   10
*                               150              590       NS =   **
*                               590             3000       NS =   64
*                              3000             6000       NS =  128
*                              6000            12000       NS =  256
*                             12000            24000       NS =  512
*                             24000            48000       NS = 1024
*                             48000            96000       NS = 2048
*                             96000         INFINITY       NS = 4096
*
*                     (+)  By default matrices of this order are
*                          passed to the implicit double shift routine
*                          PxLAQR1.  See PIPARMQ(ISPEC=12) above. These
*                          values of NS are used only in case of a rare
*                          PxLAQR1 failure.
*
*                     (**) The asterisks (**) indicate an ad-hoc
*                          function increasing from 10 to 64.
*
*       PIPARMQ(ISPEC=16) Select structured matrix multiply.
*                         (See ISPEC=16 above for details.)
*                         Default: 3.
*
*     ================================================================
*     .. Parameters ..
      INTEGER            inmin, inwin, inibl, ishfts, iacc22
      parameter( inmin = 12, inwin = 13, inibl = 14,
     $                   ishfts = 15, iacc22 = 16 )
      INTEGER            nmin, NMIN2, k22min, kacmin, nibble, knwswp
      parameter( nmin = 220, k22min = 14, kacmin = 14,
     $                   nibble = 14, knwswp = 500, nmin2 = 770 )
      REAL               two
      parameter( two = 2.0 )
*     ..
*     .. Local Scalars ..
      INTEGER            nh, ns, myrow, MYCOL, nprow, npcol, np
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          log, max, mod, nint, real
*     ..
*     .. External functions ..
      INTEGER            iceil
      EXTERNAL           iceil
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo
*     ..
*     .. Executable Statements ..
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      IF( ( ispec.EQ.ishfts ) .OR. ( ispec.EQ.inwin ) .OR.
     $    ( ispec.EQ.iacc22 ) ) THEN
*
*        ==== Set the number simultaneous shifts ====
*
         nh = ihi - ilo + 1
         ns = 2
         IF( nh.GE.30 )
     $        ns = 4
         IF( nh.GE.60 )
     $        ns = 10
         IF( nh.GE.150 )
     $        ns = max( 10, nh / nint( log( real( nh ) ) / log( two ) ))
         IF( nh.GE.590 )
     $        ns = 64
         IF( nh.GE.3000 )
     $        ns = 128
         IF( nh.GE.6000 )
     $        ns = 256
         IF( nh.GE.12000 )
     $        ns = 512
         IF( nh.GE.24000 )
     $        ns = 1024
         IF( nh.GE.48000 )
     $        ns = 2048
         IF( nh.GE.96000 )
     $        ns = 4096
         IF( nh.GE.192000 )
     $        ns = 8192
         IF( nh.GE.384000 )
     $        ns = 16384
         IF( nh.GE.768000 )
     $        ns = 32768
         IF( nh.GE.1000000 )
     $        ns = iceil( nh, 25 )
         ns = max( ns, 2*min(nprow,npcol) )
         ns = max( 2, ns-mod( ns, 2 ) )
      END IF
*
      IF( ispec.EQ.inmin ) THEN
*
*
*        ===== Submatrices of order smaller than NMIN*min(P_r,P_c)
*        .     get sent to PxLAHQR, the classic ScaLAPACK algorithm.
*        .     This must be at least 11. ====
*
         piparmq = nmin * min( nprow, npcol )
*
      ELSE IF( ispec.EQ.inibl ) THEN
*
*        ==== INIBL: skip a multi-shift QR iteration and
*        .    whenever aggressive early deflation finds
*        .    at least (NIBBLE*(window size)/100) deflations. ====
*
         np = min( nprow, npcol )
         IF( np.EQ.1 ) THEN
            piparmq = nibble
         ELSE
            nh = ihi - ilo + 1
            piparmq = min( 100,
     $           ceiling( 335.0d+0 * nh**(-0.44d+0) * np ) )
         END IF
*
      ELSE IF( ispec.EQ.ishfts ) THEN
*
*        ==== NSHFTS: The number of simultaneous shifts =====
*
         piparmq = ns
*
      ELSE IF( ispec.EQ.inwin ) THEN
*
*        ==== NW: deflation window size.  ====
*
         IF( nh.LE.knwswp ) THEN
            piparmq = ns
         ELSE
            piparmq = 3*ns / 2
         END IF
*
      ELSE IF( ispec.EQ.iacc22 ) THEN
*
*        ==== IACC22: Whether to use 2-by-2 block structure while
*        .     doing it.  A small amount of work could be saved
*        .     by making this choice dependent also upon the
*        .     NH=IHI-ILO+1.
*
         piparmq = 1
c         PIPARMQ = 0
c         IF( NS.GE.KACMIN )
c     $      PIPARMQ = 1
         IF( ns.GE.k22min )
     $      piparmq = 2
*
      ELSE
*        ===== invalid value of ispec =====
         piparmq = -1
*
      END IF
*
*     ==== End of PIPARMQ ====
*
      END